[已解决]奇怪的批处理，不让加汉字，加了汉字就运行不正常

hnfeng · 发表于 2025-10-29 21:55:51

本帖最后由 hnfeng 于 2025-10-30 14:57 编辑

这个批处理，我想把一些英文信息文字改为汉字，结果发现只要有汉字，批处理就运行不正常。怎么做到的？如何去掉这个限制?
原批处理是ansi编码

@echo off
rem script: @rgadguard
rem version: v1.03.2
setlocal EnableExtensions
setlocal EnableDelayedExpansion
color 0a
:BIN
cd /d "%~dp0"
if exist "%~dp0bin\7z.exe" (set "x7z=%~dp0bin\7z.exe") else (goto :DLBin)
if not exist "%~dp0bin\7z.cmd" goto :DLBin
if not exist "%~dp0bin\7z.dll" goto :DLBin
if exist "%~dp0bin\aria2c.exe" (set "aria2=%~dp0bin\aria2c.exe") else (goto :DLBin)
if not exist "%~dp0bin\smv.cmd" goto :DLBin
if exist "%~dp0bin\smv.exe" (set "smv=%~dp0bin\smv.exe") else (goto :DLBin)
call :sup
call :tr
set "uuid=0ffac4d9-0ec8-80b2-1e75-31f1d0baa24a"
set "key=free"
if /i !key! EQU free call :free
color 0a
title Select list files...
"%aria2%" -x1 -s1 -d"%dir_temp%" -o"list.txt" "https://files.rg-adguard.net/file/%uuid%/list" --disable-ipv6
for /f "tokens=1 delims=" %%a in ('type "%dir_temp%\list.txt"') do set /a count+=1
:ListFiles
cls
set ListSel=
echo.
echo %r%
echo The list of files that will be uploaded during operation...
echo %r%
echo.
for /f "tokens=2,3 delims=^|" %%a in ('type "%dir_temp%\list.txt"') do (
echo %%a ^(%%b^)
)
echo.
echo %r%
if /i %count% NEQ 1 (
echo Save all files - press key S
echo Save only the requested file - press key F
) else (
echo Enter F or S to continue downloading files
)
echo %r%
echo.
CHOICE /c fs /n /m "Save all or just the requested file?"
if /i %count% NEQ 1 (If Errorlevel 2 set ListSel=S)
If Errorlevel 1 set ListSel=F
goto :working
:working
title Download files...
cls
"%aria2%" -x1 -s1 -d"%dir_temp%" -o"dl.txt" "https://files.rg-adguard.net/dl/%key%/%uuid%" --disable-ipv6
"%aria2%" -x1 -s1 -j1 -c -R -d"%cd%" -i"%dir_temp%\dl.txt" --disable-ipv6
if exist "%~dp0tmp\*.aria2" (
erase /q "%dir_temp%\dl.txt"
echo Re-download, after 10 seconds...
timeout /t 10 /NOBREAK
goto :working
)
call bin\7z.cmd
call bin\smv.cmd
goto :exit
:DLBin
for /f "tokens=3 delims=:. " %%f in ('bitsadmin.exe /CREATE /DOWNLOAD "Download Tools" ^| findstr "Created job"') do set GUID=%%f
title Download tools...
bitsadmin /transfer %GUID% /download /priority foreground https://files.rg-adguard.net/tools "%cd%\tools.cab"
if NOT EXIST tools.cab goto :Error 4
expand "tools.cab" -f:* .\ >nul
del /f /q tools.cab >nul 2>&1
goto :BIN
:sup
set "dir_temp=%~dp0%random%"
set xOS=x86
if exist "%WINDIR%\SysWOW64" Set xOS=x64
if exist "%WINDIR%\SysArm32" Set xOS=a64
for /f "tokens=6 delims=[]. " %%# in ('ver') do set xBuild=%%#
if %xOS% NEQ x64 goto :Error 1
if %xBuild% LSS 6000 goto :Error 2
exit /b
:Error
cls
color 4f
echo.
echo %r%
echo.
echo.
if %1==1 echo Attention, the script only works with a 64-bit system.
if %1==2 echo For the script to work, the operating system Windows Vista or higher is required.
if %1==3 echo There are not enough files in the bin folder.
if %1==4 echo Failed to download the software package.
echo.
echo.
echo %r%
echo.
echo.
pause
exit
:limit
title LIMIT DOWNLOAD
cls
color 4f
echo.
echo %r%
echo.
echo LIMIT DOWNLOAD
echo.
echo You have exceeded the limit of simultaneous connections.
echo During the free download, no more than 1 connection is available.
echo.
echo %r%
echo.
pause
echo.
exit
:free
title THIS BANNER IS A WARNING
cls
color 4f
echo.
echo %r%
echo.
echo THIS BANNER IS A WARNING
echo.
echo You have used the free download.
echo The download speed will be limited.
echo If you want to download multiple files at maximum speed and with the possibility
echo of downloading them at once, you need to purchase a subscription.
echo.
echo %r%
echo.
echo This message is available within a few seconds.
echo.
timeout /t 10 /NOBREAK
echo.
exit /b
:exit
set fnd=n
title Finish...
cls
echo.
echo %r%
echo.
echo The script is finished.
echo All the files you received are files, you will find them next to the script.
echo.
echo Here is the list of files:
echo %t%
echo.
for /f "tokens=2 delims=^|" %%a in ('type "%dir_temp%\list.txt"') do (
if exist %%a echo %%a && set "fnd=y"
)
if !fnd! NEQ y goto :limit
echo.
echo %r%
echo.
rd>nul /s /q "%dir_temp%"
timeout>nul /t 10
exit
:tr
set "r=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^=^="
set "t=----------------------------------------------------------------------------------------------------"
goto :eof

复制代码

hnfeng · 发表于 2025-10-29 22:00:20

原批处理下载地址：
https://files.rg-adguard.net/fil ... 2-1e75-31f1d0baa24a

aloha20200628 · 发表于 2025-10-29 22:26:52

回复 1# hnfeng

诊断须知》你要修改哪个位置的英文数据？

hlzj88 · 发表于 2025-10-29 22:56:05

我的系统win11，22H。
反正是奇奇怪怪的不算正常，可以用。
新建文本是utf-8格式。
新建的bat如果内容是全英文字母，改ansi格式后还是会变为utf-8，处理汉字会出错。所以我是在bat开头先写个汉字，bat就不会变utf-8。比如 echo 啊

楼主的情况也许是这样。可以试试看。

77七 · 发表于 2025-10-30 00:20:48

回复 2# hnfeng

换行符改为CR+LF试试

hnfeng · 发表于 2025-10-30 07:32:10

本帖最后由 hnfeng 于 2025-10-30 08:31 编辑

回复 hnfeng

诊断须知》你要修改哪个位置的英文数据？
aloha20200628 发表于 2025-10-29 22:26

所有位置

例如，不改动运行正常。如果在118行后面加一个“汉”字，再运行就乱套了。删掉这个“汉”字，再运行，又正常

hnfeng · 发表于 2025-10-30 07:38:02

回复 hnfeng

换行符改为CR+LF试试
77七发表于 2025-10-30 00:20

厉害厉害，一下子点醒梦中人。

经试验，果然是这个原因

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [已解决]奇怪的批处理，不让加汉字，加了汉字就运行不正常

评分