[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖
支持每行字符数不同
  1. @echo off&setlocal enabledelayedexpansion
  2. for /f "delims=" %%a in (a.txt) do (set/a n+=1&set "_!n!=%%a")
  3. :loop
  4. for /l %%i in (1,1,%n%) do (
  5.     if defined _%%i (<nul set/p=!_%%i:~,1!&set _%%i=!_%%i:~1!) else (set/p= <nul)
  6. )
  7. echo/&for /l %%i in (1,1,%n%) do if defined _%%i goto loop
  8. pause
复制代码

TOP

看错题意,算了...

[ 本帖最后由 zm900612 于 2011-3-12 13:01 编辑 ]

TOP

哈哈,这题么,全是单字节字符,正好用上cmd /u
  1. @echo off&setlocal enabledelayedexpansion
  2. find /v "" a.txt
  3. echo 以下为纵横转换结果:
  4. for /f "skip=1 delims=:" %%a in ('(type a.txt^&echo;^)^|findstr /o .*') do (
  5.         set /a ho=%%a-2,l=ho-last-2,last=ho,"max+=(max-l)*((max-l)>>31)"
  6.         set o=!o!!ho!
  7. )
  8. set n=1
  9. for /f "delims=" %%a in ('cmd /u /c type a.txt^|more') do (
  10.         for /f "tokens=1,2" %%x in ("!n! !o!") do (
  11.                 set .!n!=!.%%x!%%a
  12.                 set /a n+=1,m+=1
  13.                 if !m!==%%y (
  14.                         for /l %%z in (!n! 1 %max%) do set ".%%z=!.%%z! "
  15.                         set o=!o:* =!&set /a n=1,m+=2
  16.                 )
  17.         )
  18. )
  19. for /l %%a in (1 1 %max%) do echo [!.%%a!]
  20. pause
复制代码

[ 本帖最后由 zm900612 于 2011-3-13 12:31 编辑 ]

TOP

贴一个正统的解法
用到了临时文件
得亏事先造好了声势
可以不用偷偷摸摸了

楼主号称5句代码能够解题
等待瞻仰中……
  1. @echo off & setlocal EnableDelayedExpansion
  2. rem 重置可能影响程序的环境变量为空
  3. for %%e in (lines context sizes cols) do set %%e=
  4. rem 将所有文本行拼成一行,并统计行数
  5. for /f "delims=" %%l in (a.txt) do set /a lines+=1&set "context=!context!%%l"
  6. rem 获取文本总字节数,并依此计算列数和列边界
  7. (echo %context%)>b.txt
  8. for %%f in (b.txt) do set /a sizes=%%~zf-2,cols=sizes/lines,collimit=cols-1
  9. rem 依照字符坐标转换,依次输出各列字符
  10. for /l %%i in (0,1,%collimit%) do (
  11. for /l %%j in (%%i,%cols%,%sizes%) do set/p=!context:~%%j,1!<nul
  12. echo.
  13. )
  14. pause
复制代码
天的白色影子

TOP

  1. @echo off
  2. set /p char=<a.txt
  3. set n=0
  4. :o
  5. if not "%char%"=="" (
  6.     set /a n+=1
  7.     set char=%char:~1%
  8.     goto :o
  9. )
  10. set /a n-=1
  11. setlocal enabledelayedexpansion
  12. for /l %%b in (0,1,%n%) do (
  13.     for /f "delims=" %%a in (a.txt) do (
  14.         set "str=%%a"
  15.         set str%%b=!str%%b!!str:~%%b,1!
  16.     )
  17.     echo !str%%b!
  18. )
  19. pause
复制代码

TOP

  1. @echo off
  2. Setlocal EnableDelayedExpansion
  3. set maxlength=0
  4. for /f "delims=" %%i in (a.txt) do (
  5.     call :len "%%i" length
  6.     set "number=!number! !length!"
  7.     set "list=!list!%%i"
  8. )
  9. for /l %%i in (1,1,%maxlength%) do (
  10.     set /a x=0
  11.     set "temp="
  12.     for %%j in (%number%) do (
  13.         set /a m=!x!+%%i-1
  14.         call set temp=!temp!%%list:~!m!,1%%
  15.         set /a x+=%%j
  16.     )
  17.     echo !temp!
  18. )
  19. exit
  20. :len
  21. set "strs=%~1" & set /a n=0
  22. :loop
  23. if defined strs (
  24.     set strs=%strs:~1%
  25.     set /a n+=1
  26.     goto:loop
  27. )
  28. if %maxlength% lss %n% (
  29.     set maxlength=%n%
  30. )
  31. set %2=%n%
复制代码

TOP

返回列表