【练习-008】批处理实现文本内容横列变纵列

pusofalse

因为论坛会吞掉文本每行的第一个空格，现截图上来。

每行的字符数都一样，但未知多少个字符。
注意，文本第三行r之后有一个空格。第四行x之后有一个空格。
输出为：

即横列变纵列，并保留原来空格。
要求，高效，不生成临时文件。

ieutk

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set /a num=-1
   
4. :main
   
5. set "ot="
   
6. set /a num+=1
   
7. for /f "delims=" %%a in (a.txt) do call :ie "%%a"
   
8. echo.%ot%
   
9. goto :main
   
10. 
    
11. 
    
12. :ie
    
13. set "var=%~1"
    
14. if "!var:~%num%,1!"=="" (pause&exit)
    
15. call,set "ot=!ot!%%var:~%num%,1%%"
    
16. goto :eof

复制代码

pusofalse

我试了一下，这题能在5句之内解决。

浅默

@echo off&setlocal enabledelayedexpansion
for /l %%a in (0,1,10) do (
    for /f "delims=" %%i in (a.txt) do (
        set ke=%%i
        set /p=!ke:~%%a,1!<nul
    )
    echo.
)
pause

pusofalse

4楼的代码够简洁，但仍不通用。
每行的字符数是未知的。

batman

先贴一种方案吧：

1. @echo off&setlocal enabledelayedexpansion
   
2. set "n=0"&set "m=0"
   
3. :lp
   
4. for /f "delims=" %%+ in (1.txt) do (
   
5.     set /a x+=1&set "str=%%+"
   
6.     if "!str:~%n%,1!" equ "" (
   
7.        set /a m+=1
   
8.        if !m! equ !x! pause>nul&goto :eof
   
9.        ) else (
   
10.        set /p=!str:~%n%,1!<nul
    
11.     )
    
12. )
    
13. echo.&set /a n+=1,x=0&goto lp

复制代码

batman

再来段貌似高深的代码：

1. @echo off
   
2. for /f "delims=" %%. in (1.txt) do set "_=0"&set "..=%%."&call :{}
   
3. for /l %%+ in (1,1,%_%) do call,echo.%%..%%+%%
   
4. pause>nul&goto :eof
   
5. :{}
   
6. set "#=%..:~,1%"&call,set "..=%%..:~1%%"&set /a _+=1&call,set "..%_%=%%..%_%%%%#%"&if defined .. goto {}

复制代码

说明下：
       之所以写下这么一段怪异的代码，就是想告诉大家，只要你运用得得当，批处理真的是可以随心所欲地写，这也就
是其中乐趣所在了。。。

[ 本帖最后由 batman 于 2008-8-3 00:50 编辑 ]

batman

这道题并不难啊，大家都来锻炼下思维，踊跃答题啊！

terse

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in (a.txt) do set str=%%i&set/a n+=1,m=0&call:lp
   
3.    for /l %%i in (0 1 %m%) do if not "!%%ip!"=="" echo !%%ip!
   
4. pause&goto :eof
   
5. :lp
   
6.    set "%m%p=!%m%p!!str:~%m%,1!"
   
7.    if not "!str:~%m%,1!"=="" set/a m+=1&goto lp

复制代码

terse

行的字符不同处理

1. @echo off&setlocal enabledelayedexpansion
   
2. set t=0
   
3. for /f "delims=" %%i in (a.txt) do set str=%%i&set/a n+=1,m=1&call:lp
   
4.    for /l %%i in (1 1 %t%) do (
   
5.       for /l %%j in (1 1 %n%) do if "!%%jp%%i!"=="" (set/p= <nul)else set/p=!%%jp%%i!<nul
   
6.       echo.
   
7. )
   
8. pause&goto :eof
   
9. :lp
   
10.    set "%n%p%m%=%str:~,1%"
    
11.    set "str=%str:~1%"
    
12.    if defined str set/a m+=1&goto lp
    
13.    if %m% gtr %t% set/a t=m

复制代码

sjzong

发错了！还是先向别人学习

[ 本帖最后由 sjzong 于 2009-4-24 18:38 编辑 ]

keen

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in (a.txt) do (
   
3.     set v=%%i
   
4.     set n=0
   
5.     call :lp
   
6. )
   
7. for /l %%i in (1 1 %n%) do (
   
8.     set num=%%i
   
9.     call,echo %%_!num!%%
   
10. )
    
11. pause&exit/b
    
12. :lp
    
13.     set /a n+=1
    
14.     set _%n%=!_%n%!%v:~0,1%
    
15.     set v=%v:~1%
    
16.     if not "%v%"=="" goto lp
    
17. goto :eof

复制代码

keen

回复batman

不是说我不想帮助别人，只是不知道怎么样去帮助别人。

我觉得自己的技术还不够成熟，怕给别人说错了，误导别人，这个责任我担不起。

netbenton

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in (a.txt) do (set v=%%i&call :lp)
   
3. for /l %%i in (0 1 %n%) do (echo.!#%%i!)
   
4. pause&goto :eof
   
5. 
   
6. :lp
   
7. for /l %%a in (0,1,100) do (if "!v:~%%a,1!"=="" (set n=%%a&goto :eof) else (set #%%a=!#%%a!!v:~%%a,1!))

复制代码

jt10086

新人,来学习学习,支持楼主了,说实话看了就头大,吼吼