批处理如何批量删除文件夹里时长小于指定秒数的视频？

盛世繁华 · 发表于 2025-10-31 22:34:31

bat和多个文件夹在同一个目录下，每个文件夹有若干视频，需要批量删除文件夹里时长小于指定秒数的视频，比如7秒。最好能在运行的时候自己输入秒数。

用deepseek试写了一个并不能运行，大佬帮忙优化一下，看是哪里的问题，也已经把ffmpeg软件和bat放一起了，再次感谢了

代码如下：

@echo off
setlocal enabledelayedexpansion
:: 设置视频时长阈值（秒）
set "threshold=7"
:: 获取当前文件夹路径
set "current_dir=%cd%"
:: 遍历当前目录及所有子目录下的MP4文件
for /R "%current_dir%" %%f in (*.mp4) do (
:: 使用FFmpeg获取视频时长
for /f "tokens=1 delims=." %%d in ('ffmpeg -i "%%f" 2>&1 ^| findstr "Duration"') do (
set "duration=%%d"
set "duration=!duration: =!"
:: 提取时长的小时、分钟和秒部分
for /f "tokens=1-3 delims=:" %%h in ("!duration!") do (
set "hours=%%h"
set "minutes=%%i"
set "seconds=%%j"
)
:: 计算总时长（秒）
set /a total_seconds = hours * 3600 + minutes * 60 + seconds
:: 如果时长小于阈值，则删除文件
if !total_seconds! lss %threshold% (
echo Deleting %%f (Duration: !total_seconds! seconds)
del "%%f"
)
)
)
endlocal
pause

复制代码

flashercs · 发表于 2025-10-31 23:32:59

@echo off
setlocal enabledelayedexpansion
REM 设置视频时长阈值（秒）
set "threshold=7"
REM 获取当前文件夹路径
set "current_dir=%cd%"
REM 遍历当前目录及所有子目录下的MP4文件
for /R "%current_dir%" %%A in (*.mp4) do (
REM 使用FFmpeg获取视频时长
for /f "tokens=2-4 delims=:. " %%d in ('ffmpeg -i "%%A" 2^>^&1 ^| findstr "Duration"') do (
REM 计算总时长（秒）
set /a "total_seconds=(1%%d-100)*3600+(1%%e-100)*60+(1%%f-100)"
REM echo total_seconds=!total_seconds!
REM 如果时长小于阈值，则删除文件
if !total_seconds! lss %threshold% (
echo Deleting %%A [Duration: !total_seconds! seconds]
del "%%A"
)
)
)
endlocal
pause

复制代码

aloha20200628 · 发表于 2025-11-1 11:42:19

本帖最后由 aloha20200628 于 2025-11-1 11:59 编辑

回复 1# 盛世繁华

以下代码中第一行设置 '时长限值'，假设为7秒，格式如 00:00:07

@echo off &setlocal &set "t=00:00:07"
for /f "delims=" %%F in ('dir /b/s/a-d *.mp4') do for /f "tokens=2 delims=., " %%t in ('ffmpeg.exe -hide_banner -i "%%F" 2^>^&1^|find /i "duration:" ') do if "%%t" lss "%t%" (echo,Deleting %%F [%%t] &del /q "%%F")
pause&exit/b

复制代码

77七 · 发表于 2025-11-1 15:06:48

我把1楼第一句话发给chatgpt，给了个这个，有点错误但是不影响使用。

@echo off
setlocal enabledelayedexpansion
:: 设置阈值秒数，例如7秒
set "LIMIT=7"
echo 正在扫描当前目录下的所有视频文件，删除时长小于 %LIMIT% 秒的文件...
echo.
:: 遍历所有子文件夹中的视频文件
for /r %%A in (*.mp4 *.mkv *.avi *.mov *.flv *.wmv) do (
rem 获取文件路径
set "file=%%A"
rem 使用 ffprobe 获取视频时长（秒）
for /f "tokens=* usebackq" %%B in (`ffprobe -v error -select_streams v:0 -show_entries format^=duration -of default^=noprint_wrappers^=1:nokey^=1 "%%A"`) do (
set "duration=%%B"
)
rem 有些文件会出错返回空值，跳过
if not defined duration (
echo [跳过] %%~nxA（无法读取时长）
) else (
rem 截取整数部分比较
set /a dur_int=!duration:.=!
for /f "tokens=1 delims=." %%C in ("!duration!") do set /a dur_int=%%C
if !dur_int! lss %LIMIT% (
echo [删除] %%~nxA（!dur_int! 秒）
del "%%A"
) else (
echo [保留] %%~nxA（!dur_int! 秒）
)
)
)
echo.
echo 处理完毕！
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理如何批量删除文件夹里时长小于指定秒数的视频？