[已解决]批处理diskpart下如何选择其他盘符还原镜像

dragon123 · 发表于 2025-5-8 20:45:44

@echo off
@rem This script is called by x:\Windows\System32\Startnet.cmd - WinPE
@echo.
@echo.
@echo.
@echo Running Intel Optimization powercfg for improved imaging times
@echo.
@echo call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
@echo.
@echo.
@echo.
@rem *****************************************************************
@rem List all the disks, then search the volumes of each one to see
@rem which disks may have "Winpe" in the label. We will ignore that
@rem disk and use the first disk without the Winpe label that we find.
@rem *****************************************************************
@echo call diskpart /s %WinPESource%DiskpartFiles\listdisk.txt
call diskpart /s %WinPESource%DiskpartFiles\listdisk.txt>x:\Disks.txt
@echo.
@rem Set Disk equal to blank to start
set disk=
@echo.
@rem
@rem This line will write a diskpart script to select the disk and detail it's contents.
@rem We use this output to find a disk that does NOT have Winpe as the volume label.
@rem That disk will have the OS installed to it. This way you can exclude USB from diskpart.
@rem
@rem This works around the issue where the USB key is sometimes enumerated as disk 0 and the
@rem SSD is disk 1.
@rem
for /f "skip=8 tokens=2" %%A in (x:\Disks.txt) do (
@echo sel disk %%A>x:\Par.txt
@echo det disk>>x:\Par.txt
@echo exit>>x:\Par.txt
if NOT "%%A"=="DiskPart..." call :ListPar %%A
)
if %Disk%=="" echo No disk found without a volume label of "Winpe"&& set disk=0
@echo Using Disk "%Disk%"
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo Write the diskpart script now that we know what disk to use
@echo *****************************************************************
@echo.>x:\wimpart.txt
@echo select disk "0">>x:\wimpart.txt
@echo clean>>x:\wimpart.txt
@echo convert gpt>>x:\wimpart.txt
@echo create partition efi size=100>>x:\wimpart.txt
@echo format quick fs=fat32 label="System">>x:\wimpart.txt
@echo assign letter="S">>x:\wimpart.txt
@echo create partition msr size=128>>x:\wimpart.txt
@echo create partition primary>>x:\wimpart.txt
@echo format quick fs=ntfs label="Windows">>x:\wimpart.txt
@echo assign letter="W">>x:\wimpart.txt
@echo exit>>x:\wimpart.txt
@echo.
@echo Wimpart.txt now contains.....
@echo.
type x:\wimpart.txt
@echo.
@echo.
@echo *****************************************************************
@echo Setting up the partition table
@echo *****************************************************************
@echo call diskpart /s x:\wimpart.txt
diskpart /s x:\wimpart.txt
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem Map drive letter for Install.wim and Winre.wim
@echo *****************************************************************
@rem Create an output file containing all the drive letters
@echo call diskpart /s %WinPESource%DiskpartFiles\listVol.txt>%WinPESource%Output.txt
diskpart /s %WinPESource%DiskpartFiles\listVol.txt>%WinPESource%Output.txt
@echo.
@rem Go through each drive letter, looking for the images\Install.txt file
for /f "skip=8 tokens=3" %%A in (%WinPESource%Output.txt) do (
if exist %%A:\images\install.txt set InstallPath=%%A:\images&& echo "Found device with images folder and install.txt file"
)
@echo.
@echo.
@rem Check InstallPath was found and there are images in it.
if NOT EXIST %InstallPath%\Install.wim echo "Install.wim NOT found." && goto :Error
@echo Install.wim FOUND at %InstallPath%\images\install.wim
@echo.
@echo ----------------------------------------------------------------------------
@echo ****************************************************************************
@echo Applying the -Testing- image from the Images Partition in the eMMC
@echo ****************************************************************************
@echo ----------------------------------------------------------------------------
DISM /Apply-Image /ImageFile:"%InstallPath%\install.wim" /ApplyDir:w: /Index:1
if %errorlevel% NEQ 0 echo "Failed to apply image to w:" && goto :error
@echo.
@echo *****************************************************************
@echo Setting the boot environment
@echo *****************************************************************
@echo call w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
if %errorlevel% NEQ 0 echo "Failed to set boot information" && goto :error
@echo *****************************************************************
@echo -Testing- image deployment COMPLETE. Type EXIT from Command
@echo Prompt to restart or turn off device.
@echo *****************************************************************
color 2f
goto :END
:ERROR
@echo.
@echo An error has been detected.
color 4f
@echo.
goto :END
:ListPar
@REM This section is to bring a disk number and use it to List Partitions
@echo.
set TempDisk=%1
diskpart /s x:\Par.txt>x:\ParOutput.txt
for /f "skip=24 tokens=3" %%A in (x:\ParOutput.txt) do (
if /i "%%A"=="no" set Disk=%TempDisk%
)
for /f "skip=26 tokens=4" %%A in (x:\ParOutput.txt) do (
if /i NOT "%%A"=="Winpe" set Disk=%TempDisk%
)
Goto :EOF
:END
@rem
@rem Get finish time so we can evaluate total WinPE phase time.
@rem
call |time>x:\StopTime.txt
@rem
@rem Now parse both files to display the Start and Finish Time
@rem
@echo.
@echo.
for /f "tokens=5" %%A in (x:\starttime.txt) do echo Script Start Time is %%A
for /f "tokens=5" %%A in (x:\stoptime.txt) do echo Script Stop Time is %%A
@echo.
pause
x:\windows\system32\wpeutil shutdown

复制代码

默认的是镜像还原到disk 0，如何改成disk 1，请指教，

jiavip · 发表于 2025-5-8 23:53:09

@echo *****************************************************************
@echo.>x:\wimpart.txt
@echo select disk "0">>x:\wimpart.txt
@echo clean>>x:\wimpart.txt
@echo convert gpt>>x:\wimpart.txt
@echo create partition efi size=100>>x:\wimpart.txt
@echo format quick fs=fat32 label="System">>x:\wimpart.txt
@echo assign letter="S">>x:\wimpart.txt
@echo create partition msr size=128>>x:\wimpart.txt
@echo create partition primary>>x:\wimpart.txt
@echo format quick fs=ntfs label="Windows">>x:\wimpart.txt
@echo assign letter="W">>x:\wimpart.txt
@echo exit>>x:\wimpart.txt

复制代码

@echo select disk "0">>x:\wimpart.txt

玩PE 系统？玩PE 好像无忧论坛的高手多点吧！
年轻的时候也喜欢自己整PE，现在没啥动力了，，

dragon123 · 发表于 2025-5-9 08:53:20

回复 2# jiavip

谢谢大佬，我是新手，还停留在应用的阶段，主要是备份和还原win 系统，有其他图形界面的备份与还原的winpe吗？我试了一下傲梅，不稳定不好用

dragon123 · 发表于 2025-5-9 09:07:39

回复 2# jiavip

for /f "skip=8 tokens=3" %%A in (%WinPESource%Output.txt) do (
if exist %%A:\images\install.txt set InstallPath=%%A:\images&& echo "Found device with images folder and install.txt file"
)
这一句有点看不懂，请
大佬帮忙详解

flashercs · 发表于 2025-5-9 10:35:49

本帖最后由 flashercs 于 2025-5-9 10:40 编辑

回复 4# dragon123
选择磁盘序号:1

@echo select disk "1">>x:\wimpart.txt

复制代码

关于代码解释,可以让AI给解释代码;
AI的解释:

for /f "skip=8 tokens=3":
for /f: 用于逐行读取文件内容，并对每一行执行命令。
"skip=8 tokens=3": 这些是for循环的选项。
skip=8: 跳过文件开头的前8行，从第9行开始处理。
tokens=3: 每一行按默认分隔符（空格、制表符等）分割后，只取第3个标记(token)赋值给循环变量%%A。
%%A:
在批处理脚本中，%%A 是循环变量，它会依次被赋予由tokens=3指定的每行的第3个标记的值。注意，在命令行直接运行时只需单百分号(%A)，但在批处理脚本(.bat或.cmd文件)中需要双百分号(%%A)。
in (%WinPESource%Output.txt):
指定要读取的文件路径。这里使用了变量 %WinPESource% 来动态构建文件路径，最终指向名为 Output.txt 的文件。
do (...):
对于每一行（经过skip和tokens过滤后的），执行括号内的命令。
if exist %%A:\images\install.txt:
检查是否存在以当前循环变量%%A（代表盘符或其他标识符）为根目录下的\images\install.txt文件。
set InstallPath=%%A:\images:
如果上述条件满足，则设置环境变量InstallPath为其对应的路径（即%%A:\images）。
&& echo "Found device with images folder and install.txt file":
&& 表示如果前面的命令成功执行（返回状态码为0），则执行后面的命令。
echo 输出一条消息到控制台，指示找到了包含所需文件夹和文件的设备。

复制代码

dragon123 · 发表于 2025-5-9 14:19:00

回复 5# flashercs

感谢大佬提醒

jiavip · 发表于 2025-5-10 21:35:44

本帖最后由 jiavip 于 2025-5-11 01:03 编辑

回复 3# dragon123
称不上大佬吧，

其实像这样的小问题，，随便一个，，，diskpart /? 就能试探出很多解释了。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理diskpart下如何选择其他盘符还原镜像

评分

评分