设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT求助&讨论 › 简单的 VT100 绘图引擎，支持 24 位色！
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发新帖
查看: 31922|回复: 12

[特效代码] 简单的 VT100 绘图引擎，支持 24 位色！

[复制链接]
HOPE2021
发表于 2022-9-10 13:30:17 | 显示全部楼层 |阅读模式
本帖最后由 HOPE2021 于 2022-9-11 12:11 编辑

前两天无意中看到用批处理制作绘图引擎的提议。仔细想了一下，觉得在Windows 10中使用控制台虚拟终端序列制作还是挺简单的。于是我将常用的VT100转义写成了函数，下面是一些简单的实例：
VT 100 动画 - 本楼
中秋节快乐艺术字海报 - 2楼
进度条时钟 - 3 楼
  1. @Mode Con: Cols=80 Lines=25 & Chcp 936 > Nul & @SetLocal Enableextensions & @Echo Off
  2. %= 利用 VT100 虚拟终端序列来制作绘图引擎的实例 =%
  3. @Goto :Main

  5. :Main
  6.         @Call :Ani
  7.         Pause > Nul
  8. @Exit /B 0

  10. :Ani
  11.         Call :SetConsoleCursorInfo 1 1
  12.         Call :SetConsoleTextAttribute 0-0-0 0-128-0
  13.         Call :Type "Welcome to the "
  14.         Call :SetConsoleTextAttributeEx 4
  15.         Call :Type "future"
  16.         Call :SetConsoleTextAttributeEx 5
  17.         Call :Type "."
  18.         TimeOut /T 2 > Nul 2> Nul
  19.         Call :SetConsoleCursorInfo 2 0
  20.         Cls
  21.         For /L %%I in (0,1,2) Do (
  22.                 Call :GotoXY 1 13
  23.                 Set /P=Welcome to the future.< Nul
  24.                 For /L %%I in (1,1,58) Do (
  25.                         Help > Nul 2> Nul
  26.                         Call :GotoXY %%I 13
  27.                         Set /P=# Welcome to the future.< Nul
  28.                 )
  29.                 For /L %%I in (58,-1,1) Do (
  30.                         Help > Nul 2> Nul
  31.                         Call :GotoXY %%I 13
  32.                         Set /P=Welcome to the future. < Nul
  33.                 )
  34.         )
  35.         Cls
  36.         For /L %%I in (0,16,255) Do (
  37.                 For /L %%J in (0,16,255) Do (
  38.                         For /L %%K in (0,16,255) Do (
  39.                                 Call :SetConsoleTextAttribute %%I-%%J-%%K %%I-%%J-%%K
  40.                                 Set /P=#< Nul
  41.                         )
  42.                 )
  43.         )
  44. @Goto :Eof

  46. %================================================================%
  47. %= 日期: 2022 年 9 月 10 日 =%
  48. %= 名称: Type =%
  49. %= 作用: 模拟打字 =%
  50. %= 参数: String 要显示的字符串 =%
  51. %= 备注: 此函数要访问环境变量 _._ =%
  52. %================================================================%
  53. :Type <String>
  54.         If "%~1"=="" @Goto :Eof
  55.         Set "_._=%~1"
  56.         Set /P=#%_._:~0,1%< Nul
  57.         Set "_._=%_._:~1%"
  58.         TimeOut /T 0 > Nul 2> Nul
  59.         If Defined _._ @Call :Type "%_._%"
  60. @Goto :Eof

  62. %================================================================================================================================%
  63. %= VT100 函数 =%
  64. %================================================================================================================================%

  66. %================================================================%
  67. %= 日期: 2022 年 9 月 9 日 =%
  68. %= 名称: InitVT100 =%
  69. %= 作用: 初始化 Windows 10 的 虚拟终端序列 =%
  70. %================================================================%
  71. :InitVT100
  72. %= { =%

  74.         %= 获取 ESC 字符 =%

  76.         Set "ESC="

  78.         %= 如果没有定义 ESC 字符，这个过程是为了防止论坛误吞上文的 ESC 字符 =%
  79.         If Not Defined ESC (

  81.                 For /F "Delims=#" %%_ in ('Prompt #$E# ^& Echo On ^& For %%$ in ^(1^) Do DosKey') Do Set "ESC=%%_"

  83.         )

  85. %= } =%
  86. @Goto :Eof

  88. %================================================================%
  89. %= 日期: 2022 年 9 月 9 日 =%
  90. %= 名称: GotoXY =%
  91. %= 作用: 定位光标到指定位置 =%
  92. %= 参数: X 光标的 X 轴坐标，如果省略或设为 0，则设其为1 =%
  93. %= 参数: Y 光标的 Y 轴坐标，如果省略或设为 0，则设其为1 =%
  94. %================================================================%
  95. :GotoXY <X> <Y>
  96. %= { =%

  98.         %= 如果没有定义 ESC 字符 =%
  99.         If Not Defined ESC (

  101.                 @Call :InitVT100

  103.         )

  105.         %= 定位光标 =%
  106.         Set /P=%ESC%[%2;%1H< Nul

  108. %= } =%
  109. @Goto :Eof

  111. %================================================================%
  112. %= 日期: 2022 年 9 月 9 日 =%
  113. %= 名称: SetConsoleTextAttribute =%
  114. %= 作用: 设置控制台文本颜色 =%
  115. %= 参数: BGCOL 背景 RGB 颜色值，格式为R-G-B =%
  116. %= 参数: FGCOL 前景 RGB 颜色值，格式为R-G-B =%
  117. %================================================================%
  118. :SetConsoleTextAttribute <BGCOL> <FGCOL>
  119. %= { =%

  121.         %= 如果没有定义 ESC 字符 =%
  122.         If Not Defined ESC (

  124.                 @Call :InitVT100

  126.         )

  128.         %= 设置背景色 =%
  129.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%1") Do (
  130.                 Set /P=%ESC%[48;2;%%I;%%J;%%Km< Nul
  131.         )

  133.         %= 设置前景色 =%
  134.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%2") Do (
  135.                 Set /P=%ESC%[38;2;%%I;%%J;%%Km< Nul
  136.         )

  138. %= } =%
  139. @Goto :Eof

  141. %================================================================%
  142. %= 日期: 2022 年 9 月 9 日 =%
  143. %= 名称: SetConsoleCursorInfo =%
  144. %= 作用: 设置控制台光标属性 =%
  145. %= 参数: CursorVisibility 光标可见和闪烁状态，取值1~4，分别为： =%
  146. %=       1 显示光标 =%
  147. %=       2 隐藏光标 =%
  148. %=       3 开始光标闪烁 =%
  149. %=       4 停止闪烁光标 =%
  150. %= 参数: CursorShape      自定义光标形状，取值0~6，分别为： =%
  151. %=       0 用户配置的默认光标形状 =%
  152. %=       1 闪烁块光标形状 =%
  153. %=       2 稳定块光标形状 =%
  154. %=       3 闪烁下划线光标形状 =%
  155. %=       4 稳定下划线光标形状 =%
  156. %=       5 闪烁条形光标形状 =%
  157. %=       6 稳定条形光标形状 =%
  158. %================================================================%
  159. :SetConsoleCursorInfo <CursorVisibility> <CursorShape>
  160. %= { =%

  162.         %= 如果没有定义 ESC 字符 =%
  163.         If Not Defined ESC (

  165.                 @Call :InitVT100

  167.         )

  169.         %= 设置光标可见和闪烁状态 =%
  170.         For /F "Delims=-, Tokens=%1" %%I in ("25h-25l-12h-12l") Do (
  171.                 Set /P=%ESC%[?%%I< Nul
  172.         )

  174.         Set /P=%ESC%[%2 q< Nul

  176. %= } =%
  177. @Goto :Eof

  179. %================================================================%
  180. %= 日期: 2022 年 9 月 9 日 =%
  181. %= 名称: SetConsoleTextAttributeEx =%
  182. %= 作用: 格式化控制台文本 =%
  183. %= 参数: Code 操作代码，取值1~6，分别为： =%
  184. %=       1 默认，通常相当于Color 07 =%
  185. %=       2 粗体/亮 =%
  186. %=       3 无粗体/亮 =%
  187. %=       4 下划线 =%
  188. %=       5 无下划线 =%
  189. %=       6 交换前景色和背景色 =%
  190. %================================================================%
  191. :SetConsoleTextAttributeEx <Code>
  192. %= { =%

  194.         %= 如果没有定义 ESC 字符 =%
  195.         If Not Defined ESC (

  197.                 @Call :InitVT100

  199.         )

  201.         For /F "Delims=-, Tokens=%1" %%I in ("0-1-22-4-24-7") Do (
  202.                 Set /P=%ESC%[%%Im< Nul
  203.         )

  205. %= } =%
  206. @Goto :Eof
复制代码
运行效果：

评分

参与人数 3PB +14 技术 +2 收起 理由
CrLf + 8 + 1 感谢分享
老刘1号 + 6 +6
ANSL + 1 说的是我吗?厉害!

查看全部评分

回复

举报

HOPE2021
 楼主| 发表于 2022-9-10 20:00:59 | 显示全部楼层
本帖最后由 HOPE2021 于 2022-9-11 21:47 编辑

今天是中秋节，我以此作品祝大家中秋节快乐：
  1. @Mode Con: Cols=160 Lines=20 & Chcp 437 > Nul & Title Happy Mid-Autumn Day! & @SetLocal EnableExtensions EnableDelayedExpansion & @Echo Off
  2. %= 利用 VT100 虚拟终端序列来制作绘图引擎的实例 =%
  3. %= 此程序必须保存为ANSI编码 =%
  4. If "%1"=="" (
  5.         For %%a in (        FontSize:0006000C
  6.         ) Do For /F "tokens=1,2 delims=:" %%b in ("%%a") do (
  7.                 > Nul Reg Add HKCU\Console\Happy_Mid_Autumn_Day /V %%b /T Reg_DWORD /D 0x%%c /F
  8.         )
  9.         Start "Happy_Mid_Autumn_Day" "%ComSpec%" /C "%~s0" 1 & @Goto :Eof

  11. ) Else (
  12.         > Nul Reg Delete HKCU\Console\Happy_Mid_Autumn_Day /F
  13. )
  14. @Goto :Main

  16. :Main
  17.         @Call :Ani
  18.         Pause > Nul
  19. @Exit /B 0

  21. :Ani
  22.         Set "Chr[1]=0x0100,0x0100,0x0104,0x7FFE,0x4104,0x4104,0x4104,0x4104,0x7FFC,0x4104,0x0100,0x0100,0x0100,0x0100,0x0100,0x0100"
  23.         Set "Chr[2]=0x0840,0x1C40,0xF040,0x1040,0x1144,0xFD4C,0x1150,0x3240,0x3840,0x54A0,0x50A0,0x9110,0x1108,0x120E,0x1404,0x1800"
  24.         Set "Chr[3]=0x1080,0x1080,0x1080,0x1088,0x5BFC,0x5488,0x5088,0x9088,0x1088,0x1FFE,0x1080,0x1140,0x1120,0x1210,0x140E,0x1804"
  25.         Set "Chr[4]=0x0020,0x00F0,0x1F00,0x1000,0x1100,0x1100,0x2104,0x7FFE,0x0100,0x0100,0x0920,0x0910,0x1108,0x210C,0x4504,0x0200"
  26.         @Call :SetConsoleCursorInfo 2 2
  27.         @Call :SetConsoleTextAttribute 0-0-0 251-193-1
  28.         Cls
  29.         @Call :DrawMoon
  30.         @Call :SetConsoleTextAttribute 0-0-0 16-132-186
  31.         @Call :DrawChr 22 3 "%Chr[1]%"
  32.         @Call :DrawChr 57 3 "%Chr[2]%"
  33.         @Call :DrawChr 92 3 "%Chr[3]%"
  34.         @Call :DrawChr 127 3 "%Chr[4]%"
  35. @Goto :Eof

  37. %================================================================%
  38. %= 日期: 2022 年 9 月 10 日 =%
  39. %= 名称: DrawMoon =%
  40. %= 作用: 输出月亮 =%
  41. %= 备注: 此函数要访问环境变量 _x_ / _y_ / _Temp_ =%
  42. %================================================================%
  43. :DrawMoon
  44. %={=%
  45.         Set _x_=1
  46.         Set _y_=1
  47.         For /L %%_ in (1,1,11) Do (
  48.                         Set /A "_y_=%%_"
  49.                 For /L %%? in (1,1,11) Do (
  50.                         Set /A "_x_=%%?"
  51.                         Set /A "_Temp_=!_x_!*!_x_!+!_y_!*!_y_!-121"
  52.                         If !_Temp_! Leq 0 Set /P=圹< Nul
  53.                 )
  54.                 @Call :GotoXY 1 %%_
  55.         )       
  56. %={=%
  57. @Goto :Eof

  59. %================================================================%
  60. %= 日期: 2022 年 9 月 10 日 =%
  61. %= 名称: DrawChr =%
  62. %= 作用: 输出点阵字符 =%
  63. %= 参数: x 字符左上角 X 轴坐标 =%
  64. %= 参数: y 字符左上角 Y 轴坐标 =%
  65. %= 参数: Code 点阵数据 =%
  66. %= 备注: 此函数要访问环境变量 _._ / _.._ / _..._ / _x_ / _y_ =%
  67. %================================================================%
  68. :DrawChr <x> <y> <Code>
  69. %={=%
  70.         Set /A "_x_=%1"
  71.         Set /A "_y_=%2"
  72.         For %%_ in (%~3) Do (
  73.                 Set "_..._="
  74.                 Set /A "_.._=0"
  75.                 Set /A "_._=%%_"
  76.                 For /L %%? in (0,1,15) Do (
  77.                         Set /A "_.._=!_._!%%2"
  78.                         Set "_..._=!_.._!!_..._!"
  79.                         Set /A "_._=!_._!-!_.._!"
  80.                         Set /A "_._=_._/2"
  81.                 )
  82.                 Set _..._=!_..._:1=圹!
  83.                 Set _..._=!_..._:0=  !
  84.                 Call :GotoXY !_x_! !_y_!
  85.                 Echo.!_..._!
  86.                 Set /A "_y_+=1"
  87.                 %= 下面这句是为了让画面更有年代感，可以删去 =%
  88.                 Help > Nul 2> Nul
  89.         )
  90.         Echo.
  91. %=}=%
  92. @Goto :Eof

  94. %================================================================================================================================%
  95. %= VT100 函数 =%
  96. %================================================================================================================================%

  98. %================================================================%
  99. %= 日期: 2022 年 9 月 9 日 =%
  100. %= 名称: InitVT100 =%
  101. %= 作用: 初始化 Windows 10 的 虚拟终端序列 =%
  102. %================================================================%
  103. :InitVT100
  104. %= { =%

  106.         %= 获取 ESC 字符 =%

  108.         Set "ESC="

  110.         %= 如果没有定义 ESC 字符，这个过程是为了防止论坛误吞上文的 ESC 字符 =%
  111.         If Not Defined ESC (

  113.                 For /F "Delims=#" %%_ in ('Prompt #$E# ^& Echo On ^& For %%$ in ^(1^) Do DosKey') Do Set "ESC=%%_"

  115.         )

  117. %= } =%
  118. @Goto :Eof

  120. %================================================================%
  121. %= 日期: 2022 年 9 月 9 日 =%
  122. %= 名称: GotoXY =%
  123. %= 作用: 定位光标到指定位置 =%
  124. %= 参数: X 光标的 X 轴坐标，如果省略或设为 0，则设其为1 =%
  125. %= 参数: Y 光标的 Y 轴坐标，如果省略或设为 0，则设其为1 =%
  126. %================================================================%
  127. :GotoXY <X> <Y>
  128. %= { =%

  130.         %= 如果没有定义 ESC 字符 =%
  131.         If Not Defined ESC (

  133.                 @Call :InitVT100

  135.         )

  137.         %= 定位光标 =%
  138.         Set /P=%ESC%[%2;%1H< Nul

  140. %= } =%
  141. @Goto :Eof

  143. %================================================================%
  144. %= 日期: 2022 年 9 月 9 日 =%
  145. %= 名称: SetConsoleTextAttribute =%
  146. %= 作用: 设置控制台文本颜色 =%
  147. %= 参数: BGCOL 背景 RGB 颜色值，格式为R-G-B =%
  148. %= 参数: FGCOL 前景 RGB 颜色值，格式为R-G-B =%
  149. %================================================================%
  150. :SetConsoleTextAttribute <BGCOL> <FGCOL>
  151. %= { =%

  153.         %= 如果没有定义 ESC 字符 =%
  154.         If Not Defined ESC (

  156.                 @Call :InitVT100

  158.         )

  160.         %= 设置背景色 =%
  161.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%1") Do (
  162.                 Set /P=%ESC%[48;2;%%I;%%J;%%Km< Nul
  163.         )

  165.         %= 设置前景色 =%
  166.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%2") Do (
  167.                 Set /P=%ESC%[38;2;%%I;%%J;%%Km< Nul
  168.         )

  170. %= } =%
  171. @Goto :Eof

  173. %================================================================%
  174. %= 日期: 2022 年 9 月 9 日 =%
  175. %= 名称: SetConsoleCursorInfo =%
  176. %= 作用: 设置控制台光标属性 =%
  177. %= 参数: CursorVisibility 光标可见和闪烁状态，取值1~4，分别为： =%
  178. %=       1 显示光标 =%
  179. %=       2 隐藏光标 =%
  180. %=       3 开始光标闪烁 =%
  181. %=       4 停止闪烁光标 =%
  182. %= 参数: CursorShape      自定义光标形状，取值0~6，分别为： =%
  183. %=       0 用户配置的默认光标形状 =%
  184. %=       1 闪烁块光标形状 =%
  185. %=       2 稳定块光标形状 =%
  186. %=       3 闪烁下划线光标形状 =%
  187. %=       4 稳定下划线光标形状 =%
  188. %=       5 闪烁条形光标形状 =%
  189. %=       6 稳定条形光标形状 =%
  190. %================================================================%
  191. :SetConsoleCursorInfo <CursorVisibility> <CursorShape>
  192. %= { =%

  194.         %= 如果没有定义 ESC 字符 =%
  195.         If Not Defined ESC (

  197.                 @Call :InitVT100

  199.         )

  201.         %= 设置光标可见和闪烁状态 =%
  202.         For /F "Delims=-, Tokens=%1" %%I in ("25h-25l-12h-12l") Do (
  203.                 Set /P=%ESC%[?%%I< Nul
  204.         )

  206.         Set /P=%ESC%[%2 q< Nul

  208. %= } =%
  209. @Goto :Eof

  211. %================================================================%
  212. %= 日期: 2022 年 9 月 9 日 =%
  213. %= 名称: SetConsoleTextAttributeEx =%
  214. %= 作用: 格式化控制台文本 =%
  215. %= 参数: Code 操作代码，取值1~6，分别为： =%
  216. %=       1 默认，通常相当于Color 07 =%
  217. %=       2 粗体/亮 =%
  218. %=       3 无粗体/亮 =%
  219. %=       4 下划线 =%
  220. %=       5 无下划线 =%
  221. %=       6 交换前景色和背景色 =%
  222. %================================================================%
  223. :SetConsoleTextAttributeEx <Code>
  224. %= { =%

  226.         %= 如果没有定义 ESC 字符 =%
  227.         If Not Defined ESC (

  229.                 @Call :InitVT100

  231.         )

  233.         For /F "Delims=-, Tokens=%1" %%I in ("0-1-22-4-24-7") Do (
  234.                 Set /P=%ESC%[%%Im< Nul
  235.         )

  237. %= } =%
  238. @Goto :Eof
复制代码

评分

参与人数 1PB +18 技术 +1 收起 理由
523066680 + 18 + 1 支持一下

查看全部评分

回复

举报

HOPE2021
 楼主| 发表于 2022-9-11 12:08:26 | 显示全部楼层
VT100绘图引擎实例3，进度条时钟：
  1. @Mode Con: Cols=128 Lines=9 & Chcp 437 > Nul & Title Clock & @SetLocal EnableExtensions EnableDelayedExpansion & @Echo Off
  2. %= 利用 VT100 虚拟终端序列来制作绘图引擎的实例 =%
  3. %= 此程序必须保存为ANSI编码 =%
  4. @Goto :Main

  6. :Main
  7.         @Call :SetConsoleTextAttribute 0-0-0 58-150-221
  8.         @Cls
  9.         @Call :SetConsoleCursorInfo 2 0
  10.         @Call :Show
  11. @Exit /B 0

  13. :Show
  14.         @Call :GotoXY 61 2
  15.         @Call :SetConsoleTextAttribute 0-0-0 58-150-221
  16.         Set _Temp_Time_=%Time:~0,8%
  17.         Set /P=#%_Temp_Time_%< Nul
  18.         Set _Temp_Time_=%_Temp_Time_: =0+%
  19.         Set _Temp_Time_=%_Temp_Time_::0=:0+%

  21.         Set "Block=圹"
  22.         Set "Block=%Block:~0,1%"

  24.         For /F "Delims=:, Tokens=1,2,3" %%i in ("%_Temp_Time_%") Do (
  25.                 Set /A _Temp_H_=%%i
  26.                 Set /A _Temp_M_=%%j
  27.                 Set /A _Temp_S_=%%k
  28.         )

  30.         @Call :SetConsoleTextAttribute 255-255-255 58-150-221

  32.         @Call :GotoXY 5 4
  33.         For /L %%i in (0,1,23) Do (
  34.                 For /L %%j in (0,1,4) Do (
  35.                         If %%i Lss !_Temp_H_! (
  36.                                 Set /P=#%Block%< Nul
  37.                         ) Else Set /P=# < Nul
  38.                 )
  39.         )

  41.         @Call :GotoXY 5 6
  42.         For /L %%i in (0,1,59) Do (
  43.                 For /L %%j in (0,1,1) Do (
  44.                         If %%i Lss !_Temp_M_! (
  45.                                 Set /P=#%Block%< Nul
  46.                         ) Else Set /P=# < Nul
  47.                 )
  48.         )

  50.         @Call :GotoXY 5 8
  51.         For /L %%i in (0,1,59) Do (
  52.                 For /L %%j in (0,1,1) Do (
  53.                         If %%i Lss !_Temp_S_! (
  54.                                 Set /P=#%Block%< Nul
  55.                         ) Else Set /P=# < Nul
  56.                 )
  57.         )

  59. @Goto :Show

  61. %================================================================================================================================%
  62. %= VT100 函数 =%
  63. %================================================================================================================================%

  65. %================================================================%
  66. %= 日期: 2022 年 9 月 9 日 =%
  67. %= 名称: InitVT100 =%
  68. %= 作用: 初始化 Windows 10 的 虚拟终端序列 =%
  69. %================================================================%
  70. :InitVT100
  71. %= { =%

  73.         %= 获取 ESC 字符 =%

  75.         Set "ESC="

  77.         %= 如果没有定义 ESC 字符，这个过程是为了防止论坛误吞上文的 ESC 字符 =%
  78.         If Not Defined ESC (

  80.                 For /F "Delims=#" %%_ in ('Prompt #$E# ^& Echo On ^& For %%$ in ^(1^) Do DosKey') Do Set "ESC=%%_"

  82.         )

  84. %= } =%
  85. @Goto :Eof

  87. %================================================================%
  88. %= 日期: 2022 年 9 月 9 日 =%
  89. %= 名称: GotoXY =%
  90. %= 作用: 定位光标到指定位置 =%
  91. %= 参数: X 光标的 X 轴坐标，如果省略或设为 0，则设其为1 =%
  92. %= 参数: Y 光标的 Y 轴坐标，如果省略或设为 0，则设其为1 =%
  93. %================================================================%
  94. :GotoXY <X> <Y>
  95. %= { =%

  97.         %= 如果没有定义 ESC 字符 =%
  98.         If Not Defined ESC (

  100.                 @Call :InitVT100

  102.         )

  104.         %= 定位光标 =%
  105.         Set /P=%ESC%[%2;%1H< Nul

  107. %= } =%
  108. @Goto :Eof

  110. %================================================================%
  111. %= 日期: 2022 年 9 月 9 日 =%
  112. %= 名称: SetConsoleTextAttribute =%
  113. %= 作用: 设置控制台文本颜色 =%
  114. %= 参数: BGCOL 背景 RGB 颜色值，格式为R-G-B =%
  115. %= 参数: FGCOL 前景 RGB 颜色值，格式为R-G-B =%
  116. %================================================================%
  117. :SetConsoleTextAttribute <BGCOL> <FGCOL>
  118. %= { =%

  120.         %= 如果没有定义 ESC 字符 =%
  121.         If Not Defined ESC (

  123.                 @Call :InitVT100

  125.         )

  127.         %= 设置背景色 =%
  128.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%1") Do (
  129.                 Set /P=%ESC%[48;2;%%I;%%J;%%Km< Nul
  130.         )

  132.         %= 设置前景色 =%
  133.         For /F "Delims=-, Tokens=1,2,3" %%I in ("%2") Do (
  134.                 Set /P=%ESC%[38;2;%%I;%%J;%%Km< Nul
  135.         )

  137. %= } =%
  138. @Goto :Eof

  140. %================================================================%
  141. %= 日期: 2022 年 9 月 9 日 =%
  142. %= 名称: SetConsoleCursorInfo =%
  143. %= 作用: 设置控制台光标属性 =%
  144. %= 参数: CursorVisibility 光标可见和闪烁状态，取值1~4，分别为： =%
  145. %=       1 显示光标 =%
  146. %=       2 隐藏光标 =%
  147. %=       3 开始光标闪烁 =%
  148. %=       4 停止闪烁光标 =%
  149. %= 参数: CursorShape      自定义光标形状，取值0~6，分别为： =%
  150. %=       0 用户配置的默认光标形状 =%
  151. %=       1 闪烁块光标形状 =%
  152. %=       2 稳定块光标形状 =%
  153. %=       3 闪烁下划线光标形状 =%
  154. %=       4 稳定下划线光标形状 =%
  155. %=       5 闪烁条形光标形状 =%
  156. %=       6 稳定条形光标形状 =%
  157. %================================================================%
  158. :SetConsoleCursorInfo <CursorVisibility> <CursorShape>
  159. %= { =%

  161.         %= 如果没有定义 ESC 字符 =%
  162.         If Not Defined ESC (

  164.                 @Call :InitVT100

  166.         )

  168.         %= 设置光标可见和闪烁状态 =%
  169.         For /F "Delims=-, Tokens=%1" %%I in ("25h-25l-12h-12l") Do (
  170.                 Set /P=%ESC%[?%%I< Nul
  171.         )

  173.         Set /P=%ESC%[%2 q< Nul

  175. %= } =%
  176. @Goto :Eof

  178. %================================================================%
  179. %= 日期: 2022 年 9 月 9 日 =%
  180. %= 名称: SetConsoleTextAttributeEx =%
  181. %= 作用: 格式化控制台文本 =%
  182. %= 参数: Code 操作代码，取值1~6，分别为： =%
  183. %=       1 默认，通常相当于Color 07 =%
  184. %=       2 粗体/亮 =%
  185. %=       3 无粗体/亮 =%
  186. %=       4 下划线 =%
  187. %=       5 无下划线 =%
  188. %=       6 交换前景色和背景色 =%
  189. %================================================================%
  190. :SetConsoleTextAttributeEx <Code>
  191. %= { =%

  193.         %= 如果没有定义 ESC 字符 =%
  194.         If Not Defined ESC (

  196.                 @Call :InitVT100

  198.         )

  200.         For /F "Delims=-, Tokens=%1" %%I in ("0-1-22-4-24-7") Do (
  201.                 Set /P=%ESC%[%%Im< Nul
  202.         )

  204. %= } =%
  205. @Goto :Eof
复制代码

评分

参与人数 1PB +12 技术 +1 收起 理由
523066680 + 12 + 1 支持一下

查看全部评分

回复

举报

帝尊
发表于 2022-9-14 18:21:47 | 显示全部楼层
本帖最后由 帝尊 于 2022-9-14 18:48 编辑

回复 3# HOPE2021


    为什么我运行后进度条是σσσσσ这个符号？？

保存为ANSI后变成？？？？号了。

抱歉，应该是我系统是英文的原因。
回复

举报

HOPE2021
 楼主| 发表于 2022-9-14 19:33:11 | 显示全部楼层
回复 4# 帝尊
试试看用Visual Studio Code编辑，另存为GB2312编码
回复

举报

帝尊
发表于 2022-9-14 20:22:47 | 显示全部楼层
回复 5# HOPE2021


    改了编码的确正常了。不得不说，大神做的这个东西很有启发，牛逼！
回复

举报

ANSL
发表于 2022-9-16 08:19:36 | 显示全部楼层
很厉害，但是写程序多考虑兼容性问题，因为现在还有很多人用win7,xp
回复

举报

HOPE2021
 楼主| 发表于 2022-9-16 21:30:58 | 显示全部楼层
回复 7# ANSL
您说得很有道理，但事物总有落伍的时候，很多早先的东西都不支持了。现在VT100转义正在壮大，应该尽早赶上国际潮流。此外，兼容的问题也可以最大化减小，VT100转义序列和早期的ANSI是有部分相同的，可以判断版本然后决定使用VT100转义还是ANSI，早期Windows使用ANSI的方法见：
http://www.bathome.net/viewthread.php?tid=8509&highlight=ANSI
回复

举报

ANSL
发表于 2022-9-17 10:32:28 | 显示全部楼层
本帖最后由 ANSL 于 2022-9-17 10:39 编辑

回复 8# HOPE2021我倒是可以接受新事物，但findstr绘图引擎却是最实用的，可以在新系统上运行，也可以在XP运行,(本人电脑win10),(个人感觉)
见:[转载自Dostips] 游戏 劳里的幻想世界 - BAT求助&讨论 - 批处理之家 批处理_BAT脚本_PowerShell_VBS_CMD_DOS_Perl_Python - Powered by Discuz! (bathome.net)对，比如之前的findstr,debug,第三方,16位程序.......
我还是希望尽早淘汰win7,xp我之前也想写这么个东西，没时间，因为兼容性闹心
尝试把VT100技术做成可以被rundll32执行的dll，可惜不行
回复

举报

HOPE2021
 楼主| 发表于 2022-9-17 10:47:27 | 显示全部楼层
本帖最后由 HOPE2021 于 2022-9-17 10:54 编辑

回复 9# ANSL
虽然FindStr能完成日常所需的图形绘制，但功能未免太弱小了，根本不可能彩显特殊字符，像下面两个作品根本不可能用FindStr实现：
https://www.dostips.com/forum/viewtopic.php?f=3&t=8044
https://www.dostips.com/forum/viewtopic.php?f=3&t=8056
而且FindStr的速度太慢，支持的颜色太少，下面的功能就很难用FindStr实现：
https://www.dostips.com/forum/viewtopic.php?f=3&t=9869

评分

参与人数 1技术 +1 收起 理由
ANSL + 1 没错!我看中了VT100的功能!

查看全部评分

回复

举报

bat1152
发表于 2023-1-31 17:51:53 | 显示全部楼层
回复 3# HOPE2021

牛逼啊……
回复

举报

dos-a
发表于 2023-4-9 14:17:05 | 显示全部楼层
回复 11# bat1152


   大佬&#128514;&#128514;
回复

举报

老刘1号
发表于 2023-4-9 22:28:18 | 显示全部楼层
本帖最后由 老刘1号 于 2023-4-9 22:39 编辑

楼主会玩，我也给我的帖子搞几张图去，嘿嘿
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-17 02:45 , Processed in 0.025353 second(s), 9 queries , File On.

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表