[已解决]批处理文本替换问题

pd1

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. 
   
4. set "str=xxx123456yyy"
   
5. echo !str!
   
6. set /p Choice1=请输入:
   
7. set "str=!str:123=%Choice1%!"
   
8. echo !str!
   
9. set /p Choice2=请输入:
   
10. set "str=!str:456=%Choice2%!"
    
11. echo !str!
    
12. 
    
13. pause

复制代码

这样替换文本是可以的。

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (1.ini) do (
   
4. set "str=%%i"
   
5. echo !str!
   
6. set /p Choice1=请输入:
   
7. set "str=!str:123=%Choice1%!"
   
8. echo !str!
   
9. set /p Choice2=请输入:
   
10. set "str=!str:456=%Choice2%!"
    
11. echo !str!
    
12. 
    
13. )
    
14. pause

复制代码

从文件里把这字符串读出来就不行。

Batcher

回复 1# pd1


请参考Q-01观察一下哪行代码在报错：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

请参考Q-04和Q-05把bat文件和ini文件都保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

pd1

回复 2# Batcher

1. 
   
2. D:\1\test>setlocal enabledelayedexpansion
   
3. 
   
4. D:\1\test>for /F "delims=" %i in (D:\1\test\1.ini) do (
   
5. set "str=%i"
   
6. echo !str!
   
7. set /p Choice1=请输入:
   
8. set "str=!str:123=!"
   
9. echo !str!
   
10. set /p Choice2=请输入:
    
11. set "str=!str:456=!"
    
12. echo !str!
    
13. )
    
14. 
    
15. D:\1\test>(
    
16. set "str=xxx123456yyy"
    
17. echo !str!
    
18. set /p Choice1=请输入:
    
19. set "str=!str:123=!"
    
20. echo !str!
    
21. set /p Choice2=请输入:
    
22. set "str=!str:456=!"
    
23. echo !str!
    
24. )
    
25. xxx123456yyy
    
26. 请输入:aaa
    
27. xxx456yyy
    
28. 请输入:bbb
    
29. xxxyyy
    
30. 
    
31. D:\1\test>pause
    
32. Press any key to continue . . .

复制代码

flashercs

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (1.ini) do (
   
4. set "str=%%i"
   
5. echo !str!
   
6. set /p Choice1=请输入:
   
7. call set "str=!str:123=%%Choice1%%!"
   
8. echo !str!
   
9. set /p Choice2=请输入:
   
10. call set "str=!str:456=%%Choice2%%!"
    
11. echo !str!
    
12. 
    
13. )
    
14. pause

复制代码

went

set "str=!str:456=%Choice2%!" 改成这样
call set "str=%%str:123=!Choice1!%%"
不然for里面取不到chouce1的值

flashercs

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in (1.ini) do (
   
4. set "str=%%i"
   
5. echo !str!
   
6. set /p Choice1=请输入:
   
7. for %%A in (!Choice1!) do (
   
8.   set "str=!str:123=%%A!"
   
9. )
   
10. echo !str!
    
11. set /p Choice2=请输入:
    
12. for %%A in (!Choice2!) do (
    
13.   set "str=!str:456=%%A!"
    
14. )
    
15. echo !str!
    
16. 
    
17. )
    
18. pause

复制代码

pd1

谢谢各位大佬的热心解答。