[已解决]全盘查找文件的批处理只能显示第一个，可以全部都显示出来吗？

小渣飞

1. @echo off&title 全盘查找。&color 0f
   
2. set /p var1=要查找的文件？[需添加文件扩展名，如需查找同类文件可使用*.*]：
   
3. If "%var1%"=="" echo 不能为空。&pause>nul&exit
   
4. title 正在查找%var1%中... ...
   
5. echo.
   
6. color 07&echo 正在全盘查找文件[%var1%]
   
7. echo.
   
8. 
   
9. for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
   
10. if exist %%a:\ (
    
11. cd /d %%a:\
    
12. for /f "delims=" %%b in ('dir /s /a-d /b %var1%') do (
    
13. if exist "%%b" (
    
14. echo 文件已找到。[%%b]>%temp%\found.txt))))
    
15. color 0f
    
16. type %temp%\found.txt
    
17. echo.
    
18. echo 查找完毕，已生成文本报告。[%temp%\found.txt]&pause>nul

复制代码

flashercs

1. @echo off&title 全盘查找。&color 0f
   
2. set /p var1=要查找的文件？[需添加文件扩展名，如需查找同类文件可使用*.*]：
   
3. If "%var1%"=="" echo 不能为空。&pause>nul&exit
   
4. title 正在查找%var1%中... ...
   
5. echo.
   
6. color 07&echo 正在全盘查找文件[%var1%]
   
7. echo.
   
8. (
   
9. for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
   
10. if exist %%a:\ (
    
11. cd /d %%a:\
    
12. for /f "delims=" %%b in ('dir /s /a-d /b %var1%') do (
    
13. if exist "%%b" (
    
14. echo 文件已找到。[%%b]))))
    
15. )>%temp%\found.txt
    
16. color 0f
    
17. type %temp%\found.txt
    
18. echo.
    
19. echo 查找完毕，已生成文本报告。[%temp%\found.txt]&pause>nul

复制代码

Batcher

回复 1# 小渣飞


    把第14行的>改成>>

小渣飞

额，，，粗心了没发现=-=

小渣飞

挺方便的哈哈

@echo off&title 全盘查找。&color 0f
:return
rem 避免文件意外重复
set num=%random%
if exist %temp%\found_%num%.txt (goto return)
echo.>%temp%\found_%num%.txt
set "var="
set /p var=要查找的文件？[需添加文件扩展名，如查找同类文件可使用通配符*.*]：
If "%var%"=="" (cls&echo 不能为空。&pause>nul&exit)
title 正在查找%var%中... ...
echo :::::::::::::::::::: %date% / %time% Start ::::::::::::::::::::>>%temp%\found_%num%.txt
echo.>>%temp%\found_%num%.txt
echo.
color 07&echo 正在全盘查找文件[%var%]
echo.
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
cd /d %%a:\
for /f "delims=" %%b in ('dir /s /a-d /b %var%') do (
if exist "%%b" (
echo 文件已找到。["%%b"]>>%temp%\found_%num%.txt))))
echo.>>%temp%\found_%num%.txt
echo ::::::::::::::::::: %date% / %time% Finished :::::::::::::::::::>>%temp%\found_%num%.txt
color 0f&type %temp%\found_%num%.txt
echo.
title 查找完毕，已生成文本报告。[%temp%\found_%num%.txt]
echo 查找完毕，已生成文本报告。[%temp%\found_%num%.txt]&pause>nul

impk

echo  %date% / %time% Start
echo  %date% / %time% Finished

又学了一招，测脚本执行时间