[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程批处理在线视频分享
返回列表 发帖

[其他] 批处理如何显示大字体

本帖最后由 pcl_test 于 2018-1-8 11:26 编辑

求把显示IP的字变得很大,方便年纪多大的职员看IP
这个批处理如何让IP显示很大的字


@echo off
COLOR 0A
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
echo, 本机IP: %ip%
pause

本帖最后由 yhcfsr 于 2018-1-8 14:19 编辑

回复 1# rodck


    办法有,但没有完美的。
运行一次,结束后不要按回车。再运行一次就会有效果,按回车会清除修改结果。
这是全局修改,所以运行别的BAT也会应用修改结果,就这样吧。没有什么好办法。
  1. @echo off
  2. COLOR 0A
  3. if "%1"=="" goto :set_cmd
  4. for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
  5. echo, 本机IP: %ip%
  6. set/p input=按回车恢复默认字体
  7. if "%input%"=="" (reg delete "HKCU\Console\%%SystemRoot%%_system32_cmd.exe"  /f 2>nul)
  8. exit
  9. :set_cmd
  10. set reg_key="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
  11. reg delete %reg_key% /f 2>nul
  12. reg add %reg_key% /v "WindowPosition" /t REG_DWORD /d 0x01f0064 /f>nul
  13. reg add %reg_key% /v "WindowSize" /t REG_DWORD /d 0x01190050 /f>nul
  14. reg add %reg_key% /v "ScreenBufferSize" /t REG_DWORD /d 0xf0190050 /f>nul
  15. reg add %reg_key% /v "FullScreen" /t REG_DWORD /d 0x00000001 /f>nul
  16. reg add %reg_key% /v "FontSize" /t REG_DWORD /d 0x00200008 /f>nul
  17. call %~0 CmdSet &exit
复制代码
或者把设置语句单独写成一个脚本,实现这样的效果:运动脚本,如果检测到修改过显示,则恢复,否则修改显示效果。相当于开关,按下开,再按下就关。
而且,在这个设置脚本里调用ip.bat则运行一次就能应用显示效果。

TOP

去学去写去用才有进步。安装python3代码存为xx.py 双击运行或右键用IDLE打开按F5运行

TOP

本帖最后由 codegay 于 2018-1-9 04:03 编辑

SetCurrentConsoleFontEx windows 7支持这个API

https://docs.microsoft.com/en-us ... urrentconsolefontex
去学去写去用才有进步。安装python3代码存为xx.py 双击运行或右键用IDLE打开按F5运行

TOP

试用了二楼的代码,出现问题。

现在我的电脑win7所有的bat,双击bat后,隐藏运行。任务管理器里有,含建文件夹的会建,没有了交互的界面。

请问如何还原。
目的,学习批处理

TOP

回复 5# hlzj88
  1. set reg_key="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
  2. reg delete %reg_key% /f 2>nul
复制代码
保存为bat运行就可以恢复

TOP

本帖最后由 bbaa 于 2018-1-9 22:10 编辑

回复 5# hlzj88
  1. @echo off
  2. @if Not "%1"=="BigFont" (Goto :BigFont)
  3. COLOR 0A
  4. for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
  5. echo, 本机IP: %ip%
  6. pause>nul&exit
  7. :BigFont
  8. reg query "HKCU/Console/BigFont">nul 2>nul&&(
  9. start "BigFont" %ComSpec% /c %~f0 BigFont&exit /b
  10. )||(
  11. set ran=%random%
  12. more +16 %~f0>%temp%\%ran%BigFont.reg
  13. reg import "%temp%\%ran%BigFont.reg">nul 2>nul||(echo 注册表导入失败,请你确定允许导入注册表&pause>nul&exit)
  14. del /f /q "%temp%\%ran%BigFont.reg">nul 2>nul
  15. start "BigFont" %ComSpec% /c %~f0 BigFont&exit /b
  16. )
  17. Windows Registry Editor Version 5.00
  18. [HKEY_CURRENT_USER\Console\BigFont]
  19. "FaceName"="新宋体"
  20. "FontFamily"=dword:00000036
  21. "FontSize"=dword:00180000
  22. "FontWeight"=dword:00000190
  23. "WindowSize"=dword:00020019
复制代码
代码共23行,如测试成功,请不要忘记给我加分
注:本代码只对当前bat有效
1

评分人数

    • hlzj88: 嗯嗯,隐藏窗口用的上。技术 + 1

TOP

本帖最后由 zaqmlp 于 2018-1-10 12:00 编辑
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. mode con cols=140 lines=10
  4. color 0a
  5. set "#0=  "
  6. set "#1=■■■■"
  7. set "#2=■    ■"
  8. set "#3=■      "
  9. set "#4=      ■"
  10. set "#5=■"
  11. set _#0=1,2,2,2,2,2,1
  12. set _#1=5,5,5,5,5,5,5
  13. set _#2=1,4,4,1,3,3,1
  14. set _#3=1,4,4,1,4,4,1
  15. set _#4=2,2,2,1,4,4,4
  16. set _#5=1,3,3,1,4,4,1
  17. set _#6=1,3,3,1,2,2,1
  18. set _#7=1,4,4,4,4,4,4
  19. set _#8=1,2,2,1,2,2,1
  20. set _#9=1,2,2,1,4,4,1
  21. set _#.=0,0,0,0,0,0,5
  22. for /f tokens^=1^,2^ delims^=^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do set ip=%%b
  23. set s=%ip%fedcba9876543210&set /a len=0x!s:~15,1!-1
  24. echo;本机IP: %ip%
  25. if defined ip (
  26.     for /l %%a in (1 1 7) do (
  27.         for /l %%b in (0 1 %len%) do (
  28.             for %%c in (!ip:~%%b^,1!) do (
  29.                 set m=1
  30.                 for %%d in (!_#%%c!) do (
  31.                     if !m! equ %%a set "##%%a=!##%%a!!#%%d!  "
  32.                     set /a m+=1
  33.                 )
  34.             )
  35.         )
  36.         set line=!##%%a!&echo;!line:~,-1!
  37.     )
  38. )
  39. pause
复制代码
2

评分人数

    • bbaa: 厉害技术 + 1
    • codegay: 有创意。不过不是很容易识别。技术 + 1
提供有偿代写,让你省时省力省事,支付宝扫码头像支付

TOP

返回列表