批处理编程挑战题“物以类聚”-将字母按大小写归并

happy886rr · 发表于 2017-4-11 09:24:52

[问题]
给你一个字符串，只由大小写字母构成。比如字符串：aAbBD，请将所有小写字母移到左端，大写移到右端，形成这种格式：abABD。也就是原字符串中小写a在小写b前面，移动后小写a仍然在小写b的前面，原字符串中大写A在大写B前面，移动后大写A仍然在大写B前面。

要求：不限编程语言（但最好是用批处理去完成才有挑战性），只要能实现这种移动效果就行。你可以拿字符串 bBAathToHOMmEe 做测试，移动后应该输出为 bathomeBATHOME。

[示例]
CMD脚本

@echo off
set str=bBAathToHOMmEe
for %%A in (#A,#B,#C,#D,#E,#F,#G,#H,#I,#J,#K,#L,#M,#N,#O,#P,#Q,#R,#S,#T,#U,#V,#W,#X,#Y,#Z) do (
set %%A=%%A
)
setlocal enabledelayedexpansion
:cut
set letter=!str:~0,1!
for %%a in (!letter!) do (
if "#%%a"=="!#%%a!" (
set uprstr=!uprstr!%%a
) else (
set lowstr=!lowstr!%%a
)
)
set str=!str:~1!
if "!str!"=="" (set/p=%lowstr%%uprstr%&exit)
goto :cut

复制代码

523066680 · 发表于 2017-4-11 10:10:08

本帖最后由 523066680 于 2017-4-11 15:52 编辑

Perl

my $lower = my $upper = 'bBAathToHOMmEe';
$lower =~s/[A-Z]//g;
$upper =~s/[a-z]//g;
print $lower.$upper;

复制代码

my @s = split('', 'aDbEcFghijkLMN');
my $n = 0;
grep { print $_ if ( $_ ~~ ['a'..'z'] ) } @s;
grep { print $_ if ( $_ ~~ ['A'..'Z'] ) } @s;

复制代码

python也学了点毛皮

u = ''
l = ''
for c in 'bBAathToHOMmEe':
if c in "abcdefghijklmnopqrstuvwxyz":
l+=c
else:
u+=c
print(l+u)

复制代码

pcl_test · 发表于 2017-4-11 12:13:09

本帖最后由 pcl_test 于 2017-4-11 13:11 编辑

标题最好标明下明确内容如将字母按大小写归并/分组

@echo off
powershell ^
$a='bBAathToHOMmEe'.ToCharArray()^|group {1*$_ -lt 97};^
-join ($a[0].group+$a[1].group);
pause

复制代码

@echo off
cd /d %tmp%&cmd /u /c echo;bBAathToHOMmEe|more>$
(for /f %%a in ('findstr [abcdefghijklmnopqrstuvwxyz] $^&findstr [ABCDEFGHIJKLMNOPQRSTUVWXYZ] $') do set /p=%%a)<nul
pause

复制代码

happy886rr · 发表于 2017-4-11 12:24:13

回复 2# 523066680
能来个批处理版吗，我想看看你怎么处理大小写。

a20150604 · 发表于 2017-4-11 12:25:20

本帖最后由 a20150604 于 2017-4-11 12:54 编辑

JS:

str = "bBAathToHOMmEe";
console.log(str.replace(/[A-Z]/g, '') + str.replace(/[a-z]/g, ''));

复制代码

cmd:

@echo off & setlocal enableDelayedExpansion
set "str=bBAathToHOMmEe"
for /L %%i in (0 1 8000) do (
set "c=!str:~%%i,1!"
if "!c!" neq "" (
(for /f "delims=ABCDEFGHIJKLMNOPQRSTUVWXYZ" %%c in ("!c!") do ( set "rl=!rl!!c!" )) || (set "RU=!RU!!c!")
) else echo;!rl!!RU! & pause & exit
)

复制代码

老刘1号 · 发表于 2017-4-11 12:41:28

存批
……话说用VBS写是不是太简单了，以后有时间用汇编重新写一下

'&@(Cls&Cscript -nologo -e:vbscript "%~0"&Pause&Exit)
str="bBAathToHOMmEe"
For Cut = 1 To Len(str)
If LCase(Mid(str,cut,1)) = Mid(str,cut,1) Then
NewLstr=NewLstr & Mid(str,cut,1)
ElseIf UCase(Mid(str,cut,1)) = Mid(str,cut,1) Then
NewUstr=NewUstr & Mid(str,cut,1)
End If
Next
WScript.Echo str & " -- > " & NewLstr & NewUstr

复制代码

happy886rr · 发表于 2017-4-11 13:58:35

回复 6# 老刘1号
用纯批试试

happy886rr · 发表于 2017-4-11 14:01:34

回复 3# pcl_test
拼的好精致

523066680 · 发表于 2017-4-11 14:58:04

本帖最后由 523066680 于 2017-4-11 15:22 编辑

回复 4# happy886rr

我想到了 find，速度慢；我想到了 if , 大小写区分，虽然 'A' gtr 'a' 成立, 但是 'A' gtr 'z' 居然不成立；
这个时候我想到了把 a b c, A B C 分组放到变量名里，很可惜，变量名不区分大小写。对批处理感到无助

不过，OK的，勉强写一个

@echo off & setlocal enabledelayedexpansion
set str=BaAbTcHdOeMfEg
set dupl=%str%
set "uc="
set "lc="
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set dupl=!dupl:%%a=%%a!
)
set /a n = 0
:lp
if "!str:~%n%, 1!" == "!dupl:~%n%, 1!" (
set lc=!lc!!str:~%n%, 1!
) else (
set uc=!uc!!str:~%n%, 1!
)
set /a n+=1
if not "!str:~%n%!" == "" goto :lp
echo %lc%%uc%
pause

复制代码

happy886rr · 发表于 2017-4-11 15:37:13

回复 9# 523066680
批处理的坑太多。

pcl_test · 发表于 2017-4-11 16:42:07

回复 9# 523066680
还有这两种

@echo off&setlocal enabledelayedexpansion
set s=bBAathToHOMmEe
for /f "delims=" %%a in ('tree "\*\%s%"^|find ":\*"') do set "t=%%~nxa"
rem 或者dir /L
set n=0
:lp
if "!s:~%n%,1!" neq "!t:~%n%,1!" (
set /p=!s:~%n%,1!<nul
) else (
set r=!r!!s:~%n%,1!
)
set /a n+=1
if "!s:~%n%!" neq "" goto :lp
echo;%r%
pause

复制代码

taofan712 · 发表于 2017-4-11 18:30:20

本帖最后由 taofan712 于 2017-4-11 21:07 编辑

@echo off&setlocal enabledelayedexpansion
set str=bBAathToHOMmEe
set str_bp=%str%
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set str_bp=%%str_bp:%%a=%%a%%
for /l %%a in (0 1 14) do (
for /f "tokens=1,2 delims=#" %%b in ('call echo;%%str:~%%a^,1%%#%%str_bp:~%%a^,1%%') do (
if not "%%b"=="%%c" (set lc=!lc!%%b) else ( set uc=!uc!%%c)
))
echo;!lc!!uc!
pause

复制代码

请各位帮忙看下我的代码为什么这么慢，我原以为是用了call set和call echo，改成下面的，还是一样的慢。将近2秒。

@echo off&setlocal enabledelayedexpansion
set str=bBAathToHOMmEe
set str_bp=%str%
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set str_bp=!str_bp:%%a=%%a!
for /l %%a in (0 1 14) do (
for /f "tokens=1,2 delims=#" %%b in ('echo;!str:~%%a^,1!#!str_bp:~%%a^,1!') do (
if not "%%b"=="%%c" (set lc=!lc!%%b) else ( set uc=!uc!%%c)
))
echo;!lc!!uc!
pause

复制代码

@terse 感谢指点，去掉了中间一个for。

@echo off&setlocal enabledelayedexpansion
set str=bBAathToHOMmEe
set str_bp=%str%
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set str_bp=!str_bp:%%a=%%a!
for /l %%a in (0 1 14) do (
if not "!str:~%%a,1!"=="!str_bp:~%%a,1!" (set lc=!lc!!str:~%%a,1!) else ( set uc=!uc!!str_bp:~%%a,1!)
)
echo;!lc!!uc!
pause

复制代码

codegay · 发表于 2017-4-11 18:40:14

python正则查找两次。

In [89]: bat = "bBAathToHOMmEe"
In [90]: ''.join(re.findall("[a-z]",bat) + re.findall("[A-Z]",bat))
Out[90]: 'bathomeBATHOME'

复制代码

codegay · 发表于 2017-4-11 18:45:25

能不能做到一行正则处理这个问题啊？
我没有什么想法

taofan712 · 发表于 2017-4-11 18:45:31

回复 13# codegay

前辈，请帮忙指点下我写的代码（13楼），为什么会耗费将近2秒。该怎么改才对呢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

批处理编程挑战题“物以类聚”-将字母按大小写归并

评分

评分

评分

评分

评分