如何用批处理使用文件夹名字重命名内部文件

yhq300

各位大佬帮帮忙
我找到了一个代码
@echo off
cd /d "%~dp0"
for /r /d %%A in (*) do (
  for %%B in ("%%A\*") do (
    ren "%%B" "%%~nxA%%~xB"
  )
)
能完成重命中文件夹内一个文件 可是如果有多个文件会提示重复命名 只会更改第一个文件名
大佬们帮我改改 怎么让别的文件加上（） 1 2 3 4之类的 成功重命名
因为所有文件都是数字命名 只要能和数字区分开 别的什么后缀都可以

LJY4.0

是不是以文件夹的名字重命名文件?

flashercs

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /r /d %%A in (*) do (
   
4.   call :rentemp "%%A"
   
5. )
   
6. pause
   
7. exit /b
   
8. 
   
9. :rentemp
   
10. setlocal enabledelayedexpansion
    
11. pushd "%~1"|| goto end
    
12. set n=0
    
13. 
    
14. for /f "delims=" %%A in ('2^>nul dir /a-d /b') do (
    
15.   if !n! equ 0 (
    
16.     set "newname=%~nx1%%~xA"
    
17.   ) else (
    
18.     set "newname=%~nx1(!n!)%%~xA"
    
19.   )
    
20.   set /a n+=1
    
21.   if not "!newname!"=="%%A" (
    
22.     if exist "!newname!" (
    
23.       call :getTempName
    
24.       @REM echo ren "%%A" "!tempname!"
    
25.      >nul 2>nul ren "%%A" "!tempname!" && set "templist[!n!]=%%A/!tempname!/!newname!"
    
26.     ) else (
    
27.       echo ren "%%A" "!newname!"
    
28.       ren "%%A" "!newname!"
    
29.     )
    
30.   )
    
31. )
    
32. REM 重命名临时列表
    
33. for /f "tokens=1* delims==" %%A in ('2^>nul set templist[') do (
    
34.   for /f "tokens=1-3 delims=/" %%C in ("%%B") do (
    
35.     echo ren "%%C" "%%E"
    
36.     ren "%%D" "%%E"
    
37.   )
    
38. )
    
39. popd
    
40. :end
    
41. endlocal
    
42. exit /b
    
43. 
    
44. :getTempName
    
45. :loop
    
46. set tempname=~%random%~
    
47. if exist "%tempname%" goto loop
    
48. @REM echo tempname=%tempname%
    
49. exit /b

复制代码

yhq300

是不是以文件夹的名字重命名文件?
LJY4.0 发表于 2022-7-26 10:57

    是的

yhq300

flashercs 发表于 2022-7-26 13:27

    谢谢大佬 可以用了

Batcher

回复 1# yhq300


参考：批处理字符串、文本常见操作之重命名文件
https://mp.weixin.qq.com/s/_1qzhObTSbc6HRpJy4onhQ