求教如何编写满足复制粘贴

yhl87217 · 发表于 2025-12-12 18:22:48

本帖最后由 yhl87217 于 2025-12-12 18:24 编辑

新手小白求教一个问题：
F:\测试目录下有两个文件夹 1-001、2-001,
1-001、2-001文件夹里是*.jpg文件。原文件夹文件不动，按条件复制至F:\成品

条件如图：

F:\测试\1-001 对应 F:\成品\1-001 到 1-006
F:\测试\2-001 对应 F:\成品\2-001 到 1-008

以此类推

77七 · 发表于 2025-12-12 21:37:05

条件.txt

1-001 3
1-002 4
...
2-001 5
2-002 11
...

复制代码

代码

@echo off
rem "保存为ansi编码"
cd /d "%~dp0"
set f1=f:\测试
set f2=f:\成品
set file=条件.txt
setlocal enabledelayedexpansion
for /f "tokens=1-2" %%a in ('find "-" ^< "%file%"') do (
if exist "%f1%\%%a" (
pushd "%f1%\%%a"
set n=0
)
md "%f2%\%%a"
for /f "tokens=1* delims=[]" %%c in ('dir /b /a-d *.jpg ^|more +!n! ^|find /n /v ""') do (
if %%c leq %%b (
copy "%%d" "%f2%\%%a"
)
)
set /a n+=%%b
)
endlocal
pause

复制代码

yhl87217 · 发表于 2025-12-12 21:47:12

回复 2# 77七

系统找不到指定文件

是我路径问题吗

77七 · 发表于 2025-12-12 23:02:14

回复 3# yhl87217

把条件.txt 和批处理放同一个路径下；或者写明路径 set file=f:\条件.txt

aloha20200628 · 发表于 2025-12-13 00:42:44

本帖最后由 aloha20200628 于 2025-12-13 08:32 编辑

回复 1# yhl87217

以下代码存为 test.bat 运行，与两个数据文件 1-001.lst, 2-001.lst （文件名须与两个源子目录名分别对应）存于同一目录...

@echo off &setlocal enabledelayedexpansion
for %%d in ("1-001", "2-001") do (
set "n=1"
(for /f "tokens=1-2 delims= " %%a in (%%~d.lst) do (
set/a k=n+%%b-1
for /l %%i in (!n!,1,!k!) do set "f=000%%i" &echo,%%a,!f:~-4!.jpg
set/a "n=k+1" ))>#.$
for /f "tokens=1-2 delims=," %%x in (#.$) do xcopy /yi "f:\测试\%%~d\%%y" "f:\成品\%%x")
del /q #.$ &pause&exit/b

复制代码

数据文件 1-001.lst 内容如下：

1-001 3
1-002 4
1-003 2
1-004 5
1-005 9
1-006 7

复制代码

数据文件 2-001.lst 内容如下：

2-001 5
2-002 11
2-003 1
2-004 6
2-005 7
2-006 5
2-007 2
2-008 3

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] 求教如何编写满足复制粘贴

本帖子中包含更多资源

浏览过的版块