为什么c1没有正常传递？

delab-1

要处理的temp3.csv的数据如下：
,c1 ,c2 ,c3 ,c4 ,c5 ,c6 ,c7 ,c8 ,c9 ,c10
,1,2,3,4,5,6,7,8,9,10
,11,12,13,14,15,16,17,18,19,20
,21,22,23,24,25,26,27,28,29,30
,31,32,33,34,35,36,37,38,39,40
,41,42,43,44,45,46,47,48,49,50
,51,52,53,54,55,56,57,58,59,60
,61,62,63,64,65,66,67,68,69,70
,71,72,73,74,75,76,77,78,79,80
,81,82,83,84,85,86,87,88,89,90
,91,92,93,94,95,96,97,98,99,100
编写了如下批处程序：
@echo off
if not exist temp3.csv echo "temp3.csv has not generated, please run program above :next" && pause
setlocal enabledelayedexpansion

if exist *.txt del *.txt
REM --------------------------------------------
REM extracting the first row of temp.csv
REM --------------------------------------------

for /L %%k in (1,1,6) do (
set iter=%%k

set line=0
(for /f "tokens=*" %%a in (temp3.csv) do (
set /a line+=1

set numb=0
for %%i in (%%a) do (
REM --------------------------------------------
REM extracting the name for comparision
REM --------------------------------------------
set /a numb+=1

if !line!==1 if !numb!==!iter! set name=%%i
if !numb!==!iter! echo %%i
                    )
))>!name!.txt

)
但是结果出现了：
.txt
c1.txt
c2.txt
c3.txt
c4.txt
c5.txt
为什么会出现.txt?而不是c1.txt，显示都向后面滞后了一位。我用程序核实了.txt这个循环中的name取值，其值的确是c1。但是不知在>!name!.txt文献输出的时候，所有的取值都向后滞后了一位。有没有高手帮助解释一下原因，多谢多谢！

jiavip

temp3.csv 第一个字符是（,） 默认是分隔符，第一个获取的变量应该是空白的
IF %%a ==“ ”   是空白或空格，则跳过吧，，，
爪机分析，没有实写，鄙人也是瞎分析，，，自行判断！

delab-1

回复 2# jiavip
我核实了，但是!name!在循环中显示是正确的，没有任何问题，没有出现空值问题，但是在>!name!.txt中，却出现了空值，这是我很困惑的地方。

delab-1

感觉出现变量滞后传递问题，我看看可能是循环输出的时候，应该在set !name!=%%i出现在输出>!name!.txt之后，因为循环输出在更上一次循环中。

holley

回复 3# delab-1
改为for /L %%k in (2,1,7) do (试试
当你使用>重定向操作符时，CMD会在执行命令前先展开变量，而此时!name!还没有被正确赋值。

aloha20200628

回复 1# delab-1


( for /f "tokens=*" %%a in (temp3.csv) do (...) )>!name!.txt 这个复合语块被首次处理时，变量 name 尚未被赋值，因此 cmd 默认采用空值即成 ".txt" 文件名。可改用以下代码（略去源注释行）...

1. 
   
2. @echo off &setlocal enabledelayedexpansion
   
3. for /L %%k in (1,1,6) do (
   
4.    set /a "iter=%%k,line=0"
   
5.    (for /f "tokens=*" %%a in (temp3.csv) do (
   
6.        set /a "line+=1,numb=0"
   
7.        for %%i in (%%a) do (
   
8.           set /a numb+=1
   
9.           if !line! equ 1 if !numb! equ !iter! set "name=%%i"
   
10.           if !numb! equ !iter! echo,%%i)
    
11.    ))>#.$
    
12.    ren #.$ "!name!.txt"
    
13. )
    
14. pause&exit/b
    

复制代码

备注》对比一楼源代码和以上代码可体会 cmd 处理复合语块（典型如 (for ...) ）的机制...

ShowCode

回复 1# delab-1

1. @echo off
   
2. set "InpuFile=temp3.csv"
   
3. if not exist "%InpuFile%" (
   
4.     echo "%InpuFile% has not generated"
   
5.     pause
   
6.     exit /b
   
7. )
   
8. 
   
9. setlocal enabledelayedexpansion
   
10. set /p FirstLine=<"%InpuFile%"
    
11. set "iter=0"
    
12. for %%k in (%FirstLine%) do (
    
13.     set /a iter+=1
    
14.     if !iter! leq 6 (
    
15.         (for /f "tokens=*" %%a in ('type "%InpuFile%"') do (
    
16.             set "numb=0"
    
17.             for %%i in (%%a) do (
    
18.                 set /a numb+=1
    
19.                 if !numb!==!iter! echo %%i
    
20.             )
    
21.         ))>"%%k.txt"
    
22.     )
    
23. )
    

复制代码

delab-1

回复 5# holley


    这样处理是不行的，因为传递问题没有解决，问题依然存在。

delab-1

回复 6# aloha20200628


    采取另存为的思路不错，这个可行的

delab-1

回复 7# ShowCode


    这个处理思路很好，感谢。把!name!取值放在第一层循环，而且程序简洁，思路清晰，非常好！感谢感谢

aloha20200628

回复 9# delab-1

以上代码均须多次读取源数据文件，以下给一个仅须读取一次的版本...

1. 
   
2. @echo off &setlocal enabledelayedexpansion
   
3. for /f "delims=" %%a in (temp3.csv) do (
   
4.    if not defined f1 for %%v in (%%a) do set/a "n+=1" &set "f!n!=%%v.txt"
   
5.    set "n=0" &for %%v in (%%a) do set/a "n+=1" &for %%n in (!n!) do set "c%%n=!c%%n! %%v")
   
6. for /l %%n in (1,1,6) do (for %%v in (!c%%n!) do echo,%%v)>"!f%%n!"
   
7. pause&exit/b
   

复制代码