[已解决]批处理怎样查询注册表值，设置变量？

剑气如霜 · 发表于 2025-9-5 14:26:26

本帖最后由剑气如霜于 2025-9-6 11:35 编辑

HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\xxx，这个xxx是不确定数据，每个版本都不同，下面有2个键值，

DisplayIcon，数据是C:\Program Files\Common Files\Adobe\Adobe Illustrator CS6\ai_install_pkg_rev.ico
DisplayVersion，数据是16.0

先查询DisplayIcon的数据，如果DisplayIcon的数据包含Illustrator关键词，则获取DisplayVersion的数据的前两位，也就是16，忽略小数点，然后写入注册表数据，
reg add "HKEY_CURRENT_USER\Software\Adobe\CSXSPreferences" /v PlayerDebugMode /d 1 /f
最后面的那个CSXSPreferences是和DisplayVersion的前两位是相关的，DisplayVersion从16开始，对应的键值CSXS.3会出现递增特性，这个要设置变量写。下面是对应格式

14 CSXSPreferences
15 CSXS2Preferences
16 CSXS.3
17 CSXS.4
18 CSXS.5
19 CSXS.6
20 CSXS.7
21 CSXS.8
…… ……

请帮忙写bat代码，最好不要包含PowerShell命令，那个完全搞不懂

Batcher · 发表于 2025-9-5 16:59:29

回复 1# 剑气如霜

双击文件 C:\Windows\System32\cmd.exe
在打开的CMD窗口中执行以下命令：
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /s > 1.txt
回车
把生成的1.txt文件上传到网盘

aloha20200628 · 发表于 2025-9-5 17:03:24

本帖最后由 aloha20200628 于 2025-9-5 17:10 编辑

回复 1# 剑气如霜

试试以下批处代码...

@echo off &setlocal enabledelayedexpansion&set "ok="
for %%v in ("_#14=CSXSPreferences" "_#15=CSXS2Preferences" "_#16=CSXS.3" "_#17=CSXS.4" "_#18=CSXS.5" "_#19=CSXS.6" "_#20=CSXS.7" "_#21=CSXS.8") do set %%v
reg query HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\ /s|findstr /in "\Software\Microsoft\Windows\CurrentVersion\Uninstall displayicon displayversion">#.$
for /f "tokens=1* delims=:" %%a in ('find /i "Adobe Illustrator "^<#.$') do (
set/a "n=%%a-1,ok=1"
for /f "tokens=1* delims=:" %%x in ('find "!n!:"^<#.$') do for /f "tokens=3 delims=. " %%v in ("%%y") do reg add "HKEY_CURRENT_USER\Software\Adobe\!_#%%v!" /v PlayerDebugMode /d 1 /f)
if not defined ok (echo,未发现注册表目标项) else echo,完成
del /q "#.$" &pause&exit/b

复制代码

剑气如霜 · 发表于 2025-9-5 19:44:44

回复 2# Batcher

按你的要求把注册表的内容导出来了，删掉了多余的内容，只留了3个项目。
我的想法就是通过查找illustrator在注册表的卸载路径，找到版本号，然后在HKEY_CURRENT_USER\Software\Adobe\CSX……项写入数据，版本号和CSX这个项目的对应关系就是1楼那种格式。比如我下面贴出来的illustratro 2018版本号是22.0.1，那么对应的项目就是CSX.9，Illustrator 2022版本号是26，就对应CSX.13

下面是注册表导出的内容
HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Esko boostX for Adobe Illustrator
DisplayName REG_SZ Esko boostX for Adobe Illustrator
DisplayIcon REG_SZ C:\Esko\bg_prog_boostx_v010\uninstall\esko.ico
UninstallString REG_SZ cmd /c start /min C:\Windows\eguninstall.bat C:\Esko\bg_prog_boostx_v010\uninstall\bpuninstall bpuninstall.exe x
Publisher REG_SZ Esko

HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\ILST_22_0_1
DisplayName REG_SZ Adobe Illustrator CC 2018
DisplayIcon REG_SZ C:\Program Files\Adobe\Adobe Illustrator CC 2018\Support Files\Contents\Windows\AI_Application_Icon.ico
DisplayVersion REG_SZ 22.0.1
URLInfoAbout REG_SZ Adobe Illustrator CC 2018
UninstallString REG_SZ "C:\Program Files (x86)\Adobe\Adobe Creative Cloud\HDCore\Uninstaller.exe" --uninstall=1 --sapCode=ILST --productVersion=22.0.1 --productPlatform=win64 --productAdobeCode={ILST-22.0.1-64-ADBEADBEADBEADBEADBEA} --productName="Illustrator CC" --mode=1
VersionMajor REG_SZ 22
VersionMinor REG_SZ 0
Publisher REG_SZ Adobe Systems Incorporated
InstallLocation REG_SZ C:\Program Files\Adobe\Adobe Illustrator CC 2018
EstimatedSize REG_DWORD 0x148f0c

HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\ILST_26_0_1
DisplayName REG_SZ Adobe Illustrator 2022
DisplayIcon REG_SZ C:\Program Files\Adobe\Adobe Illustrator 2022\Support Files\Contents\Windows\AI_Application_Icon.ico
DisplayVersion REG_SZ 26.0.1
URLInfoAbout REG_SZ https://www.adobe.com/go/ai_support
UninstallString REG_SZ "C:\Program Files (x86)\Common Files\Adobe\Adobe Desktop Common\HDBox\Uninstaller.exe" --uninstall=1 --sapCode=ILST --productVersion=26.0.1 --productPlatform=win64 --productAdobeCode={ILST-26.0.1-64-ADBEADBEADBEADBEADBEA} --productName="Illustrator" --mode=1
VersionMajor REG_SZ 26
VersionMinor REG_SZ 0
Publisher REG_SZ Adobe Inc.
InstallLocation REG_SZ C:\Program Files\Adobe\Adobe Illustrator 2022
InstallDate REG_SZ 8/7/2025
EstimatedSize REG_DWORD 0x19d45a

剑气如霜 · 发表于 2025-9-5 20:27:54

回复 3# aloha20200628

运行以后没反应，没暂停，直接退出了。可能是我没表达清楚，在4楼又重新表达了一遍。

aloha20200628 · 发表于 2025-9-5 20:43:27

本帖最后由 aloha20200628 于 2025-9-6 08:33 编辑

回复 5# 剑气如霜

以下测试版代码针对4楼的示例样本，假设存为 1.txt，代码中增加两个针对 22=CSXS.9 和 26=CSXS.13 的变量定义
楼主认可运行结果后，可删除代码第5行中的 echo, 即成实用版（真正写入注册表）...

@echo off &setlocal enabledelayedexpansion &set "ok=" &findstr /n .* "1.txt">#.$
for %%v in ("_#14=CSXSPreferences" "_#15=CSXS2Preferences" "_#16=CSXS.3" "_#17=CSXS.4" "_#18=CSXS.5" "_#19=CSXS.6" "_#20=CSXS.7" "_#21=CSXS.8" "_#22=CSXS.9" "_#26=CSXS.13") do set %%v
for /f "tokens=1* delims=:" %%a in ('findstr /irc:" displayicon .*Adobe Illustrator" #.$') do (
set/a "n=%%a+1,ok=1"
for /f "tokens=1* delims=:" %%x in ('find "!n!:"^<#.$') do for /f "tokens=3 delims=. " %%v in ("%%y") do echo,reg add "HKEY_CURRENT_USER\Software\Adobe\!_#%%v!" /v PlayerDebugMode /d 1 /f)
if not defined ok (echo,未发现注册表目标项) else echo,完成
del /q "#.$" &pause&exit/b

复制代码

aloha20200628 · 发表于 2025-9-6 08:23:19

本帖最后由 aloha20200628 于 2025-9-6 09:08 编辑

回复 5# 剑气如霜

调整了锚定 displayVersion 的算法，应该会提高匹配准确度，以下测试版代码取代3楼代码用于直接搜索注册表键值...

@echo off &setlocal enabledelayedexpansion &set "ok="
for %%v in ("_#14=CSXSPreferences" "_#15=CSXS2Preferences" "_#16=CSXS.3" "_#17=CSXS.4" "_#18=CSXS.5" "_#19=CSXS.6" "_#20=CSXS.7" "_#21=CSXS.8" "_#22=CSXS.9" "_#26=CSXS.13") do set %%v
reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall" /s|findstr /ni "hkey_ displayicon displayversion">#.$
for /f "delims=:" %%n in ('findstr /irc:" displayicon .*Adobe Illustrator" #.$') do (
set/a "n1=%%n-1,n2=%%n+1,ok+=1"
for /f "tokens=2,4 delims=:. " %%a in ('findstr "!n1!: !n2!:" #.$') do if /i "%%a"=="displayversion" echo,reg add "HKEY_CURRENT_USER\Software\Adobe\!_#%%b!" /v PlayerDebugMode /d 1 /f)
if not defined ok (echo,未发现注册表目标项) else echo,完成
del /q "#.$" &pause&exit/b

复制代码

楼主认可运行结果后，可删除代码第6行中的 echo, 即成实用版（真正写入注册表）...

WHY · 发表于 2025-9-6 11:31:47

本帖最后由 WHY 于 2025-9-7 14:21 编辑

@echo off
setlocal enabledelayedexpansion
set "regPath=HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall"
set "keyWord=Illustrator"
set "found="
for /f "delims=:" %%i in ('findstr /b /n ":::::" "%~f0"') do (
for /f "tokens=1*" %%j in ('more +%%i "%~f0"') do (
set "_%%j=%%k"
)
)
for /f "tokens=*" %%i in ('reg query "%regPath%" /f "%keyWord%" /d /s') do (
set "str=%%i"
if /i "!str:~0,4!" == "HKEY" (
set "subPath=%%i"
) else if /i "!str:~0,11!" == "displayIcon" (
for /f "tokens=3" %%j in ('reg query "!subPath!" /v "displayVersion" 2^>nul') do (
set "version=%%j"
)
)
if defined version (
set found=1
call :Next
set "version="
)
)
if not defined found (
echo;No such registry key or value found.
)
pause & exit
:Next
for /f "delims=" %%i in ("!subPath!") do (
set "appName=%%~nxi"
)
for /f "tokens=1,2 delims=." %%a in ("!version!") do (
if defined _%%a.%%b (
echo;!appName! ---^> !version! ---^> !_%%a.%%b!
echo reg add "HKCU\Software\Adodb\!_%%a.%%b!" /v PlayerDebugMode /d 1 /f
) else if defined _%%a (
echo;!appName! ---^> !version! ---^> !_%%a!
echo reg add "HKCU\Software\Adodb\!_%%a!" /v PlayerDebugMode /d 1 /f
) else (
echo;!appName! ---^> !version! ---^> ERROR.
)
)
goto :EOF
::::::::::::VersionList::::::::::::
14.0 CSXSPreferences
15.0 CSXS2Preferences
15.1 CSXS.2.5
16 CSXS.3
17 CSXS.4
18 CSXS.5
19 CSXS.6
20 CSXS.7
21 CSXS.7
22 CSXS.8
23 CSXS.9
24 CSXS.9
25 CSXS.10
26 CSXS.11
27 CSXS.11
28 CSXS.11
29 CSXS.12

复制代码

剑气如霜 · 发表于 2025-9-6 11:35:05

经过一晚上的安装测试，很遗憾这个话题要关闭了。AI版本号和CSXS号码的对应关系一开始就错了，是我想简单了，开始我拿代码去测试，发现总是结果不对。然后我把所有版本从CS4-CS2025全部装了一遍，发现只有前面某些版本是按顺序递增的，后面的版本毫无规律，有时候几个版本共用一个CSXS号码，所以应该是没办法按变量的方式来自动对应了。谢谢楼上几位大佬的热情，给你们贴麻烦了。

aloha20200628 · 发表于 2025-9-6 11:52:00

本帖最后由 aloha20200628 于 2025-9-6 12:01 编辑

回复 9# 剑气如霜

所给代码中对变量对应关系的定义不怕 csxs... 值是否重复或递增或递减，例如：
12       CSXSPreferences
13       CSXSPreferences
14       CSXS2Preferences
15       CSXS2Preferences
16       CSXS.5
17       CSXS.4
18       CSXS.3
19       CSXS.6
20       CSXS.7
21       CSXS.8
22       CSXS.8
23       CSXS.8
只要给出的变量定义能覆盖全部示例即可...

剑气如霜 · 发表于 2025-9-6 13:57:34

本帖最后由剑气如霜于 2025-9-6 14:29 编辑

回复 8# WHY
虽然这个帖子因为数据对应关系错误，而导致功能实现不了，但是代码是可以用来学习的。用大佬你的代码，显示的是No such registry key or value found.其实昨晚我用AI写了一段代码，是可以正常运行的，只是看起来没你写的高级，我也贴出来吧

@echo off
setlocal enabledelayedexpansion
rem 根据系统架构设置注册表路径
if "%PROCESSOR_ARCHITECTURE%"=="AMD64" (
set "uninstall_path=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall"
) else (
set "uninstall_path=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
)
rem 获取所有子项名称
for /f "tokens=*" %%a in ('reg query "%uninstall_path%"') do (
set "subkey=%%a"
rem 跳过根键本身
if not "!subkey!"=="%uninstall_path%" (
rem 检查DisplayIcon值是否包含"Illustrator"
for /f "tokens=2*" %%b in ('reg query "!subkey!" /v DisplayIcon 2^>nul') do (
set "display_icon=%%c"
echo !display_icon! | find /i "Illustrator" >nul
if !errorlevel! equ 0 (
rem 获取DisplayVersion值
for /f "tokens=2*" %%d in ('reg query "!subkey!" /v DisplayVersion 2^>nul') do (
set "version=%%e"
rem 忽略小数点，提取主版本号
for /f "tokens=1 delims=." %%v in ("!version!") do (
set "major_version=%%v"
rem 计算对应的注册表项名称
if !major_version! equ 14 (
set "pref_key=CSXSPreferences"
) else if !major_version! equ 15 (
set "pref_key=CSXS2Preferences"
) else if !major_version! gtr 15 (
set /a csxs_num=!major_version! - 13
set "pref_key=CSXS.!csxs_num!"
) else (
echo 不支持的版本: !major_version!
continue
)
rem 写入注册表设置
if defined pref_key (
echo 找到 Illustrator 版本 !version!，主版本 !major_version!
echo 写入注册表: HKEY_CURRENT_USER\Software\Adobe\!pref_key!
reg add "HKEY_CURRENT_USER\Software\Adobe\!pref_key!" /v PlayerDebugMode /d 1 /f
echo.
)
)
)
)
)
)
)
echo 处理完成!
pause

复制代码

剑气如霜 · 发表于 2025-9-6 14:20:43

回复 10# aloha20200628

真正的对应关系其实比较复杂，因为小数点的存在，每个人电脑可能安装的版本不一样，所以我想着取整数位，但是又有例外比如CS5.5的版本号是15.1，它独自对应一个CSXS号，这还不是重点，主要是如果Adobe软件的版本号跟CSXS号之间如果没有规律，那以后出新版本就只能手动去添加到代码里面了，感觉失去自动化的前提了。
14.0 CSXSPreferences
15.0 CSXS2Preferences
15.1 CSXS.2.5
16.x CSXS.3
17.x CSXS.4
18.x CSXS.5
19.x CSXS.6
20.x CSXS.7
21.x CSXS.7
22.x CSXS.8
23.x CSXS.9
24.x CSXS.9
25.x CSXS.10
26.x CSXS.11
27.x CSXS.11
28.x CSXS.11
29.x CSXS.12
这才是版本号和CSXS号的真实对应关系，是安装所有版本以后查注册表整理出来的。
AI安装后，是没有CSXS号这个注册表项目的，只有启动一次并关闭以后，才会自动生成这个项，但是项目里面没有PlayerDebugMode这个值，所以我之前的做法是先启动AI，然后关闭，然后用for /f %%a in ('reg query "HKEY_CURRENT_USER\Software\Adobe" /f CSXS.*') do reg add "%%a" /v PlayerDebugMode /d 1 /f 2>nul来实现。这样要开关2次AI，虽然很勉强，总归是能用。想着如果是在AI启动前就把CSXS号项目给写入的话，就能不用启动2次AI，应该很难做到吧。

aloha20200628 · 发表于 2025-9-6 15:17:47

本帖最后由 aloha20200628 于 2025-9-6 15:54 编辑

回复 12# 剑气如霜

一。12楼给出的实际对应关系表（可存为列表文件以便后续维护）对于7楼代码构建的变量字典没有问题。
二。至于在ai安装前可否一次性在注册表中写入键值例如 reg add HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Adobe\csxs.9 /v PlayerDebugMode /t REG_SZ /d 1 /f 也没有问题（reg add 会自动创建路径中的新项如 csxs.9），只要用管理员身份（也可能不需要）且已知其中的项名如 csxs.9 即可，关键是后者。因此楼主须确认届时是否可知其中的项名如 csxs.9？

剑气如霜 · 发表于 2025-9-6 16:12:21

回复 13# aloha20200628

所以这个问题应该是无解了，因为无法预知Adobe以后推出新版本的CSXS号，如果有规律还能猜测，没规律就只能手动录入，这样还不如我12楼写的办法，虽然要2次开启软件，但是能做到通用。不过说回来，这个帖子对于我还是有用的，让我初步了解到set /a的写法。谢谢大家！

WHY · 发表于 2025-9-7 14:29:04

修改8#脚本，版本列表在脚本尾部。根据第一列版本值，将对应的第二列数据写入注册表。
顺便简化下for循环逻辑。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[注册表类] [已解决]批处理怎样查询注册表值，设置变量？

评分

评分

评分