【已解决】批处理如何从第4行起删除每行的行尾数字

chishingchan · 发表于 2025-8-21 12:57:09

这个问题的起因是使用 Orca 软件导出表（.idt）后，从第 4 行起删除每行末尾的乱序数字，此数字长 1~5 位。表示例如下：

File Component_ FileName FileSize Version Language Attributes Sequence
s72 s72 l255 i4 S72 S20 I2 i4
File File
agnosticuilib.dll Viewer maoufxaj.dll|agnosticuilib.dll 1251424 3.0.0.2418 0 1536 4
Activation.exe Viewer mgkjfdue.exe|Activation.exe 17197152 13.0.0.21632 0 1536 2
AIPLabelfpi AIPLabelfpi AIPLabel.fpi 535648 13.0.0.21632 1033 1536 5
adaldll Viewer adal.dll 1497720 2.0.0.19401 1033 1536 3
Alfresco.fpi Alfrescofpi Alfresco.fpi 5657184 13.0.0.21632 1033 1536 6
apimswincoreconsolel110.dll Viewer 7g0h2qpu.dll|api-ms-win-core-console-l1-1-0.dll 18696 10.0.17134.12 1033 1536 7
apimswincorefilel120.dll Viewer p05oa5h9.dll|api-ms-win-core-file-l1-2-0.dll 18184 10.0.17134.12 1033 1536 12
apimswincoredatetimel110.dll Viewer zhc6g3dg.dll|api-ms-win-core-datetime-l1-1-0.dll 18184 10.0.17134.12 1033 1536 8
apimswincoredebugl110.dll Viewer xcldxomg.dll|api-ms-win-core-debug-l1-1-0.dll 18184 10.0.17134.12 1033 1536 9
apimswincorefilel210.dll Viewer nskzl4i-.dll|api-ms-win-core-file-l2-1-0.dll 18184 10.0.17134.12 1033 1536 13
apimswincoreerrorhandlingl110.dll Viewer etxbuq2g.dll|api-ms-win-core-errorhandling-l1-1-0.dll 18184 10.0.17134.12 1033 1536 10
apimswincoreheapl110.dll Viewer ifx97dtf.dll|api-ms-win-core-heap-l1-1-0.dll 18184 10.0.17134.12 1033 1536 15
ActionWizard.fpi ActionWizard cozefaey.fpi|ActionWizard.fpi 654432 13.0.0.21632 1033 1536 1
apimswincorefilel110.dll Viewer utuy1new.dll|api-ms-win-core-file-l1-1-0.dll 21768 10.0.17134.12 1033 1536 11
apimswincorehandlel110.dll Viewer xkq0otea.dll|api-ms-win-core-handle-l1-1-0.dll 18184 10.0.17134.12 1033 1536 14

复制代码

求助：现需要使用批处理从第4行起删除每行末尾的乱序数字（长度 1~5）位。例如：1 ~ 65535，谢谢！

后续精简文件行后再【已解决】重新分配升序序号。

未评分的回复请见谅，因为超出限制了。

Five66 · 发表于 2025-8-21 15:41:10

第3行可设置文件名或路径
第4行可设置行数
第5行可设置文件编码
不删除数字前的分割符 ,仅删除末尾数字
运行后会添加前缀并创建新文件

@set @do_not_save_as_utf8=1;/*&echo off
set "file=a.idt"
set "line_del=4"
set "encoding=gbk"
cscript //nologo //e:jscript "%~f0" "%file%" "%line_del%" "%encoding%"
echo,&echo done&pause&exit /b 0 */
(function(argv,stdin,stdout,stderr,wscript,nil,not_nil){if(!argv.length)return;
var p=argv(0).split(/\\|\/|\\\\/);
var file_in=file_new(argv(0),'r',argv(2));
var file_out=file_new(nil,'w',argv(2));
if(!file_in){
wscript.echo('open file '+argv(0)+' error');
file_out.close();
wscript.quit();
}
var str=file_in.readtext(8192);
file_in.position=0;
var l=str.match(/\r\n?|\n/);
if(l){
if('\n'==l[0])file_in.lineseparator=10;
if('\r'==l[0])file_in.lineseparator=13;
if('\r\n'==l[0])file_in.lineseparator=-1;
}else{file_in.lineseparator=-1;}
file_out.lineseparator=file_in.lineseparator;
var i=0,line_del=argv(1)>0?argv(1)-1:0;
while(!file_in.eos){
str=file_in.readtext(-2);
if(line_del){
line_del--;
file_out.writetext(str,1);
}else{
i++;
file_out.writetext(str.replace(/\t\d+$/,'\t'),1);
}}
file_out.savetofile('@@new_'+p.pop(),2);
file_in.close();
file_out.close();
function file_new(n,m,e){var t=2,r=GetObject('new:adodb.stream');try{if(e)r.charset=e;
if(-1!=m.indexOf('b'))t=1;r.type=t;r.open();if(n&&''!=n)r.loadfromfile(n);}catch(l){r=nil}
return r;}
})(WScript.Arguments,WScript.StdIn,WScript.StdOut,WScript.StdErr,WScript,null);

复制代码

aloha20200628 · 发表于 2025-8-21 17:56:58

本帖最后由 aloha20200628 于 2025-8-21 18:03 编辑

回复 1# chishingchan

假设源文件 a.txt 从第4行开始每行中各字段不会包含空格，逗号，分号，等号这些系统默认分割符，可用以下代码

@echo off &setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* a.txt') do if %%a lss 4 (echo.%%b) else (
set "_last=" &set "v="
for %%x in (%%b) do (
if defined _last (set "v=!v! !_last!")
set "_last=%%x")
echo.!v:~1!) )>b.txt
pause&exit/b

复制代码

如果源文件 a.txt 从第4行开始每行中各字段可能包含空格，逗号，分号，等号这些系统默认分割符，须用以下代码，但效率会有所降低...

@echo off &setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* a.txt') do if %%a lss 4 (echo.%%b) else (
set "v=" &call :xxx "%%b" &echo.!v:~1!) )>b.txt
pause&exit/b
:xxx
for /f "tokens=1* delims= " %%x in ("%~1") do if "%%~y"=="" (exit/b) else (set "v=!v! %%x" &call :xxx "%%~y")
exit/b

复制代码

aloha20200628 · 发表于 2025-8-21 19:24:00

本帖最后由 aloha20200628 于 2025-8-21 20:31 编辑

回复 1# chishingchan

再给一个批处调用 powershell 功能的版本，存为 test.bat 运行，与源文件 a.txt 同目录...

@echo off &powershell "$a=gc 'a.txt';$a[0..2]|%%{$_};$a[3..($a.length-1)]|%%{$_.substring(0,$_.LastIndexOf(' '))}">b.txt
pause&exit/b

复制代码

chishingchan · 发表于 2025-8-21 20:14:43

回复 3# aloha20200628

老大，可以帮我使用批处理一楼的示例文件后的结果如下：

File\agnosticuilib.dll
File\Activation.exe
File\AIPLabelfpi
File\adaldll
File\Alfresco.fpi
File\apimswincoreconsolel110.dll
File\apimswincorefilel120.dll
File\apimswincoredatetimel110.dll
File\apimswincoredebugl110.dll
File\apimswincorefilel210.dll
File\apimswincoreerrorhandlingl110.dll
File\apimswincoreheapl110.dll
File\ActionWizard.fpi
File\apimswincorefilel110.dll
File\apimswincorehandlel110.dll

复制代码

aloha20200628 · 发表于 2025-8-21 20:57:44

回复 5# chishingchan

用3-4楼各段代码测试一楼示例文件，其结果均会如期删除每个数据行 ...1536之后的数字，未出现5楼所示的结果...

chishingchan · 发表于 2025-8-22 08:50:09

回复 6# aloha20200628

我想要5楼的结果：获取第4行起每一行第一列的文件名，并在文件名前i添加 File\ 。

aloha20200628 · 发表于 2025-8-22 09:26:49

回复 7# chishingchan

@echo off &(for /f "skip=3 delims= " %%a in (a.txt) do echo.File\%%a)>b.txt
pause&exit/b

复制代码

chishingchan · 发表于 2025-8-22 10:06:54

回复 8# aloha20200628

谢谢！

77七 · 发表于 2025-8-22 14:50:28

我数了下，都是8列，两个问题一次解决。

@echo off
cd /d "%~dp0"
for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"1.idt"') do (
if %%a leq 3 (
echo=%%b
) else (
for /f "tokens=1-8 delims= " %%a in ("%%b") do (
set /a n+=1
set str=%%a %%b %%c %%d %%e %%f %%g
setlocal enabledelayedexpansion
echo !str! !n!
endlocal
)
)
)
pause

复制代码

chishingchan · 发表于 2025-8-22 19:19:44

本帖最后由 chishingchan 于 2025-8-22 23:24 编辑

回复 10# 77七

测试了一下，只修改了 1.idt 为 File.idt，没效果！

根据老大们的代码，我修改如下，看看能否解决三个疑难问题：

@echo off
cd /d %~dp0
type nul>Import_Table_File.idt
type nul>File.txt
for /f "tokens=1* delims=:" %%i in ('findstr /n .* File.idt') do (
if %%i lss 4 (
echo %%j>>Import_Table_File.idt
) else (
goto ExitFor
)
)
:ExitFor
setlocal enabledelayedexpansion
for /f "skip=3 tokens=1-8 delims= " %%a in (File.idt) do (
set /a n+=1
echo %%a %%b %%c %%d %%e %%f %%g !n!>>Import_Table_File.idt
echo File\%%a>>File.txt
)

复制代码

经核对，生成 Import_Table_File.idt 的方法错误的！出现错误数据列！
老大们能否给我这段代码再优化一下，谢谢！

chishingchan · 发表于 2025-8-22 23:41:16

回复 3# aloha20200628

老大，以上问题都是采纳你的答案，能否将代码组合一下，使删除序号、添加序号、生成文件列表同时进行，节省时间。谢谢！

77七 · 发表于 2025-8-23 00:10:16

回复 11# chishingchan

你改的没错。

@echo off
cd /d "%~dp0"
(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"1.idt"') do (
if %%a leq 3 (
echo=%%b
) else (
for /f "tokens=1-8 delims= " %%a in ("%%b") do (
set /a n+=1
set str=%%a %%b %%c %%d %%e %%f %%g
>> "list.txt" echo File\%%a
setlocal enabledelayedexpansion
echo !str! !n!
endlocal
)
)
)) > "2.idt"
pause

复制代码

chishingchan · 发表于 2025-8-23 07:55:32

本帖最后由 chishingchan 于 2025-8-23 08:05 编辑

回复 13# 77七

老大，这个批处理不对劲。因为有些行其中有 3 个跳表符存在，例如以下文件数据的最后一行：
File.idt

File Component_ FileName FileSize Version Language Attributes Sequence
s72 s72 l255 i4 S72 S20 I2 i4
File File
AIPLabelfpi AIPLabelfpi AIPLabel.fpi 535648 13.0.0.21632 1033 1536 5
APIMSWincorexstatel210.dll Viewer pjzw0ihk.dll|API-MS-Win-core-xstate-l2-1-0.dll 2560 10.0.17134.12 1033 1536 32
ActionWizard.fpi ActionWizard cozefaey.fpi|ActionWizard.fpi 654432 13.0.0.21632 1033 1536 1
Activation.exe Viewer mgkjfdue.exe|Activation.exe 17197152 13.0.0.21632 0 1536 2
Alfresco.fpi Alfrescofpi Alfresco.fpi 5657184 13.0.0.21632 1033 1536 6
BitMailAgent BitMailAgent 9xvzvips.exe|64BitMailAgent.exe 512096 1.0.8.1228 0 1536 48
Bookmark Bookmark Bookmark.fpi 1590880 13.0.0.21632 2052 1536 49
BoxPlugin.fpi BoxPlugin veo3zuir.fpi|BoxPlugin.fpi 4972640 13.0.0.21632 0 1536 50
Calculator Calculator w4waceym.fpi|Calculator.fpi 3839584 13.0.0.21632 2052 1536 51
CheckLicenceDll.dll CheckLicenceDll phc.dll 722944 13.0.0.21632 0 1536 52
CheckLicenceX64_Dll.dll CheckLicenceDll2 phc64.dll 788992 13.0.0.21632 0 1536 53
CheckLicenceX86_Dll.dll CheckLicenceDll2 phc.dll 722944 13.0.0.21632 0 1536 54
CommentsSummary.fpi CommentsSummary 66iuskyu.fpi|CommentsSummary.fpi 602720 13.0.0.21632 0 1536 55
ComparePDF ComparePDF 6v9mf7bn.fpi|ComparePDF.fpi 517728 13.0.0.21632 0 1536 56
ConnectedPDFLogin ConnectedPDFLogin eks9tbgk.dll|ConnectedPDFLogin.dll 2826848 13.0.0.21632 1033 1536 58
ConnectedPDFLogin64 ConnectedPDFLogin vpv4twiv.dll|ConnectedPDFLogin64.dll 3743328 13.0.0.21632 1033 1536 59
ContentSuite.fpi ContentSuitefpi zbqplez4.fpi|ContentSuite.fpi 2064480 13.0.0.21632 1033 1536 60
ConvertToPDF.dll ConvertToPDFDll zwid-adl.dll|ConvertToPDF_x86.dll 19192416 13.0.0.15725 0 1536 61
ConvertToPDF3.dll ConvertToPDFDll2 ndvmxdsc.dll|ConvertToPDF_x64.dll 23299168 13.0.0.15725 0 1536 62
CrossReferenceLinks CrossReferenceLinks mpuhzevn.fpi|CrossReferenceLinks.fpi 436832 13.0.0.21632 1033 1536 63
DMSforLegal.fpi DmsForLegal gbjcbk0o.fpi|DMSforLegal.fpi 2182240 13.0.0.21632 1033 1536 65
DefaultPluginsList.xml DefaultPluginsList bssyikxc.xml|DefaultPluginsList.xml 28573 1536 64

复制代码

错误的处理结果：

DefaultPluginsList.xml DefaultPluginsList bssyikxc.xml|DefaultPluginsList.xml 28573 1536 64 22

复制代码

最后正确结果应该是这样才对：

DefaultPluginsList.xml DefaultPluginsList bssyikxc.xml|DefaultPluginsList.xml 28573 1536 22

复制代码

麻烦老大修正一下，谢谢！

77七 · 发表于 2025-8-23 09:24:40

回复 14# chishingchan

@echo off
cd /d "%~dp0"
(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"1.idt"') do (
if %%a leq 3 (
echo=%%b
) else (
set str=%%b@#@#
set /a n+=1
setlocal enabledelayedexpansion
for /f "tokens=1-2* delims=" %%c in ("!n!\!str: =\!") do (
echo !str:%%~nxe=%%c!
endlocal
>> "list.txt" echo %%d
)
)
)) > "2.idt"
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理如何从第4行起删除每行的行尾数字

评分

评分

评分

评分

浏览过的版块