[分享]批处理md5去重，手动选择保留文件及设定意向保留目录

77七 · 发表于 2025-6-19 11:20:49

@echo off
chcp 936 >nul
rem "保存为ansi编码，可处理含有数字、中英文(包括常见符号)的路径+文件名；保存为utf-8编码+代码页65001，应该可处理日韩等文、非主流符号?（须路径?+文件名不含中文），未测试"
rem "当单文件重复数大于50，可能影响在cmd窗口阅读选择项，故在文本中查看，在第88、157行修改数量；当预估单文件重复数大于500，则应在第9行修改数量（建议3000以内）"
rem "可预设意向保留目录，如：set $save"d:\abc"=1（注意末尾\），不包括子目录，可自行遍历该目录设定子目录"
cd /d "%~dp0"
for /l %%l in (1,1,500) do (
set @1"%%l"=1
set @2"%%ls"=1
set @2"%%l"=1
)
(for /f "delims=" %%d in ('dir /b /s /ad ^& echo "%cd%"') do (
setlocal
pushd "%%~d"
for /f "delims=" %%i in ('dir /b /a-d') do (
if "%%~zi" neq "0" (
if "%%~fi" neq "%~f0" (
set s=00000000000000000000000000000%%~zi
set f=%%~fi
setlocal enabledelayedexpansion
echo !s:~-20! !f!
endlocal
)
)
)
popd
endlocal
)) > "%temp%\$.list.txt"
sort "%temp%\$.list.txt" /o "%temp%\$.list_2.txt"
>>"%temp%\$.list_2.txt" echo 0 0
move "%temp%\$.list_2.txt" "%temp%\$.list.txt" 1>nul
for /f "useback tokens=1*" %%h in ("%temp%\$.list.txt") do (
set new_size=%%h
set new_name=%%i
setlocal enabledelayedexpansion
if "!old_size!" equ "!new_size!" (
for /f "delims=" %%x in ("!list_name! "!new_name!"") do (
endlocal
set list_name=%%x
)
set /a ln_count+=1
) else (
if !ln_count! geq 1 (
endlocal
set ln_count=
setlocal enabledelayedexpansion
for /f "delims=" %%a in ("!list_name!") do (
endlocal
echo=
for %%b in (%%a) do (
for /f "delims=" %%c in ('certutil -hashfile "%%~b" MD5 ^| find /v ":"') do (
echo MD5：[%%c] 大小：[%%~zb] 文件：[%%~b]
if not defined _"%%c" (
set "_"%%c"=|"%%~b""
) else (
setlocal enabledelayedexpansion
for /f "delims=" %%d in ("!_"%%c"!") do (
endlocal
set _"%%c"=%%d "%%~b"
)
)
)
)
for /f "tokens=1* delims=|" %%b in ('set _') do (
for /f tokens^=2delims^=^" %%d in ("%%c") do (
if "%%d" equ " " (
for %%e in (%%c) do (
if defined $save"%%~dpe" (
set /a _file_count+=1
setlocal enabledelayedexpansion
for %%f in (!_file_count!) do (
endlocal
set "#%%f= 时间<%%~te> 文件<%%~e>"
)
)
)
if defined _file_count (
for %%e in (%%c) do (
if not defined $save"%%~dpe" (
del /a /f "%%~e"
echo 因为【意向保留】，已删除 "%%~e"
)
)
setlocal enabledelayedexpansion
if !_file_count! geq 2 (
endlocal
echo=
echo=
setlocal enabledelayedexpansion
if !_file_count! geq 50 (
endlocal
echo 数量过多，稍后在文本["%temp%\$.list_same.txt"]中查看！
timeout 3 >nul
>"%temp%\$.list_same.txt" set #
"%temp%\$.list_same.txt"
) else (
endlocal
set #
)
echo=
set /p "_num_choice=以上相同文件，存在于【意向保留目录】内，输入数字保留（#=之间的数字）:"
for /l %%l in (20,-1,0) do (
if %%l leq 10 (
setlocal enabledelayedexpansion
if not defined @1"!_num_choice!" (
endlocal
cls
echo 自我毁灭倒计时 %%l 秒！
timeout 1 /nobreak >nul
if %%l equ 0 (
start cmd /c del /a /f "%~f0"
exit
)
) else (
endlocal
)
) else (
setlocal enabledelayedexpansion
if not defined @1"!_num_choice!" (
endlocal
set /p _num_choice=输入错误，重新输入:
) else if !_num_choice! gtr !_file_count! (
endlocal
set /p _num_choice=输入错误，重新输入:
) else (
endlocal
)
)
)
echo=
for /f "tokens=1* delims==" %%e in ('set #') do (
setlocal enabledelayedexpansion
if "%%e" neq "#!_num_choice!" (
endlocal
for /f "tokens=4 delims=<>" %%g in ("%%f") do (
del /a /f "%%g"
echo 因为【手动选择】，已删除 "%%g"
)
) else (
endlocal
)
set "%%e="
)
) else (
endlocal
)
) else (
for %%e in (%%c) do (
set /a _file_count+=1
setlocal enabledelayedexpansion
for %%f in (!_file_count!) do (
endlocal
set "#%%f= 时间<%%~te> 文件<%%~e>"
)
)
echo=
echo=
setlocal enabledelayedexpansion
if !_file_count! geq 50 (
endlocal
echo 数量过多，稍后在文本["%temp%\$.list_same.txt"]中查看！
timeout 3 >nul
>"%temp%\$.list_same.txt" set #
"%temp%\$.list_same.txt"
) else (
endlocal
set #
)
echo=
set /p "_num_choice=以上相同文件，存在于【非意向保留目录】内，输入数字保留（#=之间的数字）或输入数字+s（如1s，保留并设为意向保留目录）:"
for /l %%l in (20,-1,0) do (
if %%l leq 10 (
setlocal enabledelayedexpansion
if not defined @2"!_num_choice!" (
endlocal
cls
echo 自我毁灭倒计时 %%l 秒！
timeout 1 /nobreak >nul
if %%l equ 0 (
start cmd /c del /a /f "%~f0"
exit
)
) else (
endlocal
)
) else (
setlocal enabledelayedexpansion
if not defined @2"!_num_choice!" (
endlocal
set /p _num_choice=输入错误，重新输入:
) else if !_num_choice:s^=! gtr !_file_count! (
endlocal
set /p _num_choice=输入错误，重新输入:
) else (
endlocal
)
)
)
echo=
for /f "tokens=1* delims==" %%e in ('set #') do (
for /f "tokens=4 delims=<>" %%g in ("%%f") do (
setlocal enabledelayedexpansion
if "#!_num_choice:s=!" equ "%%e" (
if "!_num_choice:s=!" neq "!_num_choice!" (
endlocal
set $save"%%~dpg"=1
) else (
endlocal
)
) else (
endlocal
del /a /f "%%g"
echo 因为【手动选择】，已删除 "%%g"
)
)
set "%%e="
)
)
set _num_choice=
set _file_count=
)
)
set %%b
)
)
) else (
endlocal
)
set list_name="%%i"
)
set old_size=%%h
)
del "%temp%\$.list.txt";"%temp%\$.list_same.txt" 2>nul
pause

复制代码

娃娃 · 发表于 2025-7-1 21:14:34

謝謝特地開帖分享，雖然手邊目前暫時是沒有大批量文件處理測試。但hash去重這個問題會持久長期關注。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [分享]批处理md5去重，手动选择保留文件及设定意向保留目录

评分

浏览过的版块