[已解决]bat命令，如何判断哪个磁盘，哪个分区，是当前win系统启动盘？

ygqiang

bat命令，如何判断哪个磁盘，哪个分区，是当前win系统启动盘？
win系统下，计算机管理，磁盘管理，这里显示的磁盘号。

[已解决]
代码如下：

1. @echo off & setlocal enabledelayedexpansion
   
2. echo 代码开始
   
3. 
   
4. :star
   
5. cls
   
6. 
   
7. echo.
   
8. echo.
   
9. echo ------------------当前系统-启动磁盘-启动分区------------------1111
   
10. 
    
11. for /f "delims=" %%a in (
    
12.   'powershell "gwmi -computername '.' -namespace 'root\cimv2' -class 'win32_logicaldisktopartition'|%%{$ld=$_.__RELPATH.substring($_.__RELPATH.length-5,2);if($ld -eq '%systemDrive%'){$_.__RELPATH -replace '.*disk #(\d+),.*', '$1'}}" '
    
13. ) do echo,启动磁盘----磁盘%%a&echo,启动分区----%systemDrive%
    
14. echo,
    
15. 
    
16. echo ------------------当前系统-启动磁盘-启动分区------------------2222
    
17. for /l %%i in (0,1,25) do (
    
18.   for /f "tokens=3 delims= " %%a in (
    
19.     '(echo,select disk %%i ^&echo,detail disk^)^|diskpart^|findstr /rc:" 卷[ ]*[0-9]" '
    
20.   ) do if /i "%%a:"=="%SystemDrive%" echo,启动磁盘----磁盘%%i&echo,启动分区----%systemDrive%&goto[end])
    
21. :[end]
    
22. echo,&echo,
    
23. 
    
24. 
    
25. ping 0 -n 16 >nul 2>nul
    
26. goto :star

复制代码

aloha20200628

回复 1# ygqiang

参考此帖 8 楼》http://www.bathome.net/thread-70700-1-1.html

ygqiang

回复 2# aloha20200628


    多谢，最好用bat或者diskpart就能获取到。

ygqiang

顶。。。。

aloha20200628

回复 1# ygqiang

1. 
   
2. @echo off &for /f "tokens=2 delims=#," %%x in (
   
3.    ' "wmic logicaldisk where DeviceID='%systemDrive%' assoc /assocclass:Win32_LogicalDiskToPartition" '
   
4. ) do echo,系统启动盘符 %systemDrive% = 物理盘号 %%x
   
5. pause&exit/b
   

复制代码

ygqiang

回复 5# aloha20200628


    谢谢，除了wmic命令，有没有别的方法？
win11系统，新版本都不内置wmic了

aloha20200628

回复 3# ygqiang

以下代码存为 test.bat 运行，须先获得管理员权限，在其新窗口中启运 diskpart.exe 析取系统启动盘符与所对应的物理盘号，首次启运 diskpart.exe 须等候当前所有外接驱动器热连接，其运行效率明显低于5楼和8楼代码...

1. 
   
2. @echo off
   
3. %~1 powershell "start -file '%~f0' -arg '::' -verb runas" &exit/b
   
4. for /l %%i in (0,1,25) do (
   
5.   for /f "tokens=3 delims= " %%a in (
   
6.     '(echo,select disk %%i ^&echo,detail disk^)^|diskpart^|findstr /rc:" 卷[ ]*[0-9]" '
   
7.   ) do if /i "%%a:"=="%SystemDrive%" echo,系统启动盘符 %systemDrive% = 物理盘号 %%i &goto[end])
   
8. :[end]
   
9. pause&exit/b
   

复制代码

aloha20200628

回复 6# ygqiang

再给一个 bat+powershell 版本（存为 test.bat 运行），不必获取管理员权限，也无须等候当前所有外接硬盘完成热连接，效率明显高于 diskpart 版...

1. 
   
2. @echo off &for /f "delims=" %%a in (
   
3.   'powershell "gwmi -computername '.' -namespace 'root\cimv2' -class 'win32_logicaldisktopartition'|%%{$ld=$_.__RELPATH.substring($_.__RELPATH.length-5,2);if($ld -eq '%systemDrive%'){$_.__RELPATH -replace '.*disk #(\d+),.*', '$1'}}" '
   
4. ) do echo,系统启动盘符 %systemDrive% = 物理盘号 %%a
   
5. pause&exit/b
   

复制代码

aloha20200628

回复 1# ygqiang

再打磨一下8楼代码，句式还可更简洁，如下...

1. 
   
2. @echo off &for /f "delims=" %%a in (
   
3.    'powershell "gwmi win32_logicaldisktopartition|%%{$ld=$_.dependent.substring($_.dependent.length-3,2);if($ld -eq '%systemDrive%'){$_.antecedent -replace '.*Disk #(\d+).*', '$1'}}" ') do echo,系统启动盘符 %systemDrive% = 物理盘号 %%a
   
4. pause&exit/b
   

复制代码