批处理如何自动按文件夹名称批量重命名各自的文件？

gan537519 · 发表于 2024-7-30 23:05:05

本帖最后由 gan537519 于 2024-8-2 23:56 编辑

比如现在文件夹A，A里面有文件夹photo， document, data, other. 各个文件夹内有若干个文件。
那么在A里面双击bat后
photo里面的所有文件都加上前缀 picture
document里面的全部文件加上前缀 TX
data里面的全部文件加上前缀data
other的不处理。

包含当前目录和所有子目录下的文件夹都是这样处理。

77七 · 发表于 2024-7-31 00:07:07

@echo off
cd /d "%~dp0"
for %%a in ("_photo=picture" "_document=TX" "_data=data") do (
set %%~a
)
for /f "delims=" %%d in ('dir /b /ad') do (
if defined _%%d (
for /f "delims=" %%i in ('dir /b /s /a-d "%%d\*"') do (
call ren "%%i" "%%_%%d%%%%~nxi"
)
)
)
pause

复制代码

自行测试...

aloha20200628 · 发表于 2024-7-31 13:21:21

本帖最后由 aloha20200628 于 2024-8-3 08:45 编辑

回复 1# gan537519

给一个不用自定义变量%var%的版本...

@echo off &for %%d in (
"photo/picture"
"document/TX"
"data/data"
) do for /f "tokens=1-2 delims=/" %%a in ("%%~d") do (
pushd "%%a"
for /f "delims=" %%F in ('dir /b/a-d') do ren "%%F" "%%b_%%~nxF"
popd
)
pause&exit/b

复制代码

gan537519 · 发表于 2024-8-2 22:07:20

回复 gan537519

给一个不用自定义变量%var%的版本...
aloha20200628 发表于 2024-7-31 13:21

谢谢。当前目录下的可以，子目录下文件的不行。大佬看下能不能帮忙弄下在子目录也自动执行这些规则，比如photo 文件夹里面还有文件夹photo，第二个photo里的文件也自动重命名。other里面有document，这个document里的文件也自动重命名。

gan537519 · 发表于 2024-8-2 22:22:23

自行测试...
77七发表于 2024-7-31 00:07

谢谢。当前目录下的可以，子目录下的文件也自动按照根目录的执行，比如data里面有photo，photo的文件还是按data命名了。
大佬看下能不能帮忙弄下在子目录下的文件也自动按分类执行这些规则，比如data文件夹里面还有文件夹photo，这个photo里的文件自动重命名为picture。other里面有document，这个document里的文件也自动重命名TX。

77七 · 发表于 2024-8-2 22:40:59

回复 5# gan537519

包含当前目录和所有子目录下的文件都是这样处理。

描述为包含当前目录和所有子目录下的文件夹都是这样处理。是不是更为恰当？

@echo off
cd /d "%~dp0"
for %%a in ("_photo=picture" "_document=TX" "_data=data") do (
set %%~a
)
for /f "delims=" %%d in ('dir /b /s /ad') do (
if defined _%%~nxd (
for /f "delims=" %%i in ('dir /b /a-d "%%d\*"') do (
call ren "%%d\%%i" "%%_%%~nxd%%%%~nxi"
)
)
)
pause

复制代码

未测试。

gan537519 · 发表于 2024-8-2 23:52:51

回复 6# 77七

谢谢，测试可行。抱歉描述的不够准确。

gan537519 · 发表于 2024-8-3 00:51:13

回复 6# 77七

对了，前缀后应该有个"_", 但没有出来

77七 · 发表于 2024-8-3 01:13:21

回复 8# gan537519

%%～nxi指文件名，在前面加上就行。

aloha20200628 · 发表于 2024-8-3 07:45:18

本帖最后由 aloha20200628 于 2024-8-3 08:54 编辑

回复 4# gan537519

@echo off &set "kwl=photo/picture/document/TX/data/data"
for /f "delims=" %%F in ('dir /b/s/a-d') do (
set "_p=%%~pF"&setlocal enabledelayedexpansion
for %%p in ("!_p:~0,-1!") do for /f "delims=/" %%a in ("!kwl:*%%~nxp=!") do if /i "!kwl!" neq "!kwl:*%%~nxp=!" (ren "%%F" "%%a_%%~nxF")
endlocal
)
pause&exit/b

复制代码

aloha20200628 · 发表于 2024-8-3 09:29:57

本帖最后由 aloha20200628 于 2024-8-3 09:46 编辑

见 http://www.bathome.net/thread-69489-1-1.html 中3楼示例代码，验证 dir /b "c:\abc\123.txt\.." 可锚定目标文件 123.txt 所在目录，进一步可用
for %%P in ("c:\abc\123.txt\..") do set "p=%%~nxP"
直接提取目标文件 123.txt 所在目录名（没有尾部路径分隔符），据此可对10楼代码再造一个版本...

@echo off &set "kwl=photo/picture/document/TX/data/data"
for /f "delims=" %%F in ('dir /b/s/a-d') do (
set "_p=%%~pF"&setlocal enabledelayedexpansion
for %%P in ("%%F\..") do for /f "delims=/" %%a in ("!kwl:*%%~nxP=!") do if /i "!kwl!" neq "!kwl:*%%~nxP=!" (echo,ren "%%F" "%%a_%%~nxF")
endlocal
)
pause&exit/b

复制代码

gan537519 · 发表于 2024-8-3 14:28:49

回复 9# 77七

3Q

gan537519 · 发表于 2024-8-3 14:29:09

回复 10# aloha20200628

3Q

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理如何自动按文件夹名称批量重命名各自的文件？