[分享]批处理根据xpl文件内容复制文件

Batcher · 发表于 2023-8-21 18:17:37

【问题描述】

@echo off
cd /d "%~dp0"
set "NewFolder=我自己创建的"
if not exist "%NewFolder%" (
md "%NewFolder%"
)
for /f "delims=" %%i in ('dir /b /a-d *.xpl') do (
echo --- %%i
for /f tokens^=2^ delims^=^" %%a in ('type "%%i" ^| findstr "filename"') do (
set "MyFile=%%a"
setlocal enabledelayedexpansion
set "MyFile=!MyFile:\\isilon.zf.com\ADASdata\=Z:\!"
echo xcopy /y "!MyFile!" "!NewFolder!"
xcopy /y "!MyFile!" "!NewFolder!"
endlocal
)
)
pause

复制代码

就是针对上周的脚本又出现了新的需求
1.每个xpl文件里面读取的文件放到以xpl文件命名的文件夹
2.根据读取到的xpl文件内容找到前两分钟和后一分钟的文件

https://pan.baidu.com/s/1BTfzhFcD18uvPoGjFjQRlA?pwd=9wf4
就以这个为例
里面的文件名最后是619.sdf
往前两分钟就是617，618，往后一分钟就是620
最小的是001.sdf，最大的是999.sdf
不会超过这个区间

Batcher · 发表于 2023-8-21 18:18:00

【解决方案】

放到以xpl文件命名的文件夹.bat

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.xpl') do (
echo --- %%i
for /f tokens^=2^ delims^=^" %%a in ('type "%%i" ^| findstr "filename"') do (
set "MyFile=%%a"
setlocal enabledelayedexpansion
set "MyFile=!MyFile:\\isilon.zf.com\ADASdata\=Z:\!"
set "NewFolder=%%~ni"
if not exist "!NewFolder!" (
md "!NewFolder!"
)
echo xcopy /y "!MyFile!" "!NewFolder!"
xcopy /y "!MyFile!" "!NewFolder!"
endlocal
)
)
pause

复制代码

Batcher · 发表于 2023-8-21 18:18:33

1+2.bat

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.xpl') do (
echo --- %%i
for /f tokens^=2^ delims^=^" %%a in ('type "%%i" ^| findstr "filename"') do (
set "MyFile=%%a"
setlocal enabledelayedexpansion
set "MyFile=!MyFile:\\isilon.zf.com\ADASdata\=Z:\!"
set "NewFolder=%%~ni"
if not exist "!NewFolder!" (
md "!NewFolder!"
)
echo xcopy /y "!MyFile!" "!NewFolder!"
xcopy /y "!MyFile!" "!NewFolder!"
set "FileThis=1!MyFile:~-7,3!"
set /a FileBefore2=FileThis-2
set /a FileBefore1=FileThis-1
set /a FileAfter1=FileThis+1
if !FileThis! equ 1001 (
xcopy /y "!MyFile:~0,-8!!FileAfter1:~1!%%~xa" "!NewFolder!"
) else if !FileThis! equ 1002 (
xcopy /y "!MyFile:~0,-8!!FileBefore1:~1!%%~xa" "!NewFolder!"
xcopy /y "!MyFile:~0,-8!!FileAfter1:~1!%%~xa" "!NewFolder!"
) else if !FileThis! equ 1999 (
xcopy /y "!MyFile:~0,-8!!FileBefore2:~1!%%~xa" "!NewFolder!"
xcopy /y "!MyFile:~0,-8!!FileBefore1:~1!%%~xa" "!NewFolder!"
) else (
xcopy /y "!MyFile:~0,-8!!FileBefore2:~1!%%~xa" "!NewFolder!"
xcopy /y "!MyFile:~0,-8!!FileBefore1:~1!%%~xa" "!NewFolder!"
xcopy /y "!MyFile:~0,-8!!FileAfter1:~1!%%~xa" "!NewFolder!"
)
endlocal
)
)
pause

复制代码

yyz219 · 发表于 2023-8-22 07:59:32

1+2.bat
Batcher 发表于 2023-8-21 18:18

谢谢分享

jszw666 · 发表于 2023-8-22 09:17:52

鼓励辛苦了！学习

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [分享]批处理根据xpl文件内容复制文件

评分