[分享]批处理删除第一个位置参数获取其余参数

Batcher · 发表于 2023-7-24 20:28:20

【问题描述】

已知使用以下方式调用 test.bat 脚本：
test.bat "C:\Program Files\WinRAR" "File 1.txt" "File 2.txt" "File 3.txt"
这个时候，%*的值是：
"C:\Program Files\WinRAR" "File 1.txt" "File 2.txt" "File 3.txt"

怎样去掉第一个位置参数，并赋值给变量，得到：
FileList="File 1.txt" "File 2.txt" "File 3.txt"

Batcher · 发表于 2023-7-24 20:29:24

【解决方案】

test-1.bat

@echo off
setlocal enabledelayedexpansion
set "SkipFlag="
set "FileList="
for %%i in (%*) do (
if not defined SkipFlag (
set "SkipFlag=true"
) else if not defined FileList (
set "FileList=%%i"
) else (
set "FileList=!FileList! %%i"
)
)
echo,%FileList%

复制代码

Batcher · 发表于 2023-7-24 20:29:46

test-2.bat

@echo off
set "ArgsAll=%*"
call set "FileList=%%ArgsAll:*%1 =%%"
echo,%FileList%

复制代码

Batcher · 发表于 2023-7-24 20:39:23

test-3.bat

@echo off
set "FileList="
:Loop
shift
if not defined FileList (
set "FileList=%1"
) else (
set "FileList=%FileList% %1"
)
if "%~2" neq "" (
goto :Loop
)
echo,%FileList%

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [分享]批处理删除第一个位置参数获取其余参数

浏览过的版块