30元求助（已解决）

2652boy

具体报酬：30元
支付方式：支付宝
联系方式：QQ2652993952
有效期限：2023年5月20日之前。
需要批量移动jpg图片到指定文件夹；存在大批数据，每个都需要对应
如：G:\1953\民事庭\2098  中的jpg图片移动到 G:\1953\民事庭\2098\正卷 中
      G:\1953\民事庭\2099  中的jpg图片移动到 G:\1953\民事庭\2099\正卷 中

buyiyang

1. @echo off
   
2. rem 设置主目录，脚本保存为ansi编码
   
3. set "sd=G:\1953\民事庭"
   
4. 
   
5. cd "%sd%"
   
6. for /d %%i in (*) do robocopy "%%i" "%%i\正卷" *.jpg /mov
   
7. pause

复制代码

zaqmlp

bat需另存为ANSI/GB2312编码

1. @echo off&cd /d "%~dp0"&mode con lines=5000
   
2. for %%a in (
   
3. "G:\1953\民事庭|正卷"
   
4. "G:\1960\xxx|yyy"
   
5. ) do (
   
6.     for /f "tokens=1* delims=|" %%b in ("%%~a") do (
   
7.         for /f "delims=" %%i in ('dir /ad-h/b "%%~b" 2^>nul') do (
   
8.             if not exist "%%~b\%%~nxi\%%~c" md "%%~b\%%~nxi\%%~c"
   
9.             echo;"%%~b\%%~nxi\*.jpg" --^> "%%~b\%%~nxi\%%~c"
   
10.             move /y "%%~b\%%~nxi\*.jpg" "%%~b\%%~nxi\%%~c"
    
11.             echo;&echo;
    
12.         )
    
13.     )
    
14. )
    
15. pause
    
16. exit

复制代码

2652boy

buyiyang 发表于 2023-5-18 11:43

    已解决

qixiaobin0715

1. @echo off
   
2. cd /d "G:\1953\民事庭"
   
3. for /f "delims=" %%i in ('dir /b /ad') do (
   
4.     if exist "%%i\*.jpg" move "%%i\*.jpg" "%%i\正卷"
   
5. )
   
6. pause

复制代码

也可删除代码第2行，将批处理文件放在图片文件所在文件夹同一目录（在这里即是文件夹“民事庭”下）。