[分享]批处理获取用户名、计算机名、BIOS序列号生成csv文件

Batcher · 发表于 2022-4-26 13:54:55

【问题描述】
生成以下格式的csv文件

1,2,3
"Administrator","DESKTOP-BatHome","123456654321"

Batcher · 发表于 2022-4-26 13:55:12

【解决方案】

@echo off
(echo 1,2,3
for /f "tokens=2 delims==" %%i in ('wmic bios list full ^|findstr "SerialNumber"') do (
for /f %%j in ("%%i") do (
echo "%username%","%computername%","%%j"
)
))>"a.csv"

复制代码

Batcher · 发表于 2022-4-26 16:09:59

补充提问：该怎么第四列显示IP地址？

@echo off
(echo 1,2,3,4
for /f "tokens=2 delims==" %%i in ('wmic bios list full ^|findstr "SerialNumber"') do (
for /f %%j in ("%%i") do (
for /f "tokens=16" %%k in ('ipconfig ^|find /i "ipv4"') do (
echo "%username%","%computername%","%%j","%%k"
)
)
))>"a.csv"

复制代码

Batcher · 发表于 2022-4-26 21:53:13

@echo off
setlocal enabledelayedexpansion
set "OutFile=a.csv"
>"%OutFile%" echo 计算机名,域用户名,序列号,IP地址,子网掩码,网关,MAC地址,操作系统,WIN7型号,WIN10型号,出厂日期
for /f "tokens=2 delims==" %%i in ('wmic bios list full ^| findstr "SerialNumber"') do (
for /f %%j in ("%%i") do (
set "SN=%%j"
)
)
for /f "tokens=16" %%i in ('ipconfig ^| findstr /i "ipv4"') do set "IP=%%i"
for /f "tokens=15" %%i in ('ipconfig ^| findstr /i "子网掩码"') do set "Mask=%%i"
for /f "tokens=15" %%i in ('ipconfig ^| findstr /i "默认网关"') do set "Gateway=%%i"
for /f %%i in ('getmac /nh ^| findstr "..-..-..-..-..-.."') do set "MAC=%%i"
for /f "tokens=1* delims==" %%i in ('wmic os get caption /value ^| findstr "="') do (
for /f "delims=" %%k in ("%%j") do (
set "CaptionOS=%%k"
)
)
for /f "tokens=1* delims==" %%i in ('wmic csproduct get name /value ^| findstr "="') do (
for /f "delims=" %%k in ("%%j") do (
set "ProductName=%%k"
)
)
for /f "tokens=1* delims==" %%i in ('wmic csproduct get version /value ^| findstr "="') do (
for /f "delims=" %%k in ("%%j") do (
set "ProductVersion=%%k"
)
)
for /f "tokens=2 delims==" %%i in ('wmic bios get releasedate /value ^| findstr "="') do set "TS=%%i"
set "MyDate=!TS:~0,4!年!TS:~4,2!月!TS:~6,2!日"
>>"%OutFile%" echo "%computername%","%username%","!SN!","!IP!","!Mask!","!Gateway!","!MAC!","!CaptionOS!","!ProductName!","!ProductVersion!","!MyDate!"

复制代码

yyz219 · 发表于 2022-4-26 22:33:24

回复 4# Batcher

收藏备用，谢谢分享

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] [分享]批处理获取用户名、计算机名、BIOS序列号生成csv文件