[文本处理] [已解决]批处理如何将两个txt文本内容的每一行合并在一起

IGOfilm

比如我有a文本
aaaaa
bbbbb
ccccc
现在我想把b文本
11111
22222
33333
的每行追加到a文本后面去，变成
aaaaa11111
bbbbb22222
ccccc33333

求大佬指教

went

@echo off & cd /d "%~dp0"
set "f1=a.txt"
set "f2=b.txt"
(
	for /f "usebackq delims=" %%i in ("%f1%") do (
		set /p "s="
		call echo %%i%%s%%
	)
)<"%f2%">"%f1%_new"
move /y "%f1%_new" "%f1%"
pause&exit
复制代码

aloha20200628

@echo off & setlocal EnableDelayedExpansion
findstr /n .* a.txt > a.b
findstr /n .* b.txt >> a.b
set/a n=0
(for /f "delims=" %%s in ('sort a.b') do (
  set "z=%%s" & set "z=!z:*:=!"
  if !n! equ 1 (set/a n=0 & echo,!ls!!z!) else (set/a n+=1 & set ls=!z!)
))>ab.txt
del/q a.b

aloha20200628

再精简一步：
@echo off & setlocal EnableDelayedExpansion
findstr /n .* a.txt > a.b
findstr /n .* b.txt >> a.b
set/a n=0
(for /f "tokens=1* delims=:" %%1 in ('sort a.b') do (
      if !n! equ 1 (set/a n=0 & echo,!ls!%%2) else (set/a n+=1 & set ls=%%2)
))>ab.txt
del/q a.b

IGOfilm

回复 2# went


    感谢

IGOfilm

回复 4# aloha20200628


    感谢