批处理如何对字符串值的变量里的字符串值插入换行符

wjshan0808

如何对字符串值的变量里的字符串值插入换行符

不需要下面的结果

1. set param="this is demo"
   
2. echo %param%
   
3. ——结果——
   
4. this is demo
   
5. ——结果——
   

复制代码

而是需要以下的结果

1. ——结果——
   
2. this
   
3. is
   
4. demo
   
5. ——结果——

复制代码

idwma

1. set param=this is demo
   
2. set param=%param: =^&echo;%
   
3. echo %param%

复制代码

wjshan0808

回复 2# idwma

——结果——
this^&echo;is^&echo;demo
——结果——

this is not what I wanted

wjshan0808

回复 2# idwma

结果不是我想要的那个
    我在机器上测了

idwma

set param="this is demo"
把引号去掉

wjshan0808

回复 5# idwma


   如果

1. set param=this-is-demo

复制代码

一样是不能做到换行的

wjshan0808

回复 5# idwma

1. 
   
2. set paramA=this
   
3. set paramB=is
   
4. set paramC=demo
   
5. 
   
6. ::伪代码
   
7. %param% = %paramA%+换行+%paramB%+换行+%paramC%

复制代码

要类似的这种操作，
场景是
命令 PowerShell -c Get-ExecutionPolicy -List
获取 到多行结果
把行结果赋值给一个变量

Batcher

回复 1# wjshan0808

1. @echo off
   
2. set param="this is demo"
   
3. for %%i in (%param:~1,-1%) do (
   
4.     echo,%%i
   
5. )
   
6. pause

复制代码

Batcher

回复 7# wjshan0808

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set CrLf=^
   
4. 
   
5. 
   
6. set paramA=this
   
7. set paramB=is
   
8. set paramC=demo
   
9. set "param=%paramA%!CrLf!%paramB%!CrLf!%paramC%"
   
10. echo !param!
    
11. pause

复制代码

idwma

回复 6# wjshan0808

也能呀

1. set param=this-is-demo
   
2. set param=%param:-=^&echo;%
   
3. echo %param%

复制代码

cmd1152

1. set a="this is demo"
   
2. set a=%a: =^&echo(%
   
3. echo(%a%

复制代码

wjshan0808

回复 9# Batcher

非常感谢回复需求
代码如下

1. @echo off
   
2. 
   
3. setlocal enabledelayedexpansion
   
4. 
   
5. set psGetPolicy="& {Get-ExecutionPolicy -List;}"
   
6. call :executionPowerShell  %psGetPolicy%  policy
   
7. echo %policy%
   
8. 
   
9. pause
   
10. 
    
11. :executionPowerShell
    
12.   for /f "usebackq tokens=*" %%G in (`PowerShell -Command %1 `) do (
    
13.     set result=!result!%%G
    
14.   )
    
15.   set %2=!result!
    
16. goto:eof
    
17. 
    

复制代码

要的是 代码中的变量 policy 的值是如下格式的
即 命令 echo %policy% 输出如下格式
排版不用对齐，只要是一行一行的就行

1.         Scope ExecutionPolicy
   
2.         ----- ---------------
   
3. MachinePolicy       Undefined
   
4.    UserPolicy       Undefined
   
5.       Process       Undefined
   
6.   CurrentUser       Undefined
   
7. LocalMachine       Undefined

复制代码

而不是如下格式

1. Scope ExecutionPolicy----- ---------------MachinePolicy       UndefinedUserPolicy       UndefinedProcess       UndefinedCurrentUser       UndefinedLocalMachine       Undefined

复制代码

wjshan0808

回复 11# cmd1152

感谢回复，具体细节请看12楼

wjshan0808

回复 10# idwma


非常感谢多次回复，具体细节请看12楼

newswan

1. 
   
2. @echo off
   
3. setlocal enabledelayedexpansion
   
4. set LF=^&echo,
   
5. 
   
6. set psGetPolicy="& {Get-ExecutionPolicy -List;}"
   
7. call :executionPowerShell  %psGetPolicy%  policy
   
8. echo %policy%
   
9. 
   
10. pause
    
11. 
    
12. :executionPowerShell
    
13.   for /f "usebackq tokens=*" %%G in (`PowerShell -Command %1 `) do (
    
14.     set result=!result!%%G!LF!
    
15.   )
    
16.   set %2=!result!
    
17. goto:eof
    

复制代码