[分享]批处理两两合并文件并取首行内容作为新文件名

Batcher · 发表于 2021-9-27 17:47:40

【问题】
在一个文件夹里，批处理合并001.txt + 002.txt 合并后的新文件重命名为001.txt里的第一行文字，合并003.txt + 004.txt 合并后的新文件重命名为003.txt里的第一行文字，合并005.txt + 006.txt 合并后的新文件重命名为005.txt里的第一行文字......

Batcher · 发表于 2021-9-27 17:47:55

test1.bat

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "NewFolder=合并结果"
if not exist "%NewFolder%" (
md "%NewFolder%"
)
for /l %%i in (1001,2,1999) do (
set "FileA=%%~ni"
if exist "!FileA:~-3!.txt" (
set /a FileB=FileA+1
set /p NewFile=<"!FileA:~-3!.txt"
copy /b !FileA:~-3!.txt+!FileB:~-3!.txt "%NewFolder%\!NewFile!.txt"
)
)

复制代码

Batcher · 发表于 2021-9-27 18:16:29

test2.bat

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "NewFolder=合并结果"
if not exist "%NewFolder%" (
md "%NewFolder%"
)
set "n=0"
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
set /a n+=1
set /a m=n%%2
if !m! equ 0 (
set FileMerge="!FileMerge!"+"%%i"
copy /b !FileMerge! "%NewFolder%\!NewFile!.txt"
) else (
set "FileMerge=%%i"
set /p NewFile=<"%%i"
)
)

复制代码

qixiaobin0715 · 发表于 2021-9-27 20:41:35

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "NewFolder=合并结果"
if not exist "%NewFolder%" md "%NewFolder%"
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
if not defined n (
set /p NewFile=<"%%i"
set str=%%i
set n=true
) else (
copy !str!+%%i "%NewFolder%\!NewFile!.txt"
set n=
)
)
pause

复制代码

qixiaobin0715 · 发表于 2021-9-28 08:25:46

蹭个热度。通常情况下，如果路径中含有空格的话，执行dos命令时，含有空格的路径应当使用双引号。有2个命令可以例外，那就是标记路径的命令pushd和目录跳转命令cd，当它们后面含有空格路径时，可不加双引号直接使用。

Batcher · 发表于 2021-9-28 09:08:38

回复 5# qixiaobin0715

老版本的系统里面不加双引号会出错

qixiaobin0715 · 发表于 2021-9-28 21:20:33

回复 6# Batcher
win7 win10可以，没有xp系统。

Batcher · 发表于 2021-9-28 21:26:19

回复 7# qixiaobin0715

除了PC系统，还有一些老的Server版本的系统也是需要加双引号的。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [分享]批处理两两合并文件并取首行内容作为新文件名