批处理替换文件名，20元求助

coolzq1980

我的总文件夹下，有N个文件，N个文件夹，文件名（文件夹名）前面都是一样的，序号不一样，比如是（小猪1.jpg，小猪2.jpg，小猪3.png,小猪4.psd，.......）要替换成（小猫1.jpg，小猫2.jpg，小猫3.png,小猫4.psd，.......），文件夹更名也是同理

Batcher

回复 1# coolzq1980


test1.bat

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. cd /d "%~dp0"
   
4. 
   
5. set "OldStr=小猪"
   
6. set "NewStr=小猫"
   
7. 
   
8. for /f "delims=" %%i in ('dir /b /ad') do (
   
9.     set "OldFolder=%%i"
   
10.     set "NewFolder=!OldFolder:%OldStr%=%NewStr%!"
    
11.     ren "!OldFolder!" "!NewFolder!"
    
12. )
    
13. 
    
14. for /f "delims=" %%i in ('dir /b /a-d') do (
    
15.     if "%%i" neq "%~nx0" (
    
16.         set "OldFile=%%i"
    
17.         set "NewFile=!OldFile:%OldStr%=%NewStr%!"
    
18.         ren "!OldFile!" "!NewFile!"
    
19.     )
    
20. )

复制代码

Batcher

回复 1# coolzq1980


test2.bat

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. cd /d "%~dp0"
   
4. 
   
5. set "OldStr=小猪"
   
6. set "NewStr=小猫"
   
7. 
   
8. for /f "delims=" %%i in ('dir /b') do (
   
9.     if "%%i" neq "%~nx0" (
   
10.         set "OldName=%%i"
    
11.         set "NewName=!OldName:%OldStr%=%NewStr%!"
    
12.         ren "!OldName!" "!NewName!"
    
13.     )
    
14. )

复制代码

cmd1152

外面的小孩一直叫我，烦死了！

1. ren 小猪* 小猫*

复制代码

qixiaobin0715

回复 1# coolzq1980
楼主几次说法都不统一。我第一次理解是修改目标文件夹下文件名及子文件夹名，第二次理解为修改子文件夹名及子文件夹下的文件名，不知道楼主到底是什么意思，现在只有理解为修改目标文件夹中所有目录中的名称（包括范围内的所有文件夹及文件）。受到版主的启示，代码可以这样写：

1. @echo off
   
2. set "OldStr=小猪"
   
3. set "NewStr=小猫"
   
4. setlocal enabledelayedexpansion
   
5. cd /d D:\abc
   
6. for /f "delims=" %%a in ('dir /b /s ^|sort /r') do (
   
7. set str=%%~nxa
   
8. set str=!str:%OldStr%=%NewStr%!
   
9. ren "%%a" "!str!"
   
10. )
    
11. pause

复制代码

注意事项：
1.假设目标文件夹为D:\abc;
2.不要把批处理文件放在目标文件夹下；
3.代码中的sort /r，是为了先修改内层文件及文件夹，防止循环中改名后，目录改变而引起找不到路径的情况。