批处理怎样递归查找所有png复制到一个文件夹内，同名的递增重命名

Edwin_

1. pushd D:\phpstudy_pro\WWW\xdzmb
   
2.         for /r %%a in (*.png) do (
   
3.                 IF EXIST D:\phpstudy_pro\WWW\fff\%%~nxa (
   
4.                         COPY %%a%%^(1) "D:\phpstudy_pro\WWW\fff"
   
5.                 ) else (
   
6.                         COPY %%a "D:\phpstudy_pro\WWW\fff"
   
7.                 )
   
8.         )
   
9. popd
   
10. pause

复制代码

大概就是这个意思  这怎么改啊  在线等

tz_being

1. 
   
2. @echo off &pushd D:\phpstudy_pro\WWW\xdzmb
   
3. for /r %%i in (*.png) do (
   
4.     set "strName=%%~nxi" & set "n="
   
5.     call :CP "%%i"
   
6. )
   
7. pause & exit
   
8. 
   
9. :CP
   
10. if not exist "D:\phpstudy_pro\WWW\fff\%strName%" copy "%~1" "D:\phpstudy_pro\WWW\fff\%strName%" & goto :EOF
    
11. if exist "D:\phpstudy_pro\WWW\fff\%strName%" set /a n+=1
    
12. set "strName=%~n1(%n%)%~x1"
    
13. goto :CP
    

复制代码

cutebe

1. ::复制所有（包含子目录中）的png到目标目录，重名则添加/修改数字后缀。
   
2. @echo off
   
3. setlocal enableDelayedExpansion
   
4. 
   
5. set "sPath=D:\phpstudy_pro\WWW\xdzmb"
   
6. set "tPath=D:\phpstudy_pro\WWW\fff"
   
7. 
   
8. pushd %sPath%
   
9. for /f "delims=" %%i in ('dir/s/b/a-d *.png')do (
   
10.         if exist "%tPath%\%%~nxi" (
    
11.                 call :pngNum pngName "%%i"
    
12.                 copy "%%i" "%tPath%\!pngName!%%~xi"
    
13.         )else copy "%%i" "%tPath%"
    
14. )
    
15. popd
    
16. goto :eof
    
17. ::====完====
    
18. 
    
19. :pngNum pngName pngPath
    
20. setlocal
    
21. pushd %~dp2
    
22. set/am=1,@2=1
    
23. for /l %%n in (0 1 9)do set _%%n=%%n
    
24. set "strNum=%~n2"
    
25. :numlp        ::取末尾数字
    
26. if defined _%strNum:~-1% (
    
27.         set/aLen+=1,m*=10
    
28.         set n=%strNum:~-1%%n%
    
29.         set strNum=%strNum:~,-1%
    
30.         goto :numlp
    
31. )
    
32. if "%Len%"=="" set/a num1=Len=1&goto :nend
    
33. :nnext
    
34. set/an1=1%n%+1
    
35. set/ah=n1/m
    
36. set num1=!@%h%!!n1:~-%Len%!
    
37. if "%h%"==2 set/aLen+=1,m*=10
    
38. :nend
    
39. set "fName=%strNum%%num1%"
    
40. if exist "%tPath%\%fName%%~x2" set n=%num1%&goto :nnext
    
41. popd
    
42. endlocal&set "%1=%fName%"
    
43. goto :eof

复制代码

qixiaobin0715

利用以前写的代码进行修改，未经测试

1. @echo off
   
2. set path1=D:\phpstudy_pro\WWW\xdzmb
   
3. set path2=D:\phpstudy_pro\WWW\fff
   
4. setlocal enabledelayedexpansion
   
5. for /r %path1% %%a in (*.png) do (
   
6.     if not exist "%path2%\%%~nxa" (copy "%%a" "%path2%") else (
   
7.         if not exist "%path2%\%%~na (2)%%~xa" (copy "%%a" "%path2%\%%~na (2)%%~xa") else (
   
8.             set n=2
   
9.             for /f "delims=" %%b in ('dir /b /a-d %path2%\*^|findstr /r /be /c:"%%~na ([0-9][0-9]*)%%~xa"') do (
   
10.                 set "str=%%~nb"
    
11.                 set "m=!str:%%~na (=!"
    
12.                 set "m=!m:)=!"
    
13.                 if !m! gtr !n! set /a n=m
    
14.             )
    
15.             set /a n+=1
    
16.             copy "%%a" "%path2%\%%~na (!n!)%%~xa"
    
17.         )
    
18.     )
    
19. )
    
20. pause
    

复制代码