【已解决】求助VBS如何将文件夹下文本中的某些字符替换？

loveforjg

1. 某文件夹下有多个文本TXT
2. 需求： 将这些TXT文件中，PINORDER  PINSWAP FUNCTION后面的有文件名字符串的字符串替换为NAME RENAME。

RESC1608X50M.txt 内容如下：（详细见附件）

(DEVICE FILE: resc1608x50m)

PACKAGE resc1608x50m
CLASS IC
PINCOUNT 2

PINORDER resc1608x50m  1 2

PINSWAP resc1608x50m  1 2

FUNCTION resc1608x50m resc1608x50m  1 2

END

只替换：PINORDER  PINSWAP FUNCTION后面的文件名字符串，其他不变
（注意有的文本会有多行数据，见附件QFN50P600X600X80-41N.txt）
替换结果为：

(DEVICE FILE: resc1608x50m)

PACKAGE resc1608x50m
CLASS IC
PINCOUNT 2

PINORDER NAME  1 2

PINSWAP NAME    1 2

FUNCTION NAME RENAME 1 2

END

WHY

1. Rem On Error Resume Next
   
2. Dim reg1
   
3. Set reg1 = New RegExp
   
4. reg1.Pattern = "\b(PIN(?:ORDER|SWAP)[ \t]+)\S+"
   
5. reg1.Global = True
   
6. 
   
7. Dim reg2
   
8. Set reg2 = New RegExp
   
9. reg2.Pattern = "\b(FUNCTION[ \t]+)\S+([ \t]+)\S+"
   
10. reg2.Global = True
    
11. 
    
12. Dim fso, objFile, ext
    
13. Set fso = CreateObject("Scripting.FileSystemObject")
    
14. 
    
15. For Each objFile In fso.GetFolder(".").Files
    
16.     ext = fso.GetExtensionName(objFile.Path)
    
17.     If LCase(ext) = "txt" Then
    
18.         replaceStr objFile.Path
    
19.     End If
    
20. Next
    
21. 
    
22. Function replaceStr(filePath)
    
23.     Dim f, s
    
24.     Set f = fso.OpenTextFile(filePath)
    
25.     s = f.ReadAll
    
26.     s = reg1.Replace(s, "$1NAME")
    
27.     s = reg2.Replace(s, "$1NAME$2RENAME")
    
28.     f.Close
    
29.     fso.OpenTextFile(filePath, 2, True).Write(s)
    
30. End Function
    
31. 
    
32. MsgBox "Done"

复制代码

loveforjg

回复 2# WHY
大神您好! 再请教下，如果要把PIN SWAP打头这节的内容都去掉，表达式咋个改？（（注意有的文本会有多行数据）
输出为：
(DEVICE FILE: resc1608x50m)

PACKAGE resc1608x50m
CLASS IC
PINCOUNT 2

PINORDER NAME  1 2
FUNCTION NAME RENAME 1 2

END

WHY

回复 3# loveforjg


    把 PINORDER 和 FUNCTION 之后的字符改名，把 PINSWAP 及之后的多行数据删除，多行数据判断的依据：以逗号+回车换行结束。

1. Rem On Error Resume Next
   
2. Dim reg1
   
3. Set reg1 = New RegExp
   
4. reg1.Pattern = "\b(PINORDER[ \t]+)\S+"
   
5. reg1.Global = True
   
6. 
   
7. Dim reg2
   
8. Set reg2 = New RegExp
   
9. reg2.Pattern = "\b(FUNCTION[ \t]+)\S+([ \t]+)\S+"
   
10. reg2.Global = True
    
11. 
    
12. Dim reg3
    
13. Set reg3 = New RegExp
    
14. reg3.Pattern = "\bPINSWAP[ \t](?:[^\r\n,]|,\r\n)+(?:\r\n)?"
    
15. reg3.Global = True
    
16. 
    
17. Dim fso, objFile, ext
    
18. Set fso = CreateObject("Scripting.FileSystemObject")
    
19. 
    
20. For Each objFile In fso.GetFolder(".").Files
    
21.     ext = fso.GetExtensionName(objFile.Path)
    
22.     If LCase(ext) = "txt" Then
    
23.         replaceStr objFile.Path
    
24.     End If
    
25. Next
    
26. 
    
27. Function replaceStr(filePath)
    
28.     Dim f, s
    
29.     Set f = fso.OpenTextFile(filePath)
    
30.     s = f.ReadAll
    
31.     s = reg1.Replace(s, "$1NAME")
    
32.     s = reg2.Replace(s, "$1NAME$2RENAME")
    
33.     s = reg3.Replace(s, "")
    
34.     f.Close
    
35.     fso.OpenTextFile(filePath, 2, True).Write(s)
    
36. End Function
    
37. 
    
38. MsgBox "Done"

复制代码

loveforjg

回复 4# WHY
谢谢 膜拜大神！
FUNCTION的表达式为何后面多了一截 “([ \t]+)\S+”，有何讲究？