[已解决]如何写批处理保留备份文件夹里按日期命名的最新文件

tmp05 · 发表于 2020-9-11 10:46:25

本帖最后由 tmp05 于 2020-9-24 17:22 编辑

已设置了每日定时运行批处理备份文件到d:\bak文件夹，现要求定时移动旧的备份文件到d:\bakold，d:\bak只保留当前日期的最新备份，如bak20200911.rar

d:\bak下有以下以日期命名的备份文件，还有一些其它文件

bak20200909.rar
bak20200910.rar
bak20200911.rar
a.7z
b.7z
c.rar
......

试写了以下代码，帮修改下，谢谢！
forfiles /p "d:\bak\bak*.rar" /d -1 /c "cmd /c move /y @path d:\bakold\
这里是否能用通配符来表示bak开始的文件名？

tmp05 · 发表于 2020-9-12 20:31:30

是标题词不达意？

tmp05 · 发表于 2020-9-13 10:19:56

有经验的进，谢谢。

Batcher · 发表于 2020-9-13 22:17:04

回复 1# tmp05

@echo off
setlocal enabledelayedexpansion
set "SrcFolder=D:\bak"
set "DstFolder=D:\bakold"
if not exist "%DstFolder%" (
md "%DstFolder%"
)
echo 获取系统日期
for /f "delims=" %%i in ('powershell -c "Get-Date -UFormat '%%Y%%m%%d'"') do (
set "SysTS=%%i"
)
pushd "%SrcFolder%"
for /f "delims=" %%i in ('dir /b /a-d "bak*.rar"') do (
set "FileName=%%i"
set "FileDate=!FileName:~3,8!"
if "!FileDate!" neq "%SysTS%" (
move /y "!FileName!" "%DstFolder%"
)
)
popd

复制代码

tmp05 · 发表于 2020-9-24 17:21:52

回复 4# Batcher
回复迟了，试了，能用，感谢！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]如何写批处理保留备份文件夹里按日期命名的最新文件

评分