[文本处理] 求个BAT删除空格和指定字符追加到另一文件

bh62549

1.txt  
2.txt   
平时每天都要向1.txt添加新数据，每次都是PilotEdit打开添加，如果一天好几次就有点麻烦，现在想用bat添加，不知道如何下手，其中1.txt中的数据是12位字符串，每一行都是12位无空格，2.txt是16位字符串，每一行都是16位有空格，每次都是手动把16位字符改成12位的（把第7，8，15，16位删除）
16位：11 BB CD 99 11 A1 AA 5C
12位：11BBCD11A1AA
改成12位再添加到1.txt,如果是添加几行数据倒是无所谓了，要是上百就难了
下面是我单单写成合并都难了，

@ ECHO OFF
@ ECHO.
set /p a=<"F:\TXT\1.txt"
type "F:\TXT\1.txt" >> "F:\TXT\2.txt" \n
@ ECHO 已成功添加文本
pause
复制代码

可是把2.txt向1.txtx添加不是在最后换行后才追加，比如：
1.txt中数据是
1A20A1DBA719
AA217742BCAB
2.txt中数据是
AB CD 09 81 15 AB 03 C3
11 BB CD 99 15 A1 6A 5C
12 BB CD 99 41 A1 A3 AC
13 BB CD DD 34 A1 A1 CC
21 BD 1D 39 14 A1 3A 5C
运行bat后成了
1A20A1DBA719
AA217742BCABAB CD 09 81 15 AB 03 C3
11 BB CD 99 15 A1 6A 5C
12 BB CD 99 41 A1 A3 AC
13 BB CD DD 34 A1 A1 CC
21 BD 1D 39 14 A1 3A 5C
我想追加后1.txt的是在下一行写入

zaqmlp

@echo off
set info=互助互利,支付宝扫码头像,感谢打赏
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
set "f1=1.txt"
set "f2=2.txt"
(for /f "delims=" %%a in ('type "%f1%"') do echo;%%a)>"%tmp%\t.t"
(for /f "delims=" %%a in ('type "%f2%"') do (
    set "line=%%a"
    setlocal enabledelayedexpansion
    set "line=!line: =!"
    echo;!line:~,6!!line:~8,6!
    endlocal
))>>"%tmp%\t.t"
copy /y "%tmp%\t.t" "%f1%"
echo;%info%
pause
复制代码

bh62549

BAT完美。就是我的1.txt文件比较大（7.5G），添加数据有点久

运行了一个小时还没有添加完？？

terse

试试这样可以提高点效率

@echo off & setlocal enabledelayedexpansion
set "f1=1.txt"
set "f2=2.txt"
(for /f %%i in ('findstr /v $ !f1!') do echo.
for /f "delims=" %%i in (!f2!) do (
     set "s=%%i"
     set s=!s: =!
     echo;!s:~,6!!s:~8,6!
))>>"!f1!"
pause
复制代码

bh62549

有办法把2.tx中要追加的数据删除重复再追加吗？？

terse

@echo off & setlocal enabledelayedexpansion
set "f1=1.txt"
set "f2=2.txt"
(for /f %%i in ('findstr /v $ !f1!') do echo.
for /f "delims=" %%i in (!f2!) do (
     set "s=%%i"
     set s=!s: =!
     set s=!s:~,6!!s:~8,6!
     if not defined _!s! echo;!s!
     set _!s!=1
))>>"!f1!"
pause
复制代码

回复 5# bh62549

bh62549

回复 6# terse
如果是单纯修改2.txt的内容（16转12+去重复），不要追到1,txt，这个怎么改了。
我试了bat发现如果是要追加到我的文件里（7.5G）会很慢慢。一个小时过去还没有成功添加，可能是我的文件太大了。看来只能用PilotEdit打开添加了

bh62549

回复 2# zaqmlp


    有办法把2.tx中要追加的数据删除重复再追加吗？？