[文本处理] 批处理替换文件名请求

WilSon123

有个问题需要请教，文件名为：4450036992YSMZZW.jpg,想保留数字+后面英文变为-311，就是4450036992-311.jpg,该怎么写好，谢谢大家。

zaqmlp

@echo off
for /f "delims=" %%a in ('dir /a-d/b/l *.jpg^|findstr "^[0-9][0-9]*[a-z]"') do (
    for /f "delims=abcdefghijklmnopqrstuvwxyz" %%b in ("%%a") do echo;ren "%%a" "%%b-311%%~xa"
)
pause
复制代码

WilSon123

谢谢楼上的分享，我想问下delims=abcdefghijklmnopqrstuvwxyz的指保留的意思吗？没有改到

Batcher

回复 3# WilSon123


    把第三行的 echo; 删掉试试

WilSon123

回复 4# Batcher
改成了4450036992ysmzzw.jpg-311.jpg

Batcher

@echo off
for /f "delims=" %%a in ('dir /a-d /b /l *.jpg') do (
    for /f "delims=abcdefghijklmnopqrstuvwxyz" %%b in ("%%a") do (
        ren "%%a" "%%b-311%%~xa"
    )
)
复制代码

我这边测试2楼方案没有问题

c:\Test>dir /b *.jpg
4450036992YSMZZW.jpg

c:\Test>test.bat

c:\Test>dir /b *.jpg
4450036992-311.jpg

WilSon123

回复 6# Batcher
问题解决了，多谢二楼和三楼的，另外如果有4450036992yszzw，4450036992zszzw,改为 4450036992-311，4450036992-312，这个改怎么写，是否需要判断

Batcher

回复 7# WilSon123

@echo off
setlocal enabledelayedexpansion
set n=311
for /f "delims=" %%a in ('dir /a-d /b /l *.jpg') do (
    for /f "delims=abcdefghijklmnopqrstuvwxyz" %%b in ("%%a") do (
        ren "%%a" "%%b-!n!%%~xa"
        set /a n+=1
    )
)
复制代码