（已解决）批处理怎样修改注册表路径导入注册表？

wchong

求reg注册表文件，主键替换后导入注册表的批处理

把reg注册表文件，拖拽到批处理上，完成替换文件内主键！
替换主键规则如下：
HKEY_LOCAL_MACHINE\SYSTEM        替换为   HKEY_LOCAL_MACHINE\PE-SYS
HKEY_LOCAL_MACHINE\SOFTWARE    替换为  HKEY_LOCAL_MACHINE\PE-SOF
HKEY_USERS\.DEFAULT                      替换为  HKEY_LOCAL_MACHINE\PE-DEF
HKEY_CLASSES_ROOT\Directory         替换为  HKEY_LOCAL_MACHINE\PE-SOF\Classes\Directory
HKEY_CURRENT_USER\Software         替换为   HKEY_LOCAL_MACHINE\PE-DEF\Software

例；源文件   HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\StartPage2
替换后   HKEY_LOCAL_MACHINE\PE-DEF\Software\Microsoft\Windows\CurrentVersion\Explorer\StartPage2
如规则内没有文件所需，提示后退出修改！修改主键完成以后保存文件，然后安照替换过的主键导入注册表内！…求大师们帮忙
这里有个REG 文件，用来测试用

窄口牛

那不是很简单吗，记事本查找替换就行了。

WHY

举例：

1. @echo off
   
2. set "root=HKEY_LOCAL_MACHINE"
   
3. PowerShell "(type a.reg) -replace '%root%\\SYSTEM', '%root%\PE-SYS' -replace '%root%\\SOFTWARE', '%root%\PE-SOF'>b.reg"
   
4. pause

复制代码

xinxing124

可以试试下面这种方式（拖拽a.reg到批处理文件上）：

1. @echo off
   
2. (For /f "delims=" %%i in (%1) do (Set str=%%i
   
3. SetLocal EnableDelayedExpansion
   
4. Set str=!Str:HKEY_LOCAL_MACHINE\SYSTEM=HKEY_LOCAL_MACHINE\PE-SYS!
   
5. Set str=!Str:HKEY_LOCAL_MACHINE\SOFTWARE=HKEY_LOCAL_MACHINE\PE-SOF!
   
6. Set str=!Str:HKEY_USERS\.DEFAULT=HKEY_LOCAL_MACHINE\PE-DEF!
   
7. Set str=!Str:HKEY_CLASSES_ROOT\Directory=HKEY_LOCAL_MACHINE\PE-SOF\Classes\Directory!
   
8. Set str=!Str:HKEY_CURRENT_USER\Software=HKEY_LOCAL_MACHINE\PE-DEF\Software!
   
9. echo !str!
   
10. EndLocal
    
11. ))>b.reg
    
12. start b.reg
    

复制代码

wchong

注册表拖拽到批处理上面，会生成一个B.reg的文件，但是内容却是空白的。所以导入也是失败回复 4# xinxing124

xczxczxcz

把注册表文件等拖入双击运行后的窗口中。

1. 
   
2. @echo off
   
3. cd/d "%~dp0"
   
4. setlocal EnableDelayedExpansion
   
5. echo 把注册表文件拖到窗口中
   
6. set /p var=
   
7. for /f "delims=" %%a in ('type %var%') do (
   
8.         set "str=%%a"
   
9.         if "!str:~0,1!"=="[" echo;>>NewReg.reg
   
10.         SET "str=!str:HKEY_LOCAL_MACHINE\SYSTEM=HKEY_LOCAL_MACHINE\PE-SYS!"
    
11.         SET "str=!str:HKEY_LOCAL_MACHINE\SOFTWARE=HKEY_LOCAL_MACHINE\PE-SOF!"
    
12.         SET "str=!str:HKEY_USERS\.DEFAULT=HKEY_LOCAL_MACHINE\PE-DEF!"
    
13.         SET "str=!str:HKEY_CLASSES_ROOT\Directory=HKEY_LOCAL_MACHINE\PE-SOF\Classes\Directory!"
    
14.         set "str=!str:HKEY_CURRENT_USER\SOFTWARE=HKEY_LOCAL_MACHINE\PE-DEF\SOFTWARE!"
    
15.         ECHO !str!>>NewReg.reg
    
16. )
    
17. echo 按任意键导入注册表 & pause >nul & regedit /s NewReg.reg
    
18. pause & exit
    

复制代码

============================

wchong

回复 6# xczxczxcz


    谢谢！有没有办法以管理员身份运行也能实现同样效果，这个批处理是和别的脚本一起使用，别的几个需要管理员权限

xczxczxcz

回复 7# wchong

参考 http://www.bathome.net/thread-49107-1-1.html
在批的@echo off 的末尾回车再加上

1. 
   
2. >nul 2>&1 "%windir%\system32\cacls.exe" "%windir%\system32\config\system"
   
3. if '%errorlevel%' NEQ '0' (  echo UAC... & goto UACPrompt ) else goto gotAdmin
   
4. :UACPrompt
   
5. echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
   
6. echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
   
7. "%temp%\getadmin.vbs"
   
8. exit /B
   
9. :gotAdmin
   
10. if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
    

复制代码

其它的批也加上。
win7 + 的系统都可以用。

Batcher

回复 7# wchong


试试这几个方法：
http://bbs.bathome.net/thread-49107-1-1.html

xinxing124

回复 5# wchong


    还真是，之前试验是建立了个txt文件试验的没问题，早上试了reg文件是空的。还要改下：
其中的 %file% 改成 'type %file%' 就可以了。

1. @echo off
   
2. set file=%1
   
3. (For /f "delims=" %%i in ('type %file%') do (Set str=%%i
   
4. SetLocal EnableDelayedExpansion
   
5. Set str=!Str:HKEY_LOCAL_MACHINE\SYSTEM=HKEY_LOCAL_MACHINE\PE-SYS!
   
6. Set str=!Str:HKEY_LOCAL_MACHINE\SOFTWARE=HKEY_LOCAL_MACHINE\PE-SOF!
   
7. Set str=!Str:HKEY_USERS\.DEFAULT=HKEY_LOCAL_MACHINE\PE-DEF!
   
8. Set str=!Str:HKEY_CLASSES_ROOT\Directory=HKEY_LOCAL_MACHINE\PE-SOF\Classes\Directory!
   
9. Set str=!Str:HKEY_CURRENT_USER\Software=HKEY_LOCAL_MACHINE\PE-DEF\Software!
   
10. echo !str!
    
11. EndLocal
    
12. ))>b.txt
    
13. start b.txt
    
14. pause

复制代码

wchong

回复 10# xinxing124


    多谢，已解决