如何实现将文件名中的中文数字转换成阿拉伯数字并且不够指定位数的在前面添加前导0

mm123321

【难度】麻烦大神帮我看一下怎么写呢 就是如下图所示！
原文件名称                批处理修改后的文件名称
第一章 XXXXXXXX 第一节 XXXXX.avi        →        第01章 XXXXXXXX 第01节 XXXXX.avi
第一章 XXXXXXXX 第二节 XXXXX.avi        →        第01章 XXXXXXXX 第02节 XXXXX.avi
第一章 XXXXXXXX 第三节 XXXXX.avi        →        第01章 XXXXXXXX 第03节 XXXXX.avi
第一章 XXXXXXXX 第四节 XXXXX.avi        →        第01章 XXXXXXXX 第04节 XXXXX.avi
第二章 XXXXXXXX 第一节 XXXXX.avi        →        第02章 XXXXXXXX 第01节 XXXXX.avi
第二章 XXXXXXXX 第二节 XXXXX.avi        →        第02章 XXXXXXXX 第02节 XXXXX.avi
第二章 XXXXXXXX 第三节 XXXXX.avi        →        第02章 XXXXXXXX 第03节 XXXXX.avi
第二章 XXXXXXXX 第四节 XXXXX.avi        →        第02章 XXXXXXXX 第04节 XXXXX.avi
第二章 XXXXXXXX 第五节 XXXXX.avi        →        第02章 XXXXXXXX 第05节 XXXXX.avi
第二章 XXXXXXXX 第六节 XXXXX.avi        →        第02章 XXXXXXXX 第06节 XXXXX.avi
第二章 XXXXXXXX 第七节 XXXXX.avi        →        第02章 XXXXXXXX 第07节 XXXXX.avi
               
另外当遇到→就是序号不是两位的补0成为两位的               
原文件名称                批处理修改后的文件名称
第01章 XXXXXXXX 第1节 XXXXX.avi        →        第01章 XXXXXXXX 第01节 XXXXX.avi
第01章 XXXXXXXX 第2节 XXXXX.avi        →        第01章 XXXXXXXX 第02节 XXXXX.avi
第01章 XXXXXXXX 第3节 XXXXX.avi        →        第01章 XXXXXXXX 第03节 XXXXX.avi
第01章 XXXXXXXX 第4节 XXXXX.avi        →        第01章 XXXXXXXX 第04节 XXXXX.avi
第02章 XXXXXXXX 第01节 XXXXX.avi        →        第02章 XXXXXXXX 第01节 XXXXX.avi
第02章 XXXXXXXX 第02节 XXXXX.avi        →        第02章 XXXXXXXX 第02节 XXXXX.avi
第02章 XXXXXXXX 第03节 XXXXX.avi        →        第02章 XXXXXXXX 第03节 XXXXX.avi
第02章 XXXXXXXX 第04节 XXXXX.avi        →        第02章 XXXXXXXX 第04节 XXXXX.avi
第02章 XXXXXXXX 第05节 XXXXX.avi        →        第02章 XXXXXXXX 第05节 XXXXX.avi
第02章 XXXXXXXX 第06节 XXXXX.avi        →        第02章 XXXXXXXX 第06节 XXXXX.avi
第02章 XXXXXXXX 第07节 XXXXX.avi        →        第02章 XXXXXXXX 第07节 XXXXX.avi

mm123321

版主帮我总结的标题就是我要表达的意思，神人版主！

taofan712

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for %%a in (*.avi) do (
   
4.     set "fn=%%~a"
   
5.     for /f "tokens=1,3 delims= " %%b in ("%%~a") do (
   
6.         for /f "tokens=1,2 delims=第章节 " %%d in ("%%b%%c") do (
   
7.             set tmpstr_d=%%dfedcba9876543210&set/a len_d=0x!tmpstr_d:~15,1!
   
8.             set tmpstr_e=%%efedcba9876543210&set/a len_e=0x!tmpstr_e:~15,1!
   
9.             call :change %%d !len_d! ret_d
   
10.             call :change %%e !len_e! ret_e
    
11.             call set fnew=%%fn:第%%d章=第!ret_d!章%%
    
12.             call set fnew=%%fnew:第%%e节=第!ret_e!节%%
    
13.             ren "%%~a" "!fnew!"
    
14.         )
    
15.     )
    
16. )
    
17. echo;处理完毕&pause>nul&exit /b
    
18. 
    
19. :change
    
20. set num=%1
    
21. set n=1
    
22. for %%i in (一 二 三 四 五 六 七 八 九) do (
    
23.     call set num=%%num:%%i=!n!%%
    
24.     set /a n+=1
    
25. )
    
26. if %2 equ 1 set num=%num:十=10%
    
27. if %2 equ 2 (
    
28.     set lastone=!num:~-1!
    
29.     if "!lastone!"=="十" (set num=%num:十=0%) else (set num=%num:十=1%)
    
30. )
    
31. if %2 equ 3 set num=%num:十=%
    
32. set num=000%num%
    
33. set num=%num:~-3%
    
34. endlocal&set %3=%num%&goto :eof

复制代码

可以处理 “三位数” 以下的，比如第九十九章，替换成099章
仅修改章节处的数字，比如 第十三章 七个小矮人 第十节 一把魔镜.avi，替换成 第013章 七个小矮人 第010节 一把魔镜.avi
若只需要保留两位数，把倒数第二行代码中-3改为-2

zghwelcome

学习了，写的很秒！
转换好像稍有问题
实测：第九十九章 XXXXXXXX 第二十二节 XXXXX.avi
         第909章 XXXXXXXX 第202节 XXXXX.avi

if %2 equ 3 set num=%num:十=0%   调整为  if %2 equ 3 set num=%num:十=%  后正常

taofan712

回复 4# zghwelcome


    感谢提醒，三位数确实应该把十替换为空，之前不知道怎么弄错了。

刚好还想到另外一个问题，两位数的中文数字还应该判断‘十’在个位还是在十位上，如二十和十二分别替换为0或1.

happy886rr

凑个热闹

1. 
   
2. @echo off
   
3. REM 开启变量延迟
   
4. setlocal enabledelayedexpansion
   
5. 
   
6. REM 构建基表
   
7. set "hSTRING=零一二三四五六七八九"
   
8. 
   
9. REM 构建0~99的汉字数字转换表
   
10. for /l %%a in (0,1,9) do (
    
11.         for /l %%b in (0,1,9) do (
    
12.                 if %%b equ 0 (
    
13.                         set "____!hSTRING:~%%a,1!十=%%a0"
    
14.                 ) else if %%a equ 0 (
    
15.                         set "____!hSTRING:~%%b,1!=0%%b"
    
16.                 ) else if %%a equ 1 (
    
17.                         set "____十!hSTRING:~%%b,1!=1%%b"
    
18.                 ) else if %%a gtr 1 (
    
19.                         set "____!hSTRING:~%%a,1!十!hSTRING:~%%b,1!=%%a%%b"
    
20.                 )
    
21.         )
    
22. )
    
23. 
    
24. REM 遍历子目录
    
25. for /r %%a in (*.avi) do (
    
26. 
    
27.         REM 获取章节
    
28.         for /f "tokens=1,2,3* delims=第章节" %%A in ("%%~nxa") do (
    
29. 
    
30.                 REM 将章节转化为数码
    
31.                 set "chapterNUM=!____%%A!"
    
32.                 set "sectionNUM=!____%%C!"
    
33. 
    
34.                 REM 真的纯数字直接凑齐两位
    
35.                 if not defined chapterNUM (
    
36.                         if "%%A"=="十" (
    
37.                                 set/a "chapterNUM=10"
    
38.                         ) else (
    
39.                                 set/a "chapterNUM=100+%%A"
    
40.                         )
    
41.                 )
    
42.                 if not defined sectionNUM (
    
43.                         if "%%C"=="十" (
    
44.                                 set/a "sectionNUM=10"
    
45.                         ) else (
    
46.                                 set/a "sectionNUM=100+%%C"
    
47.                         )
    
48.                 )
    
49. 
    
50.                 echo 正在重命名...   "%%~nxa"
    
51.                 ren "%%a" "第!chapterNUM:~-2!章%%B第!sectionNUM:~-2!节%%D"
    
52.         )
    
53. )
    
54. 
    
55. REM 更名完毕
    
56. pause
    

复制代码

taofan712

回复 6# happy886rr


    代码精练！ 有个小瑕疵，如  "第十章"

happy886rr

回复 7# taofan712

好说，已改。你的for内部调用call会减慢速度。不过ren本身就是外部exe，更会拖慢速度。这个批怎么写都慢速。看来还得用gawk的改造版: gawkren.exe去瞬间更名。
对了，你的代码缺少注释，至少也得标明下每块是做啥的，便于他人查阅了解思路。
打表快，以空间换时间，你需要尽量避免for中大量call，call的解释机制会重载脚本，增加读取开销。