[文本处理] 批处理如何实现全盘查找文本中列出的多个文件夹并把这些文件夹里的文件复制到指定目录

a0702130270

求帮助批处理
@echo off
set "pth=C:
for /f "delims=" %%a in (b.txt) do (
  for /f "delims=" %%b in ('dir /a-d /b /s "%pth%\%%a"') do (
    set "p=%%~dpb"
    call xcopy "%%b" "%%p:%pth%=C:\Users\Administrator\Desktop\猪八戒%%" /y
  )
)


上述代码我想改成搜索全电脑，保存的文件夹不要出现原始目录，直接把文件放在猪八戒下就可以了，谢谢

GNU

遍历一下C到Z就行了
你在论坛里面搜索全盘能找到很多例子

a0702130270

回复 2# GNU


    求赐教，帮忙写一下可以吗？我实在弄不出来

CommandBatCmd

回复 1# a0702130270

@echo off
:: 全盘查找“b.txt”中列出的文件，并拷贝到指定目录中。
set "S=C:\Users\Administrator\Desktop\猪八戒"
for %%Z in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  for /f "delims=" %%a in (b.txt) do (
    for /f "delims=" %%b in ('dir /a-d /b /s "%%Z:\%%a"') do (
        if /i not "%%~dpb"=="%S%" (
          xcopy "%%b" "%S%" /y
        )
    )
  )
)
复制代码

a0702130270

回复 4# CommandBatCmd


    谢谢大神

a0702130270

回复 4# CommandBatCmd


    我还想请问，我想找目录，txt里面输入目录名，目录连带里面的文件都复制过来，批处理改一下给我好吗？

CommandBatCmd

回复 6# a0702130270


    是不是复制来源文件时，也复制来源文件的目录结构，是这个意思吧！？

a0702130270

回复 7# CommandBatCmd


不需要保留结构，直接把目录及目录下的文件复制到猪八戒里

CommandBatCmd

回复 8# a0702130270

@echo off
:: 全盘查找“b.txt”中列出的目录，并把其下全部文件拷贝到指定目录中。
set "_S=C:\Users\Administrator\Desktop\猪八戒"   ||@REM 自定义保存目录，尾部不要“\”
set "_F=b.txt"                                   ||@REM 自定义查找的目录列表，不要路径
for %%A in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%A:\ (
    for /f "delims=" %%B in (%_F%) do (
      for /f "delims=" %%C in ('dir /ad/b/s "%%A:\" 2^>NUL') do (
        if /i not "%%~dpC"=="%_S%\" (
          if /i "%%~nxC"=="%%B" (
            for /f "delims=" %%D in ('dir /s/b/a-d "%%C" 2^>NUL') do (
              xcopy /h/y "%%D" "%_S%"
            )
          )
        )
      )
    )
  )
)

PAUSE
复制代码

a0702130270

回复 9# CommandBatCmd


    大神，跟上面同样的方法，只是把txt里面的  文件名 换成 目录，然后作用就是搜索目录并复制下面的所有文件到指定位置，能修改一下吗？
    这个我更需要，拜谢大神