设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT原创&转载 › BAT转载代码 › 批处理编程的异类：游戏、数学、时钟（延时）等 ...
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发新帖
查看: 28083|回复: 13

批处理编程的异类：游戏、数学、时钟（延时）等

[复制链接]
Batcher
发表于 2009-3-12 19:48:47 | 显示全部楼层 |阅读模式
原文地址：http://www.cn-dos.net/forum/viewthread.php?tid=8905
　　学过ＤＯＳ的人，或多或少都听过批处理。它小巧轻便，而且是系统级源代码解释，不用编译和连接而直接运行，曾经吸引了不少ＤＯＳ的爱好者和编程者。众多人士的参与，无数奇思妙想的涌现，构成了批处理编程中的＂异类＂。它们并不是单纯为解决某些＂成批处理的问题＂而设计，而是真正将批处理做为一种语言，来体现它无限的创造力。

　　下面是我搜集的一些批处理程序，他们或许并非是技术上的精品，但绝对是构思上的突破。我会不断的更新和完善这个主题，也希望大家同我一道努力，完成这个＂异类＂收藏。

　　索引
＝＝＝＝＝＝
1楼：本主题
2楼：游戏（Game）：
    1、三子棋（TicTacToe）
3楼：数学（Math）：
    1、随机数（Random）生成、随机矩阵生成，共2个
    2、2K/XP表达式计算
4楼：时钟（Clock）：
    1、暂停（Pause）、延迟（Delay）、等待（Wait）或睡眠（Sleep），共5个

　　声明
＝＝＝＝＝＝

　　１，为保持本帖的结构，仅为赞美和支持的同志请尽量不要在此回帖；
　　２，对本帖某些程序有任何疑问和建议的朋友，请访问下面的主题
　　　　http://www.cn-dos.net/forum/viewthread.php?tid=12388
　　３，有意推荐程序的朋友，请注意以下的选择标准：
　　　（１），程序实现的功能具有一定的通用性和创新性；
　　　（２），程序不依赖于任何特殊或定制的本地环境（比如程序的路径）；
　　　（３），程序未使用任何第三方工具或者软件；
　　　（４），程序最好适用于所有的 Windows 和 DOS 平台，如有特殊要求请注明；
　　４，本主题采用淘汰制，即完成相同或相似功能的代码将采用编写质量最优秀者，无法区分优劣时，或者同时在一帖内列出，或者融合二者的优秀之处改遍成新的代码；被淘汰者或者单独发表主题列出，或者列出可引用的链接。

　更新记录
＝＝＝＝＝＝
2004.06.20: 发出＂[讨论]批处理编程的异类＂主题，并与＂[分享]批处理编程的异类＂互相链接
2005.07.16: 更新7楼的 prompt 变量获取程序
2005.08.18: 修改3楼为数学（Math）主题，并增加随机数和随机阵列生成程序
2005.08.19: 修改4楼为时钟（Clock）主题，增加“暂停”程序5个
2005.09.11: 3楼数学（Math）主题增加“2K/XP表达式计算批处理”
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:49:42 | 显示全部楼层

批处理编程异类——游戏（Ｇａｍｅ）

程序：TicTacToe（三子棋、井字棋、打井、提担挑）
作者：M0eRtH
原文：TicTacToe (a.k.a. Noughts''''''''n''''''''Crosses) BATch version 1.1
　　　http://users.volja.net/sarcasmus/M0/tictactoe/tttbat.html
下载：http://users.volja.net/sarcasmus/M0/tictactoe/tictactoebat.zip
环境：１，程序应该在英文的命令行环境下运行；
　　　２，程序使用了大量的环境变量，应该修改程序运行时环境空间的大小；
　　　３，程序在ＷＩＮ２Ｋ／ＸＰ运行需要ＣＨＯＩＣＥ的支持；
备注：
　　这是我见到第一个用批处理编写的真正具有游戏性的程序，虽然程序并不提供ＡＩ对手，但是其优美的结构仍然值得称道。正文中出现的乱码字是因为作者使用了ＡＮＳＩ的表格字符。
同类：
　　福尔摩斯问答：http://dos.e-stone.cn/dosbbs/dispbbs.asp?boardID=6&ID=8272
　　ＺＤ庄园的迷魂阵：http://zdland.xiloo.com/planets/psa.html

正文：
  1. @echo off
  2. mode con cols=40 lines=25
  3. cls
  4. echo.
  5. echo   TicTacToe (a.k.a. Noughts''''''''n''''''''Crosses)
  6. echo            BATch Version 1.1
  7. echo             (c)2002 M0eRtH
  8. echo.
  9. echo      Updates and more free stuff at
  10. echo          http://m0erth.cjb.net
  11. echo.
  12. echo The keys:
  13. echo.
  14. echo          - X -            - O -
  15. echo.
  16. echo        7 ?8 ?9        Q ?W ?E
  17. echo       哪呐哪呐哪?     哪呐哪呐哪?
  18. echo        4 ?5 ?6        A ?S ?D
  19. echo       哪呐哪呐哪?     哪呐哪呐哪?
  20. echo        1 ?2 ?3       Z/Y?X ?C
  21. echo.
  22. echo   Ctrl+R = Reset game   Ctrl+Q = Quit
  23. echo.
  24. echo Note:
  25. echo   X, make sure the NumLock is ON. ;-)
  26. echo.
  27. pause

  29. set a1=-
  30. set a2=-
  31. set a3=-
  32. set b1=-
  33. set b2=-
  34. set b3=-
  35. set c1=-
  36. set c2=-
  37. set c3=-
  38. set turn=X
  39. set win=-
  40. set result=-
  41. set scoreX=-
  42. set scoreO=-
  43. set games=-
  44. set maxgames=-++++++++++++++++++++

  46. :draw
  47. cls
  48. echo.
  49. echo   TicTacToe (a.k.a. Noughts''''''''n''''''''Crosses)
  50. echo            BATch Version 1.1
  51. echo             (c)2002 M0eRtH
  52. echo.
  53. echo Score
  54. echo  X:%scoreX%
  55. echo  O:%scoreO%
  56. echo.
  57. echo                %a1% ?%a2% ?%a3%
  58. echo               哪呐哪呐哪?
  59. echo                %b1% ?%b2% ?%b3%
  60. echo               哪呐哪呐哪?
  61. echo                %c1% ?%c2% ?%c3%
  62. echo.

  64. :chkWin
  65. set result=%a1%%a2%%a3%
  66. if %result%==XXX goto XWon
  67. if %result%==OOO goto OWon
  68. set result=%b1%%b2%%b3%
  69. if %result%==XXX goto XWon
  70. if %result%==OOO goto OWon
  71. set result=%c1%%c2%%c3%
  72. if %result%==XXX goto XWon
  73. if %result%==OOO goto OWon
  74. set result=%a1%%b1%%c1%
  75. if %result%==XXX goto XWon
  76. if %result%==OOO goto OWon
  77. set result=%a2%%b2%%c2%
  78. if %result%==XXX goto XWon
  79. if %result%==OOO goto OWon
  80. set result=%a3%%b3%%c3%
  81. if %result%==XXX goto XWon
  82. if %result%==OOO goto OWon
  83. set result=%a1%%b2%%c3%
  84. if %result%==XXX goto XWon
  85. if %result%==OOO goto OWon
  86. set result=%c1%%b2%%a3%
  87. if %result%==XXX goto XWon
  88. if %result%==OOO goto OWon

  90. :getKeys
  91. echo                %turn%''''''''s turn
  92. choice /c:789456123qweasdzyxc /n :
  93. if errorlevel 21 goto reset
  94. if errorlevel 20 goto quit
  95. if errorlevel 19 goto setOC3
  96. if errorlevel 18 goto setOC2
  97. if errorlevel 17 goto setOC1
  98. if errorlevel 16 goto setOC1
  99. if errorlevel 15 goto setOB3
  100. if errorlevel 14 goto setOB2
  101. if errorlevel 13 goto setOB1
  102. if errorlevel 12 goto setOA3
  103. if errorlevel 11 goto setOA2
  104. if errorlevel 10 goto setOA1
  105. if errorlevel 9 goto setXC3
  106. if errorlevel 8 goto setXC2
  107. if errorlevel 7 goto setXC1
  108. if errorlevel 6 goto setXB3
  109. if errorlevel 5 goto setXB2
  110. if errorlevel 4 goto setXB1
  111. if errorlevel 3 goto setXA3
  112. if errorlevel 2 goto setXA2
  113. if errorlevel 1 goto setXA1
  114. goto draw

  116. :reset
  117. set a1=-
  118. set a2=-
  119. set a3=-
  120. set b1=-
  121. set b2=-
  122. set b3=-
  123. set c1=-
  124. set c2=-
  125. set c3=-
  126. goto draw

  128. :setXA1
  129. if not %a1%==- goto draw
  130. if %turn%==O goto draw
  131. set a1=X
  132. goto changeTurn
  133. :setXA2
  134. if not %a2%==- goto draw
  135. if %turn%==O goto draw
  136. set a2=X
  137. goto changeTurn
  138. :setXA3
  139. if not %a3%==- goto draw
  140. if %turn%==O goto draw
  141. set a3=X
  142. goto changeTurn

  144. :setXB1
  145. if not %b1%==- goto draw
  146. if %turn%==O goto draw
  147. set b1=X
  148. goto changeTurn
  149. :setXB2
  150. if not %b2%==- goto draw
  151. if %turn%==O goto draw
  152. set b2=X
  153. goto changeTurn
  154. :setXB3
  155. if not %b3%==- goto draw
  156. if %turn%==O goto draw
  157. set b3=X
  158. goto changeTurn

  160. :setXC1
  161. if not %c1%==- goto draw
  162. if %turn%==O goto draw
  163. set c1=X
  164. goto changeTurn
  165. :setXC2
  166. if not %c2%==- goto draw
  167. if %turn%==O goto draw
  168. set c2=X
  169. goto changeTurn
  170. :setXC3
  171. if not %c3%==- goto draw
  172. if %turn%==O goto draw
  173. set c3=X
  174. goto changeTurn


  177. :setOA1
  178. if not %a1%==- goto draw
  179. if %turn%==X goto draw
  180. set a1=O
  181. goto changeTurn
  182. :setOA2
  183. if not %a2%==- goto draw
  184. if %turn%==X goto draw
  185. set a2=O
  186. goto changeTurn
  187. :setOA3
  188. if not %a3%==- goto draw
  189. if %turn%==X goto draw
  190. set a3=O
  191. goto changeTurn

  193. :setOB1
  194. if not %b1%==- goto draw
  195. if %turn%==X goto draw
  196. set b1=O
  197. goto changeTurn
  198. :setOB2
  199. if not %b2%==- goto draw
  200. if %turn%==X goto draw
  201. set b2=O
  202. goto changeTurn
  203. :setOB3
  204. if not %b3%==- goto draw
  205. if %turn%==X goto draw
  206. set b3=O
  207. goto changeTurn

  209. :setOC1
  210. if not %c1%==- goto draw
  211. if %turn%==X goto draw
  212. set c1=O
  213. goto changeTurn
  214. :setOC2
  215. if not %c2%==- goto draw
  216. if %turn%==X goto draw
  217. set c2=O
  218. goto changeTurn
  219. :setOC3
  220. if not %c3%==- goto draw
  221. if %turn%==X goto draw
  222. set c3=O
  223. goto changeTurn


  226. :changeTurn
  227. if %turn%==X goto setTurnO
  228. set turn=X
  229. goto draw
  230. :setTurnO
  231. set turn=O
  232. goto draw


  235. :XWon
  236. echo.
  237. echo - X won! -
  238. pause
  239. set scoreX=%scoreX%+
  240. set games=%games%+
  241. if %games%==%maxgames% goto quit
  242. goto reset

  244. :OWon
  245. echo.
  246. echo - O won! -
  247. pause
  248. set scoreO=%scoreO%+
  249. set games=%games%+
  250. if %games%==%maxgames% goto quit
  251. goto reset

  253. :quit
  254. mode con cols=80 lines=25
  255. echo.
  256. echo   TicTacToe (a.k.a. Noughts''''''''n''''''''Crosses)
  257. echo            BATch Version 1.1
  258. echo             (c)2002 M0eRtH
  259. echo.
  260. echo      Updates and more free stuff at
  261. echo          http://m0erth.cjb.net
  262. echo.
  263. echo.
  264. echo  X scored: %scoreX%
  265. echo  O scored: %scoreO%
  266. echo.
  267. set a1=
  268. set a2=
  269. set a3=
  270. set b1=
  271. set b2=
  272. set b3=
  273. set c1=
  274. set c2=
  275. set c3=
  276. set turn=
  277. set win=
  278. set result=
  279. set scoreX=
  280. set scoreO=
  281. set games=
  282. set maxgames=
  283. pause
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:51:07 | 显示全部楼层

批处理编程的异类——数学（Math）

1、数学——随机

    1)随机数发生器：运行后可产生一个00~99的随机整数，并保存于环境变量 %_random% 中。

      如果要产生更复杂的随机数，也可以利用这个程序进行修改来得到，比如两次产生的随机数组合，即可得到0000~9999的随机数；在随机数前加上小数点，即可得到0.00-0.99的随机小数；将 prompt _$T$_:: 中的第一个下划线去除，可以得到0~9的随机数；用debug可以去除某些随机数的前缀0。根据以上方法，即可组合得到任意形式的随机数了。
  1. :: GenARnd.Bat - Generate a random integer (00~99)
  2. :: Will Sort - 12:06 2005-8-18 - V2 - MSDOS7.10/CMD@WinXP/MSDOS6.22
  3. @echo off
  4. echo exit|%comspec% /k prompt _$T$_::> _GenARnd.bat
  5. echo e 100 "set _random=">_GenARnd.asd
  6. for %%s in (w q) do echo %%s>>_GenARnd.asd
  7. debug _GenARnd.bat < _GenARnd.asd > nul
  8. call _GenARnd.bat
  9. for %%f in (_GenARnd*.*) do del %%f
  10. if not "%_random%"=="" if not [%1]==[@] echo Random number : %_random%
  11. :End
复制代码
2)随机阵列发生器：运行后将生成一张随机概率分布矩阵图。

      此图24行63列，由字符“-”（假）和“o”（真）组成，从上到下每三行为一组，呈现出o的分布概率依次降低。其中矩阵中的左图为真假序列分布，右图为真假数目对比。
  1. :: RndArray.bat - Generate a serial of random numbers(- or o)
  2. :: Will Sort - 2004/11/24
  3. @echo off
  4. if "%1"==":" goto %2

  6. set no=
  7. set num=0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9

  9. :loop
  10. set no=I%no%
  11. set line=
  12. set -=
  13. set o=
  14. for %%c in (%num%) do call %0 : random %no%
  15. echo %line% : %-%%o%
  16. set line=
  17. set -=
  18. set o=
  19. for %%c in (%num%) do call %0 : random %no%
  20. echo %line% : %-%%o%
  21. set line=
  22. set -=
  23. set o=
  24. for %%c in (%num%) do call %0 : random %no%
  25. echo %line% : %-%%o%
  26. if not [%no%]==[IIIIIIII] goto loop

  28. :quit
  29. del _Random.tmp
  30. for %%e in (- o no num line) do set %%e=
  31. goto end

  33. :random
  34. echo. | time > _Random.tmp
  35. ::echo exit | %comspec% /k prompt $T>_Random.tmp
  36. goto %3

  38. find ".0"<_Random.tmp>nul
  39. if not errorlevel 1 goto true
  40. :I
  41. find ".3"<_Random.tmp>nul
  42. if not errorlevel 1 goto true
  43. :II
  44. find ".6"<_Random.tmp>nul
  45. if not errorlevel 1 goto true
  46. :III
  47. find ".9"<_Random.tmp>nul
  48. if not errorlevel 1 goto true
  49. :IIII
  50. find ".2"<_Random.tmp>nul
  51. if not errorlevel 1 goto true
  52. :IIIII
  53. find ".5"<_Random.tmp>nul
  54. if not errorlevel 1 goto true
  55. :IIIIII
  56. find ".8"<_Random.tmp>nul
  57. if not errorlevel 1 goto true
  58. :IIIIIII
  59. find ".1"<_Random.tmp>nul
  60. if not errorlevel 1 goto true
  61. :IIIIIIII
  62. find ".4"<_Random.tmp>nul
  63. if not errorlevel 1 goto true
  64. find ".7"<_Random.tmp>nul
  65. if not errorlevel 1 goto true
  66. ::del _Random.tmp

  68. :false
  69. set line=%line%-
  70. set -=-%-%
  71. goto end

  73. :true
  74. set line=%line%o
  75. set o=o%o%
  76. goto end

  78. :end
复制代码
2、数学——表达式

    1)2K/XP表达式计算批处理，由 Brglng 原创并维护。转帖时精简了程序中的文档部分，可以通过以下链接查阅完整的代码和文档。

{16534}2K/XP表达式计算批处理
http://www.cn-dos.net/forum/viewthread.php?tid=16534
  1. :: Eval.cmd - 2K/XP表达式计算批处理
  2. :: Brglng - 2005.8.31
  3. @echo off
  4. setlocal
  5. if /i "%1"=="/A" if "%2"=="" echo 必须指定文件路径！& goto end
  6. if /i not "%1"=="/A" if /i not "%1"=="/N" if not "%1"=="" goto EvalArgument

  8. echo 请输入表达式(输入"Q"退出) & goto inputExpr

  10. :EvalArgument
  11. set /a EvalExpr="%1"
  12. if "%EvalExpr%"=="" echo 表达式输入错误！ & goto end
  13. echo %1=%EvalExpr%
  14. if "%2"=="" goto end
  15. echo %1=%EvalExpr% >>"%2"
  16. echo 算式和计算结果已存入"%2"！
  17. goto end

  19. :inputExpr
  20. set Expr=
  21. set EvalExpr=
  22. set /p Expr=^>
  23. if "%Expr%"=="" goto inputExpr
  24. if /i "%Expr%"=="Q" goto end
  25. set /a EvalExpr="%Expr%"
  26. if "%EvalExpr%"=="" echo 输入错误！ & goto inputExpr
  27. echo 计算结果为：%EvalExpr%
  28. if /i "%1"=="/A" goto autosave
  29. if /i "%1"=="/N" goto inputExpr

  31. :if_save
  32. set SaveEval=
  33. set /p SaveEval=是否将表达式和计算结果存入文件[Y/N]?
  34. if /i "%SaveEval%"=="Y" goto save
  35. if /i "%SaveEval%"=="N" goto inputExpr
  36. goto if_save

  38. :save
  39. set /p SaveEvalPath=请输入文件路径及文件名(如C:\Windows\file.txt。若只输入文件名则自动存入当前文件夹，留空则为上一次输入的路径)：
  40. echo "%Expr%"=%EvalExpr% >>"%SaveEvalPath%"
  41. echo 表达式以及计算结果已存入"%SaveEvalPath%"！
  42. goto inputExpr

  44. :autosave
  45. echo "%Expr%"=%EvalExpr% >>"%2"
  46. goto inputExpr

  48. :end
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:53:35 | 显示全部楼层

批处理编程的异类——时钟（Clock）

1、暂停（Pause）、延迟（Delay）、等待（Wait）、睡眠（Sleep）

0) Win7 / Win10 等系统自带的 timeout 命令
  1. @echo off
  2. echo %date% %time%
  3. timeout /nobreak /t 3 >nul
  4. echo %date% %time%
  5. pause
复制代码
1)for+set+if，时间精度为0.01秒，适用平台为WinNT/2K/XP/2003。

  利用for解析变量%time%并存为两个时间点%start%和%now%，再利用set /a计算两个时间点的时间差，最后用if判断时间差是否达到设定的暂停时间。
  1. @echo off
  2. setlocal enableextensions
  3. echo %time%
  4. call :ProcDelay 200
  5. echo %time%
  6. goto :EOF

  8. :ProcDelay delayMSec_
  9. setlocal enableextensions
  10. for /f "tokens=1-4 delims=:. " %%h in ("%time%") do set start_=%%h%%i%%j%%k
  11.   :_procwaitloop
  12.   for /f "tokens=1-4 delims=:. " %%h in ("%time%") do set now_=%%h%%i%%j%%k
  13.   set /a diff_=%now_%-%start_%
  14. if %diff_% LSS %1 goto _procwaitloop
  15. endlocal & goto :EOF
复制代码
2)VBS脚本中的sleep函数，时间精度为0.001秒，使用平台为Win9x/WinNT系列。

   动态创建一个调用sleep()函数的VBS脚本，然后用Windows脚本宿主的命令行版本cscript调用它。
  1. @echo off & setlocal enableextensions enabledelayedexpansion
  2. echo WScript.Sleep 2000 > %temp%\tmp$$$.vbs
  3. echo %time%
  4. cscript //nologo %temp%\tmp$$$.vbs
  5. echo %time%
  6. for %%f in (%temp%\tmp$$$.vbs) do if exist %%f del %%f
  7. endlocal & goto :EOF
复制代码
3)ping的消息发送间隔，时间精度为1秒，使用平台为Win9x/WinNT系列。

   需要你的Windows系统中正常安装了网卡的TCP/IP协议，有两种方案，方案二不建议采用，见主题 [讨论]批处理编程的异类 12、13楼：

(1) 利用ping两次发送消息之间的间隔时间。ping在发送多个消息时，在得到上一次消息的回应后，它会再等待1秒的时间才发送下一次消息，而这个回应时间因机型、系统和网络配置而不同，其中IP地址尤其关键，只有本地的回送地址 127.0.0.1 因为是立即回应所以才是相对恒定的，其他地址大多会产生显著的差异。此种方法要等待更大的时间，是指定发送的消息数为等待的时间加一，因为第一个消息是不等待的，IP 地址必须是 127.0.0.1 。其等待2秒的程序如下：

::根据植树原则，n后的数字为暂停秒数加一
ping -n 3 127.0.0.1>nul
(2) 利用ping的最大等待时间。ping向0.0.0.1发送一次“网际消息控制协议 (ICMP)”回响请求消息，因为 0.0.0.1 是个无法响应 ping 请求的IP地址，所以默认情况下，ping会等待一定的最大响应时间——4秒后便停止等待，而-w可以改变这个每发送一次消息所等待的最大响应时间。而如果将 IP 地址改为立即响应的127.0.0.1或其他响应时间很短的IP ，那 -w 便失去了作用，因为每次发送等待时间都不会达到最大的响应时间，此时延时会缩短。此种方法要等待更大的时间，可以直接使用 -w 指定，但是需要减去一定的发送延时，这个延时需要自己事先测定一下，否则会有不到1秒的误差；而且 IP 地址必须是不响应请求的地址。其等待2秒的程序如下：
  1. ping -n 2 -w 500 0.0.0.1>nul
复制代码
4)choice的缺省选择等待功能，时间精度为1秒，适用平台为MS-DOS/Win9x/WinNT系列。

  /t:y,2 将缺省选择字符设置为y，等待时间是2秒，/n禁止[y,n]提示出现在命令行上，“rem|”的作用是禁止choice从键盘接受按键，从而暂停不会因为按下y或者其它键而被意外终止。
  1. rem|choice /t:y,2 /n >nul
复制代码
5)ASCII汇编代码，延迟精度为0.001秒，适用平台为MS-DOS/Win9x/WinNT。

  德国人Herbert Kleebauer给出了一个通用方案，通过ASCII汇编器间接产生一个sleep.exe程序来实现延迟，这个程序分为DOS和Win两个模块，分别调用DOS系统中断服务和WindowsAPI。
  1. :: Sleep.bat - Sleep/Delay/Wait n seconds
  2. :: Herbert Kleebauer(Germany) - 2005/05/29
  3. :: Modified by Will Sort - 2005/06/02, 07-25
  4. @echo off
  5. echo q | debug>nul
  6. echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=>sleep.com
  7. echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6>>sleep.com
  8. echo T}{z~~@GwkBG@OEKcUt`~}@MqqBsy?seHB~_Phxr?@zAB`LrPEyoDt@Cj?>>sleep.com
  9. echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz>>sleep.com
  10. echo LFvAURQ?OYLTQ@@?~QCoOL~RDU@?aU?@{QOq?@}IKuNWpe~FpeQFwH?Vkk>>sleep.com
  11. echo _GSqoCvH{OjeOSeIQRmA@KnEFB?p??mcjNne~B?M??QhetLBgBPHexh@e=>>sleep.com
  12. echo EsOgwTLbLK?sFU`?LDOD@@K@xO?SUudA?_FKJ@N?KD@?UA??O}HCQOQ??R>>sleep.com
  13. echo _OQOL?CLA?CEU?_FU?UAQ?UBD?LOC?ORO?UOL?UOD?OOI?UgL?LOR@YUO?>>sleep.com
  14. echo dsmSQswDOR[BQAQ?LUA?_L_oUNUScLOOuLOODUO?UOE@OwH?UOQ?DJTSDM>>sleep.com
  15. echo QTqrK@kcmSULkPcLOOuLOOFUO?hwDTqOsTdbnTQrrDsdFTlnBTm`lThKcT>>sleep.com
  16. echo @dmTkRQSoddTT~?K?OCOQp?o??Gds?wOw?PGAtaCHQvNntQv_w?A?it\EH>>sleep.com
  17. echo {zpQpKGk?Jbs?FqokOH{T?jPvP@IQBDFAN?OHROL?Kj??pd~aN?OHROd?G>>sleep.com
  18. echo Q??PGT~B??OC~?ipO?T?~U?p~cUo0x>>sleep.com
  19. sleep.com>sleep.exe
  20. echo wait %1 seconds:
  21. sleep.exe %1000
  22. del sleep.com
  23. del sleep.exe
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:54:34 | 显示全部楼层
    以下是一个用字符方式画图的程序，原文来自网易广州站DOS版。
    http://fe2.gz.163.com/cgi/readsr ... amp;st=0&kw=MAP

    这个程序的工作方式很简陋，不过已经具备了一些基本的功能，比如画，擦，更换画笔字符，保存和提取字符画，备份和恢复字符画，使字符画可执行化等。程序用到了ANSI.SYS 的支持功能，所以 ECHO 后的方框字符实际上是 ASCII 码为27的符号，可在DOS下的 EDIT 中按 CTRL+P 然后按 ESC 输入此字符。
@ECHO OFF
:START
IF NOT [%3]==[] GOTO MAP%1
IF [%1]==[/?] GOTO MAPHELP
CHOICE Initizing, Please waiting../C:. /T:.,1 /N
IF [%1]==[R:] GOTO MAPRESTORE
IF [%1]==[E:] GOTO MAPEXTRACT
IF [%1]==[T:] GOTO MAPTRYSAVE

MEM /C|FIND "ANSI">NUL
IF ERRORLEVEL 1 GOTO MAPERR1

IF [%1]==[] GOTO MAPINIT
IF [%2]==[] GOTO MAPERR2
IF [%1]==[C:] IF NOT [%2]==[/LINE] IF NOT [%2]==[/PIPE] SET $F=%2
IF [%1]==[C:] GOTO MAPSTART

IF NOT EXIST %2.MAP GOTO MAPERR5
FIND "" %2.MAP>NUL
IF ERRORLEVEL 1 GOTO MAPERR3
REM FIND "" %2.MAP>NUL
REM IF ERRORLEVEL 1 GOTO MAPERR4

IF [%1]==[V:] GOTO MAPVIEW
IF [%1]==[L:] GOTO MAPLOAD
IF [%1]==[M:] GOTO MAPMAKE
:MAPINIT
CLS
SET $F=?
SET PRE=C
GOTO MAPSTART

:MAPHELP
ECHO.
ECHO Use: Draw a map with painter of characterS, and save to map file.
ECHO Usage: %0 option: parameter
ECHO Option:
ECHO            L       Load map file from the specified location.
ECHO            M       Make map file to selfexec map program.
ECHO            E       Extract selfexec map to map file.
ECHO            T       Try save map file from temporary location.
ECHO            R       Restore the map backuped map file.
ECHO            V       View the map file parameter specifle.
ECHO            C       define painter with Character parameter specifle.
ECHO.
CHOICE View guide of draw:
IF ERRORLEVEL 2 GOTO MAPEND
ECHO.
ECHO All operation control by keyboard keys.
ECHO.
ECHO Key:       Use:
ECHO 1          Left and down ----)
ECHO 2          Down              )
ECHO 3          Right and down    )
ECHO 4          Left              )---Painter Move keys
ECHO 6          Right             )
ECHO 7          Left and up       )
ECHO 8          Up                )
ECHO 9          Right and up------)
ECHO 5          painter
ECHO 0(Ins)     change to draw state
ECHO .(Del)     change to delete state
ECHO.
GOTO MAPEND

:MAPERR1
ECHO.
ECHO Error 1 in %0: Not continue for not load ANSI.
ECHO.
GOTO MAPEND
:MAPERR2
ECHO.
ECHO Error 2 in %0: Not specified second parameter.
ECHO.
GOTO MAPEND
:MAPERR3
ECHO.
ECHO Error 3 in %0: False map file.
ECHO.
GOTO MAPEND
:MAPERR4
ECHO.
ECHO Error 4 in %0: Not accomplish map file.
ECHO.
GOTO MAPEND
:MAPERR5
ECHO.
ECHO Error 5 in %0: Not exist map file.
ECHO.
GOTO MAPEND
:MAPERR6
ECHO.
ECHO Error 6 in %0: Not backup map file.
ECHO.
GOTO MAPEND
:MAPERR7
ECHO.
ECHO Error 7 in %0: Not make selfexec map program.
ECHO.
GOTO MAPEND
:MAPERR8
ECHO.
ECHO Error 8 in %0: Not correctly pattern selfexec map program.
ECHO.
GOTO MAPEND
:MAPERR9
ECHO.
ECHO Error 9 in %0: Can''''t view map file.
ECHO.
GOTO MAPEND
:MAPERR10
ECHO.
ECHO Error 10 in %0: enviroment parameter PRE is null.

::MAPPICK
IF EXIST %2.MAP CHOICE Modify this map file
IF ERRORLEVEL 2 GOTO MAPEND
ECHO @CLS>PAINTER.BAT
ECHO @SET $F=%%1>>PAINTER.BAT
ECHO @%0 START %2 /S>>PAINTER.BAT
ECHO Please choose painter of character with style (PAINTER=char).
PROMPT

[ 本帖最后由 Batcher 于 2009-3-12 19:55 编辑 ]
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:56:29 | 显示全部楼层
    以下是个在命名行提示上画一只字符小狗的程序，原文来自网易北京站的DOS版。
    http://fe4.bj.163.com/cgi/readsr ... S%B5%C4%CD%BC%D0%CE

    程序需ANSI支持。其中存在缺陷，解决的方法请查询原网址。
@PROMPT   {             (\__           }
ECHO 
@PROMPT   {            (\   `\__       }
ECHO 
@PROMPT   {(`, .------.,-'   b  $B    }
ECHO 
@PROMPT   {`-/            ',__,-"`     }
ECHO 
@PROMPT   {  $B   `;      ,  $B          }
ECHO 
@PROMPT   {   \   ;.----/ ,/           }
ECHO 
@PROMPT   {    ) // /  ( ( \           }
ECHO 
@PROMPT   {    \ \`.`\  \ \ \          }
ECHO 
@PROMPT   {     `-` `"   `-`"          }
ECHO 
@PORMPT $P$G
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:57:04 | 显示全部楼层
以下是一个获取PROMPT系统状态数据的程序，原文来自网易广州站的DOS版。
    http://fe2.gz.163.com/cgi/readsr ... t=1&kw=willsort
   
    运行时，加上存放数据的变量名和prompt对应变量名即可，如：
       getvar curver $v   
    可以提取的系统状态数据有：

      $T   Current time
      $D   Current date
      $P   Current drive and path
      $V   System version number
      $N   Current drive
  1. :: GetVar.bat - Get from 'PROMPT' text to environment variable
  2. :: Will Sort - 10:29 2005-7-16 - CMD@XP/COMMAND@Win98/MSDOS6.22
  3. @echo off
  4. echo exit | %comspec% /k prompt set %1=%2$_:: > _GetVar.bat
  5. call _GetVar.bat
  6. for %%f in (_GetVar*.*) do del %%f
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:57:43 | 显示全部楼层
    以下是一个定时器程序，原文来自网易广州站的DOS版。
    http://fe2.gz.163.com/cgi/readsr ... t=1&kw=willsort

    程序中的 CURRENT.BAT 可以更换为自己需要执行的内容。FIND 一句的时间可以根据自己的需要设定，也可用参数%1代替。还可以改为 TIME 改为 DATE 以完成的定期执行的功能。
  1. ::CURRENT.BAT
  2. @echo off
  3. echo Haha, it's the time to go!!

  5. ::TIMER.BAT
  6. @echo off
  7. :start
  8. echo.|time|find "10:30:00">run.bat
  9. choice /c:y /t:y,59 /n>nul
  10. call run.bat
  11. goto start
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:58:36 | 显示全部楼层

批处理编程的异类——网络（Network）

1、共享
    1)删除win2k/xp系统默认共享

      原文来自《批处理简明教程》
      http://www.realhack.org/article/articleshow.asp?ArticleID=954
  1. @echo preparing to delete all the default shares. when ready press any key.
  2. @pause
  3. @echo off
  4. :Rem check parameters if null show usage.
  5. if {%1}=={} goto :Usage
  6. :Rem code start.
  7. echo.
  8. echo ------------------------------------------------------
  9. echo.
  10. echo Now deleting all the default shares.
  11. echo.
  12. net share %1$ /delete
  13. net share %2$ /delete
  14. net share %3$ /delete
  15. net share %4$ /delete
  16. net share %5$ /delete
  17. net share %6$ /delete
  18. net share %7$ /delete
  19. net share %8$ /delete
  20. net share %9$ /delete
  21. net stop Server
  22. net start Server
  23. echo.
  24. echo All the shares have been deleteed
  25. echo.
  26. echo ------------------------------------------------------
  27. echo.
  28. echo Now modify the registry to change the system default properties.
  29. echo.
  30. echo Now creating the registry file
  31. echo Windows Registry Editor Version 5.00> c:\delshare.reg
  32. echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]>> c:\delshare.reg
  33. echo "AutoShareWks"=dword:00000000>> c:\delshare.reg
  34. echo "AutoShareServer"=dword:00000000>> c:\delshare.reg
  35. echo Nowing using the registry file to chang the system default properties.
  36. regedit /s c:\delshare.reg
  37. echo Deleting the temprotarily files.
  38. del c:\delshare.reg
  39. goto :END

  41. :Usage
  42. echo.
  43. echo ------------------------------------------------------
  44. echo.
  45. echo ☆ A example for batch file ☆
  46. echo ☆ [Use batch file to change the sysytem share properties.] ☆
  47. echo.
  48. echo Author：Ex4rch
  49. echo Mail:Ex4rch@hotmail.com QQ:1672602
  50. echo.
  51. echo Error：Not enough parameters
  52. echo.
  53. echo ☆ Please enter the share disk you wanna delete ☆
  54. echo.
  55. echo For instance，to delete the default shares:
  56. echo delshare c d e ipc admin print
  57. echo.
  58. echo If the disklable is not as C: D: E: ，Please chang it youself.
  59. echo.
  60. echo example：
  61. echo If locak disklable are C: D: E: X: Y: Z: ，you should chang the command into ：
  62. echo delshare c d e x y z ipc admin print
  63. echo.
  64. echo *** you can delete nine shares once in a useing ***
  65. echo.
  66. echo ------------------------------------------------------
  67. goto :EOF
  68. :END
  69. echo.
  70. echo ------------------------------------------------------
  71. echo.
  72. echo OK,delshare.bat has deleted all the share you assigned.
  73. echo.Any questions ,feel free to mail to Ex4rch@hotmail.com.
  74. echo
  75. echo.
  76. echo ------------------------------------------------------
  77. echo.
  78. :EOF
  79. echo end of the batch file
复制代码
2)PING某个区段内的所有IP的程序

      原文来自网易北京站的DOS版。
      http://fe4.bj.163.com/cgi/readsr ... t=1&kw=willsort

      在命令行输入 a.bat 0 1 2 3 4 5 6 7 8 9 ，就能显示某区段的所有 IP 地址 192.168.1.0 - 192.168.1.99 ，将其中的 echo 改成 ping 就行，其中的 choice 和 if 语句是等待用户判断是否继续，可以删除，但这样中断程序比较麻烦。
  1. @echo off
  2. :redo
  3. if "%1" == "" goto end
  4. for %%a in (0,1,2,3,4,5,6,7,8,9) do echo 192.168.1.%1%%a
  5. choice continue
  6. if errorlevel 2 goto end
  7. shift
  8. goto redo
  9. :end
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:59:14 | 显示全部楼层
    以下是一个修改文件的更新日期的程序，原文来自网易北京站的DOS版。   
    http://fe4.bj.163.com/cgi/readsr ... t=1&kw=willsort

    原文代码中有若干错误，下为修正版。
  1. @echo off
  2. rem 保存系统时间
  3. echo.|date>sysdate.bat
  4. echo.|time>systime.bat
  5. rem 修改系统时间为指定时间，日期为参数一，时间为参数二，文件名为参数三
  6. date %1
  7. time %2
  8. rem 修改文件的时间
  9. copy %3+,,>nul
  10. rem 恢复系统时间
  11. echo date %%4>current.bat
  12. call sysdate
  13. echo time %%3>current.bat
  14. call systime
  15. rem 程序执行完毕
  16. echo Success.
  17. del systime.bat
  18. del sysdate.bat
  19. del current.bat
  20. echo on
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 19:59:53 | 显示全部楼层
    以下是一个文件遍历程序，原文来自网易广州站的DOS版。
    http://fe2.gz.163.com/cgi/readsr ... t=1&kw=willsort

    原文中用到了两个外部程序，VARSET 和 LMOD，可能在本站或者新DOS时代就有下载。
  1. @echo off
  2. rem ///////////////////搜索所有目录下的所有txt文件///////////////////

  4. rem 找当前目录（根目录）的*.txt
  5. for %%a in (*.txt) do type %%a

  7. rem 以下为找当前目录（根目录）的所有子目录下的所有*.txt

  9. set i=1
  10. set j=1
  11. set filenum=0
  12. set dirnum=0

  14. varset root=FULL of . >temp.bat
  15. call temp.bat

  17. varset rootdir=string(3) %root% >temp.bat
  18. call temp.bat

  20. dir /ad /b /s >temp.txt

  22. varset dirnum=lines temp.txt >temp.bat
  23. call temp.bat

  25. :loop1

  27. type %root%\temp.txt | %root%\LMOD /L%i% set curdir=[] >%root%\temp.bat
  28. call %root%\temp.bat

  30. varset curdir=string(3) %curdir% >%root%\temp.bat
  31. call %root%\temp.bat

  33. cd %curdir%
  34. echo %curdir%
  35. set j=1
  36. :loop2
  37.      %root%\varset filenum=files *.txt >%root%\temp.bat
  38.      call %root%\temp.bat
  39.      if %filenum%==0 goto end2

  41.      dir *.txt /b | %root%\LMOD /L%j% set curfile=[] >%root%\temp.bat
  42.      call %root%\temp.bat

  44.      type %curfile%

  46.      if %j%==%filenum% goto end2

  48.      %root%\varset j=%j%+1 >%root%\temp.bat
  49.      call %root%\temp.bat
  50.      goto loop2
  51. :end2

  53. cd %rootdir%

  55. if %i%==%dirnum% goto end1

  57. %root%\varset i=%i%+1 >%root%\temp.bat
  58. call %root%\temp.bat

  60. goto loop1

  62. :end1
  63. del %root%\temp.bat
  64. del %root%\temp.txt
  65. set i=
  66. set j=
  67. set filenum=
  68. set dirnum=
  69. set root=
  70. set rootdir=
  71. set curdir=
  72. set curfile=
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 20:00:26 | 显示全部楼层
    以下是一个接收键盘输入字符串的程序，原文来自本站教学室。
    http://model.chinajewelry.net/do ... ;ID=5283&skin=1

    此文的关键技巧在于 FC 和 DEBUG 的巧妙结合使用。%TEMP%.\filename.ext 的用法也很有技巧性。%%?的用法也很新鲜。
  1. :: Get user input - includes error check
  2. @echo off
  3. echo e102'set %%1='> %temp%.\t1.dat
  4. for %%? in (w q) do echo %%?>> %temp%.\t1.dat
  5. :input
  6. echo.
  7. echo Type input:
  8. FC con nul /lb1 /n |FIND "1:" > %temp%.\t2.bat
  9. :: Error checking begins here
  10. FIND "|" %temp%.\t2.bat > nul
  11. if not errorlevel=1 goto error
  12. FIND "=" %temp%.\t2.bat > nul
  13. if not errorlevel=1 goto error
  14. FIND " nul
  15. if not errorlevel=1 goto error
  16. FIND ">" %temp%.\t2.bat > nul
  17. if not errorlevel=1 goto error
  18. :: Error checking end
  19. DEBUG %temp%.\t2.bat  nul
  20. call %temp%.\t2.bat 字符串
  21. for %%? in (t1.dat t2.bat) do del %temp%.\%%?
  22. echo 字符串=%字符串%
  23. goto eof
  24. :error
  25. echo.
  26. echo @PROMPT Invalid input. Invalid characters: $Q $L $G $B$_> %temp%.\t2.bat
  27. %comspec% /c %temp%.\t2.bat |FIND ":"
  28. goto input
  29. :eof
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 20:01:14 | 显示全部楼层
下面是一个按表顺序转换字符串的程序，原文来自本站开发室：
   http://model.chinajewelry.net/do ... ardID=6&ID=9250

    此程序为批处理中字符串值的顺序转换而编写，一般作为子程序被其他程序调用，也可以将此程序稍做修改，添加入特定批处理程序中作为子模块调用。
  1. @echo off
  2. if [%1]==[$] goto %2
  3. if [%1]==[] goto nullargu

  5. :main 主模块: count, match 句参数列表可以根据需要重新设定和增减
  6. set factor=%1
  7. call %0 $ count 1 2 3 4 5 7 8 9
  8. call %0 $ match c d e f g h i j
  9. goto display

  11. :count 计数模块: 根据指定参数 factor 设置变量值 #a1, #a2
  12. if [%3]==[] goto overflow
  13. set #a1=%#a1%-
  14. if not [%#a1%]==[----------] goto count_2
  15. set #a1=
  16. set #a2=%#a2%+
  17. if [%#a2%]==[++++++++++] goto overflow
  18. :count_2
  19. if [%3]==[%factor%] goto end
  20. shift
  21. goto count

  23. :match 匹配模块: 循环递增变量 #b1, #b2, 若分别与 #a1, #a2 相等, 则指定结果值为当前循环的参数 3.
  24. if [%3]==[] goto overflow
  25. set #b1=%#b1%-
  26. if not [%#b1%]==[----------] goto match_2
  27. set #b1=
  28. set #b2=%#b2%+
  29. if [%#b2%]==[++++++++++] goto overflow
  30. :match_2
  31. if [%#a1%]==[%#b1%] if [%#a2%]==[%#b2%] set result=%3
  32. if not [%result%]==[] goto end
  33. shift
  34. goto match

  36. :display 显示模块: 显示赋值结果
  37. if [%error%]==[] echo %factor% convert %result%
  38. set result=
  39. set factor=
  40. set error=
  41. set #a1=
  42. set #a2=
  43. set #b1=
  44. set #b2=
  45. goto end

  47. :nullargu
  48. echo.
  49. echo Error: argument 1 not specified.
  50. echo.
  51. goto end

  53. :overflow
  54. echo.
  55. echo Error: number is overflow.
  56. set error=overflow
  57. echo.
  58. goto end

  60. :end
复制代码
回复

举报

Batcher
 楼主| 发表于 2009-3-12 20:01:46 | 显示全部楼层
    下面是一个获取errorlevel值到环境变量的程序，原文来自本站开发室：
    http://model.chinajewelry.net/do ... ardID=6&ID=9358
  1. @echo off
  2. set el=0
  3. if errorlevel 1 set el=1
  4. if not errorlevel 2 goto end

  6. :partbydec
  7. for %%h in (1 2) do if errorlevel %%h00 set elh=%%h
  8. if [%elh%]==[1] for %%t in (0 1 2 3 4 5 6 7 8 9) do if errorlevel %elh%%%t0 set elt=%elh%%%t
  9. if [%elh%]==[2] for %%t in (0 1 2 3 4 5) do if errorlevel %elh%%%t0 set elt=%elh%%%t
  10. if not [%elt%]==[25] for %%o in (0 1 2 3 4 5 6 7 8 9) do if errorlevel %elt%%%o set el=%elt%%%o
  11. if [%elt%]==[25] for %%o in (0 1 2 3 4 5) do if errorlevel %elt%%%o set el=%elt%%%o
  12. set elh=
  13. set elt=

  15. :end
  16. if not [%1]==[@] echo current errolevel is %el%
复制代码
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-17 00:10 , Processed in 0.018426 second(s), 8 queries , File On.

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表