[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[原创] VBS 提取最近打开的文件、删除“最近访问的位置”中失效的快捷方式 by yu2n

本帖最后由 yu2n 于 2015-5-23 13:47 编辑

VBS 提取最近打开的文件、删除“最近访问的位置”中失效的快捷方式 by yu2n
  1. 'VBS 提取最近打开的文件、删除“最近访问的位置”中失效的快捷方式 by yu2n
  2. Const sAppTitle = "* VBS 复制最近打开的文件 by Yu2n *"
  3. Dim wso, fso, oShell, oFolder, sSrcFolder, sDesFolder, sFilterFile, oFile, oType, sSrcFile, sDesFile
  4. Set wso = CreateObject("Wscript.Shell")
  5. Set fso = CreateObject("Scripting.FileSystemObject")
  6. Set oShell = CreateObject("Shell.Application")
  7. '来源文件夹
  8. sSrcFolder = wso.SpecialFolders("Recent")  '最近打开的文件
  9. '过滤文件类型
  10. sFilterFile = InputBox("请输入要保存的文件类型:" & vbCrLf & vbCrLf & vbCrLf & vbCrLf & _
  11.   "多个文件类型,使用 “|” 符号分隔开", "Step 1/2 - " & sAppTitle, "txt|vbs|ppt")
  12. If sFilterFile = "" Then WScript.Quit
  13. '打开最近访问
  14. wso.Run "explorer /e," & sSrcFolder
  15. '目标文件夹
  16. Set oFolder = CreateObject("Shell.Application").BrowseForFolder(&H0, _
  17.   "Step 2/2 - 请选择保存的位置:", &H0010 + &H0001)
  18. If (Not oFolder Is Nothing) Then sDesFolder = oFolder.Self.Path
  19. If Not fso.FolderExists(sDesFolder) Then WScript.Quit
  20. '扫描来源文件夹
  21. Set oFolder = oShell.NameSpace(sSrcFolder)
  22. For Each oFile in fso.GetFolder(sSrcFolder).Files
  23.   '限定文件类型必须为快捷方式
  24.   If UCase(Right(oFile.Name, Len(".lnk"))) = UCase(".lnk") Then
  25.     '快捷方式指向的文件
  26.     sSrcFile = oFolder.ParseName(oFile.Name).GetLink.Path
  27.     If fso.FileExists(sSrcFile) Then
  28.       '过滤文件类型
  29.       For Each oType In Split(sFilterFile, "|")
  30.         oType = "." & Trim(oType) & ".lnk"
  31.         If UCase(Right(oFile.Name,Len(oType))) = UCase(oType) Then
  32.           '复制文件
  33.           sDesFile = sDesFolder & "\" & Left(oFile.Name, Len(oFile.Name)-Len(".lnk"))
  34.           If (Not fso.FileExists(sDesFile)) Then
  35.             fso.CopyFile sSrcFile, sDesFile, True
  36.           End If
  37.         End If
  38.       Next
  39.     Else
  40.       '删除失效的快捷方式(快捷方式指向的文件不存在)
  41.       fso.DeleteFile oFile, True
  42.     End If
  43.   End If
  44. Next
  45. Msgbox "完成!" & String(70,Chr(32)), vbSystemModal+vbInformation, sAppTitle
复制代码
『千江有水千江月』千江有水,月映千江;万里无云,万里青天。    http://yu2n.qiniudn.com/

返回列表