[已解决]提取原文件名中最后的数字字符串来重命名文件

228630386

如何批处理DOS命令自动改名？
文件名是比较长，每个文件中的名字都不统一，但尾数的-1，-2，-3，-4，-15，-16是肯定有的。
能否用DOS命令自动提取后面的数字自动改名？
原文件：

改名后效果：

范例内容：
http://pan.baidu.com/s/1bnGr3nL

DAIC

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in ('dir /b /s "C:\Test\目录1\*.jpg"') do (
   
4.     set "newname=%%~ni"
   
5.     set "newname=!newname:~-2!"
   
6.     set "newname=!newname:-=!"
   
7.     ren "%%i" "!newname!.jpg"
   
8. )

复制代码

228630386

回复 2# DAIC


    不知为什么，我改了路径也是不行的？ 能否不要路径也能运行呢？

bailong360

1. <!-- :
   
2. @echo off
   
3. setlocal enabledelayedexpansion
   
4. mshta "%~f0"
   
5. ren2 -f -r "(.*-){3}(.*)" "$2"
   
6. pause&exit /b
   
7. -->
   
8. <script src=http://www.bathome.net/lib/diy/Tools.js></script>
   
9. <script>
   
10. Tools.get('ren2')
    
11. close()
    
12. </script>

复制代码

话说竟然让一个这么好的工具尘封在硬盘里这么久,罪过啊!!
先前好多改名的问题用它就轻松解决了

228630386

回复 3# 228630386

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s "*.jpg"') do (
    set "newname=%%~ni"
    set "newname=!newname:~-2!"
    set "newname=!newname:-=!"
    ren "%%i" "!newname!.jpg"
)

改成这样可以了，非常感谢，又学到东西了。

pcl_test

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%a in ('dir /b /s *.jpg') do (
   
4.     set "tmp=%%~na"
   
5.     set "tmp=!tmp:-=,!"
   
6. for %%b in (!tmp!) do set "name=%%b"
   
7. ren "%%a" "!name!%%~xa"
   
8. )
   
9. pause

复制代码

pcl_test

ren2 [options] match format
Renames files using regular expressions
     match is a matching patters, and format is how to change the filename.
     Put the regular expressions in quotes " to make them behave well.
  -h help.
  -t make html file out.html showing changes.
  -f force file changes, otherwise changes are only shown, not made.
  -r recurse directories.
  -s display detailed syntax.

228630386

回复 7# pcl_test

亲，你的代码也可以用，谢谢！

bailong360

回复 7# pcl_test


    http://www.bathome.net/thread-35050-1-1.html
(^_^)

apang

1. @echo off & setlocal enabledelayedexpansion
   
2. for /f "delims=" %%a in ('dir /b /s *.jpg') do (
   
3.         set "s=%%a"
   
4.         for /f "delims=" %%b in ("!s:-=/!") do echo,Ren "!s!" "%%~nxb"
   
5. )
   
6. pause

复制代码

1. @set @n=0;/* & echo off
   
2. for /f "delims=" %%a in ('dir /b /s *.jpg^|cscript -nologo -e:jscript "%~0"') do (
   
3.         echo,Ren "%%a"
   
4. )
   
5. pause & exit/b & rem */
   
6. 
   
7. s = WScript.StdIn.ReadAll();
   
8. re = /.*-(\d+\.jpg$)/img;
   
9. while((ar = re.exec(s)) != null) {WScript.Echo(ar[0] + '" "' + ar[1])}

复制代码