【已解决】BAT:如何筛选未出现数

思想之翼 · 发表于 2015-2-19 22:34:50

本帖最后由思想之翼于 2015-2-20 23:00 编辑

D:/数据1/内有若干txt文本
每个文本内的数据格式为：
124
或者为：
159
456
357
或者为：
159 456 457

现在欲筛选出每个文本在0-9之间未出现的数据
比如：文本内数据是124，则未出现的数据是0356789
再比如：文本内数据是
159
456
357
则未出现的数据是028

将筛选出的未出现的数据，写入D:/数据2/，txt文本名称与原名称相同。若没有未出现的数据，则为空文本。

这样的代码如何写？恳望得到帮助。

pcl_test · 发表于 2015-2-19 23:43:35

回复 1# 思想之翼

@echo off
setlocal enabledelayedexpansion
cd /d "D:\数据1"
set "fdir=D:\数据2"
if not exist "%fdir%" md "%fdir%"
for /f "delims=" %%a in ('dir /b *.txt') do (
>$ echo 0123456789
set /p num=<$
for /l %%i in (0 1 9) do (
findstr "%%i" "%%a" >nul 2>nul && (>$ echo !num:%%i=!)
set /p num=<$
)
move /y $ "%fdir%%%a"
)
cd /d "%fdir%"
for /f "delims=" %%b in ('dir /b *.txt') do (
findstr "处于关闭状态" "%%b" >nul 2>nul && cd.>"%%b"
)
pause

复制代码

terse · 发表于 2015-2-20 14:32:35

@echo off & setlocal enabledelayedexpansion
cd /d "D:\数据1"
md "D:\数据2" 2>nul
for /f "delims=" %%a in ('dir /b *.txt') do (
set s=
for /l %%i in (0 1 9) do (
findstr %%i "%%a" >nul 2>nul ||set s=!s!%%i
)
>"D:\数据2\%%a" echo,!s!
)
pause

复制代码

c755731262 · 发表于 2015-2-21 05:38:39

@echo off&color f0
if not exist d:\数据2\ md d:\数据2\
for /f "delims=" %%a in ('dir /b d:\数据1\*.txt') do (
(for /l %%i in (0,1,9) do (
for /f "tokens=1-3" %%j in ('find /c "%%i" d:\数据1\%%a') do (
if %%l == 0 echo %%i
)
)
)>d:\数据2\%%a
)
pause

复制代码

回复 1# 思想之翼

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】BAT:如何筛选未出现数

评分

评分

评分