批处理如何输出注册表中多字符串的键值？

alpha

比如：HKCU\123项里面的test键值是：
123
456
789
我要让这个键值输出到1.txt文本中，也是注册表中的键值格式（而不是有换行符的那种）：
123
456
789

DAIC

reg export HKCU\123 test.reg
把 test.reg 压缩之后传上来看看

alpha

回复 2# DAIC

apang

1. @echo off
   
2. for /f "tokens=1,2*" %%a in ('reg query "HKCU\123"') do (
   
3.     if /i "%%a" == "test" set "var=%%c"
   
4. )
   
5. for %%a in ("%var:\0=" "%") do echo,%%~a
   
6. pause

复制代码

alpha

回复 4# apang


    为什么我合并为一行之后，会一闪而过？

1. (for /f "tokens=1,2*" %%a in ('reg query "HKCU\123"') do (if /i "%%a" == "test" set "var=%%c"))&(for %%a in ("%var:\0=" "%") do echo,%%~a)&pause

复制代码

Linuxer

把两个for套的括号去掉试试呢？
如果不行，那就是cmd识别不了这样的格式，还是分行写吧。

apang

回复 5# alpha


    你把它们整成一行，那就成复合语句了，那就必须开启变量延迟扩展

如果没有特殊要求，不建议这样干，可读性差，不便于修改维护

alpha

回复 7# apang


   说得妙，我发现开了延迟后，在cmd里面是无效的，必须要执行 cmd /v on，但是一旦开启这个，就不能合并为一行了，好纠结，还是那句话，怎么合并？

alpha

回复 6# Linuxer


    提示路径用法无效。

CrLf

回复 8# alpha


一定要写一行的话就是这样：

1. cmd /v /c "(for /f "tokens=1,2*" %%a in ('reg query "HKCU\123"') do (if /i "%%a" == "test" set "var=%%c"))&(for %%a in ("!var:\0=" "!") do echo,%%~a)&pause"

复制代码

但 cmd 里也可以写多行命令啊，如果可以复制粘贴为啥要写成一行...

alpha

回复 10# CrLf


    OK，谢啦，问题解决喽

alpha

回复 10# CrLf


    又有问题了，如果路径里面有空格就不行了。

apang

可以兼容路径中含\0和空格的情况，不要想合并到一行

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set Lf=^
   
4. 
   
5. 
   
6. for /f %%i in ('copy /z "%~0" nul') do for %%j in ("!Lf!") do (
   
7.     endlocal
   
8.     for /f "tokens=1,2*" %%a in ('reg query "HKCU\123" /se ^^^|')do (
   
9.         if /i "%%a" == "test" (
   
10.             set "var=%%c"
    
11.             setlocal enabledelayedexpansion
    
12.             echo,!var:^|=%%i%%~j!
    
13.         )
    
14.     )
    
15. )

复制代码

Microsoft Windows [版本 6.1.7601]
版权所有 (c) 2009 Microsoft Corporation。保留所有权利。

C:\Windows\System32>reg query "HKCU\123" /se ^|

HKEY_CURRENT_USER\123
    test    REG_MULTI_SZ    (Start "" "C:\a b c\01.exe")|(Start C:\2.exe)|(Start
C:\3.exe)


C:\Windows\System32>C:\Users\apang\Desktop\test.bat
(Start "" "C:\a b c\01.exe")
(Start C:\2.exe)
(Start C:\3.exe)
C:\Windows\System32>

DAIC

回复 8# alpha


    出于什么样的需求必须要合并到一行？

alpha

回复 14# DAIC


    我的delphi不支持多行命令。