批处理从 makecab 输出中获取时间和日期

tmplinshi

1. @echo off
   
2. 
   
3. echo, & echo ------------ 输出默认格式
   
4. call :Now
   
5. 
   
6. echo, & echo ------------ 输出自定义格式
   
7. call :Now YYYY年-MM月-DD日 HH时:MI分:SS秒 星期Week
   
8. 
   
9. echo, & echo ------------ 设置到变量
   
10. call :Now (set)
    
11. set now
    
12. 
    
13. pause
    
14. exit /b
    
15. 
    
16. ::=============================================================
    
17. :: 函数: Now --- 获取当前时间和日期
    
18. ::
    
19. :: 原理:
    
20. ::         从 makecab 输出文件中的第一行读取时间日期。第一行格式为:
    
21. ::                MakeCAB Report: Sat Nov 16 02:36:02 2013
    
22. :: 参数:
    
23. ::         默认值为 YYYY-MM-DD HH:MI:SS Week
    
24. ::
    
25. ::         如果参数为 "(set)"，则时间日期会被设置到以下变量中:
    
26. ::                now.yyyy now.mm now.dd now.hh now.mi now.ss now.week
    
27. 
    
28. :Now [Output=YYYY-MM-DD HH:MI:SS Week]
    
29. makecab /d RptFileName="%temp%\.rpt" /d InfFileName=nul /f nul >nul
    
30. 
    
31. for /f "usebackq tokens=3-9 delims=: " %%1 in ("%temp%\.rpt") do (
    
32.         setlocal enabledelayedexpansion
    
33.         
    
34.         set WeekList=Mon_1 Tue_2 Wed_3 Thu_4 Fri_5 Sat_6 Sun_7
    
35.         set /a Week = !WeekList:*%%1_=! 2>nul
    
36.         
    
37.         set MonthList=Jan_1 Feb_2 Mar_3 Apr_4 May_5 Jun_6 Jul_7 Aug_8 Sep_9 Oct_10 Nov_11 Dec_12
    
38.         set /a MM = !MonthList:*%%2_=! 2>nul
    
39.         
    
40.         if "%~1" == "" (
    
41.                 echo %%7-!MM!-%%3 %%4:%%5:%%6 !Week!
    
42.         ) else if /i "%~1" == "(set)" (
    
43.                 for /f "tokens=1-7" %%a in ("%%7 !MM! %%3 %%4 %%5 %%6 !Week!") do (
    
44.                         endlocal
    
45. 
    
46.                         set now.yyyy=%%a
    
47.                         set now.mm=%%b
    
48.                         set now.dd=%%c
    
49.                         set now.hh=%%d
    
50.                         set now.mi=%%e
    
51.                         set now.ss=%%f
    
52.                         set now.week=%%g
    
53. 
    
54.                         goto :eof
    
55.                 )
    
56.         ) else (
    
57.                 set "Output=%*"
    
58. 
    
59.                 set Output=!Output:YYYY=%%7!
    
60.                 for %%m in (!MM!) do set Output=!Output:MM=%%m!
    
61.                 for %%w in (!Week!) do set Output=!Output:Week=%%w!
    
62.                 set Output=!Output:DD=%%3!
    
63.                 set Output=!Output:HH=%%4!
    
64.                 set Output=!Output:MI=%%5!
    
65.                 set Output=!Output:SS=%%6!
    
66.         
    
67.                 echo,!Output!
    
68.         )
    
69. 
    
70.         endlocal
    
71.         goto :eof
    
72. )
    
73. ::=============================================================

复制代码

从以下链接看到的方法:
http://with-love-from-siberia.blogspot.com/2009/11/cross-platform-datetime-definition.html