zqz0012005

嗯，没必要将大小写字母定义在两个变量中。

@echo off
set "letters= abcdefghijklmnopqrstuvwxyzZYXWVUTSRQPONMLKJIHGFEDCBA"
for /l %%a in (1,1,26) do call set /a "_%%letters:~%%a,1%%=%%a"
:input
setlocal EnableDelayedExpansion
echo 请输入:&set /p var=&if not defined var endlocal&goto:input
:loop
set char=!var:~%pi%,1!
set /a sn=_!char! 2>nul||set sn=0
if defined char (
    if %sn% gtr 0 (
        if "!char!"=="!letters:~%sn%,1!" (set str=!str!!letters:~-%sn%,1!) else (set str=!str!!letters:~%sn%,1!)
    ) else (
        set str=!str!!char!
    )
    set /a pi+=1
    goto loop
)
echo=!str!
pause&endlocal&goto input
复制代码

netbenton

支持各种特殊情况
包括：

^ < > " ; ^ & * = ：~ |
复制代码

等符号

 @echo off&setlocal enabledelayedexpansion
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set @D%%a=%%a
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set @x%%a=%%a
set /p in=输入一个大小写都的有字符串：
set n=0
set out=
for /l %%a in (0) do (
for %%n in (!n!) do (
  for /f "delims=" %%b in ("!in:~%%n,1!") do (
   if defined @d%%b (
    if %%b equ !@D%%b! (set out=!out!!@x%%b!) else (set out=!out!!@D%%b!)
   ) else (
    set out=!out!^^%%b
   )
  set /a n+=1
  )
  if "!in:~%%n,1!" equ ";" set out=!out!;&set/a n+=1
  if %%n equ !n! echo;大小写互换为：!out!&PAUSE&exit
)
)
复制代码

[ 本帖最后由 netbenton 于 2009-11-14 19:32 编辑 ]

zqz0012005

不要忘了 for /f 的 eol 隐患，呵呵。

for /l 无限循环由于运行机制，其实不太实用。必须用 exit 强制退出整个bat，exit /b 或 goto 都不行。

netbenton

re zqz0012005
48楼又经修改，增加了以下特殊符号的处理：
^ ; !

效率可是很高的了
确实是只有exit强行退出，还没想到其它办法来做到一个预处理全部完成的，只好用它了。

Taurus

試一試...

@echo off&setlocal enabledelayedexpansion&set nub=0
set "s=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "b=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
for %%i in (!s!) do set/a num+=1&set %%i1=%%i
for %%i in (!b!) do set/a num2+=1&set %%i2=%%i
set /p "str=string= *"
:lp
call set str=%%str:~!nub!%%
for %%i in (!b!) do if "!str:~0,1!"=="%%i" call set "OK=!OK!%%!str:~0,1!1%%"&goto ut
for %%i in (!s!) do if "!str:~0,1!"=="%%i" call set "OK=!OK!%%!str:~0,1!2%%"&goto :out
if not "!str!"=="" (set "ok=!ok!!str:~0,1!") else (goto :end)
:out
set nub=1
goto :lp
:end
echo string= *!OK!
pause>nul

CrLf

用 choice 的思路，不通用、不高效、不简洁、不考虑字符的兼容性：

aAcebFaJad
cls
@echo off&setlocal enabledelayedexpansion
set str=#ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890
set /p 字符串=<%0
set 字
call :strlen 字符串
(for /l %%a in (1 1 !len!) do (
choice /cs /c abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890 /n>nul
for %%b in (!errorlevel!) do set 结 果 =!结 果 !!str:~%%b,1!
))<%0
set 结
pause

:strlen
setlocal enabledelayedexpansion
set "$=!%1!#"
set len=&for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1)do if !$:~%%a^,1!. NEQ . set/a len+=%%a&set $=!$:~%%a!
endlocal&If %2. neq . (set/a%2=%len%)else set len=%len%
复制代码

batman

vbs:

Dim inpStr, Arr, Str
inpStr = InputBox("请输入要转换的字符串")
Arr = split("a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z", ",")
For Each Str In Arr
  inpStr = Replace(inpStr, Str,"@#$&")
  inpStr = Replace(inpStr, UCase(Str), Str)
  inpStr = Replace(inpStr, "@#$&", UCase(str))
Next
MsgBox inpStr
复制代码

CrLf

另一种逐字替换，兼容各种可见的特殊字符，调用 ascmap 后可以支持汉字：

@echo off
set "字符串=WwW.baThOME.net"
set 字
setlocal enabledelayedexpansion
set<nul>tmp /p=@!字符串!
(for %%a in (tmp) do (
	for /l %%b in (1 2 %%~za) do echo;
))>k

set str=@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@!"#$%%&'()*+,-./0123456789:;<=>?@abcdefghijklmnopqrstuvwxyz[\]^_`ABCDEFGHIJKLMNOPQRSTUVWXYZ{|}~
for /f "skip=2 tokens=1,3" %%a in ('fc /b k tmp') do if "%%a" lss "1" set 结 果 =!结 果 !!str:~0x%%b,1!

set 结
del tmp k
pause
复制代码

mxxcgzxxx

没事来个好玩的

@echo off
setlocal enabledelayedexpansion
set str=aAbBcCdDeEfFgGhHiIjJkKlLmMnNoOpPqQrRsStTuUvVwWxXyYzZ
:1
set/p p=
echo %p%|findstr "--[a-Z]--">nul&&echo 大哥没事写神马多减号嘛！重写！ && ghoto :1
set a=26
:2
set /a a-=1
set b=!str:~%a%,1!
set "p=!p:%b%=--%b%--!"
set /a a-=1
set c=!str:~%a%,1!
set "p=!p:%c%=%b%!"
set "p=!p:--%b%--=%c%!"
if %a%==0 goto :3
goto :2
:3
echo %p%
pause
复制代码

BS0小陈

@echo off
setlocal enabledelayedexpansion
set "nn=qQ wW eE rR tT yY uU iI oO pP aA sS dD fF gG hH jJ kK lL zZ xX cC vV bB nN mM"
set "a=123a,B"
                                                                                    
:a
set aa=!a:~0,1!
set aaa=!a:~1!
for %%a in (!nn!) do (
set n=%%a
set n1=!n:~0,1!
set n2=!n:~1,1!
if "!aa!"=="!n1!" (
set /p=!n2!<nul) else (
if "!aa!"=="!n2!" (
set /p=!n1!<nul) else (set /p=!aa!<nul)
)
set a=!aaa!
pause>nul
if "a"=="" goto :end
goto :a
)
:end
pause
复制代码

为什么出问题了！！！！

lpy19870706

不通用的

@echo off
set var=abHJ      dfsKHK  aB
echo 替换前 %var%
set a=%var:abHJ      dfsKHK  aB=AVhj      DFSkhk  Ab%
echo 替换后 %a%
pause>nul
复制代码

jains521

@echo off& setlocal enabledelayedexpansion

set __var1=a b c d e f g h i j k l m n o p q r s t u v w x y z 
set __var2=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
set /p var=input strings:
call :setvar __var1
call :setvar __var2

set n=0
:chg
if not "!var:~%n%,1!" equ "" (
	if "!var:~%n%,1!" equ " " (set _vartmp=!_vartmp! ) else (
		set #tmp=!var:~%n%,1!
		for /f "tokens=2 delims==" %%i in ('set _!#tmp!') do (
			if not "!var:~%n%,1!" equ "%%i" set __vartmp=!__vartmp!%%i
		)
	)
	set /a n+=1
	goto chg
)
echo !__vartmp!
pause
goto :eof

:setvar
for %%i in (!%1!) do set _%%i%1=%%i
goto :eof
复制代码

CrLf

一翻旧帖才发现自己以前已经发过了奇葩代码，那就贴两个常规思路的吧，估计会撞车：

@echo off&setlocal enabledelayedexpansion
set "str=TestABC"

set "str2=!str:~1!"
set "大写=!str!"&set "小写=!str!"

for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set "大写=!大写:%%a=%%a!"
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set "小写=!小写:%%a=%%a!"

for /l %%a in (0 1 100) do (
	if "!str:~%%a,1!"=="!小写:~%%a,1!" (
		set "str=!str:~,%%a!!大写:~%%a,1!!str2:~%%a!"
	) else (
		if "!str:~%%a,1!"=="!大写:~%%a,1!" set "str=!str:~,%%a!!小写:~%%a,1!!str2:~%%a!"
	)
)
echo !str!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set "str=TestABC"

set "str=@!str!"
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z)do set %%a=%%a

for /l %%a in (1 1 8189)do (
	if "!str:~%%a,1!"=="" (
		for /f "delims=" %%b in (^""!结果!"^")do echo %%~b&pause
	)
	set 结果=!结果!!str:~%%a,1!
	if !str:~%%a^,1! leq Z if !str:~%%a^,1! geq a (
		for /f %%b in ("!str:~%%a,1!:") do (
			if %%b neq %%~db (set chr=%%~db)else set chr=!%%b~0!
		)
		set 结果=!结果:~,-1!!chr:~,1!
	)
)
复制代码

悬崖之树

本代码处理的字符串不得有空格和特殊符号，也就是只能是大小写字母。

@echo off&setlocal enabledelayedexpansion
set str=qdjSSM
for /l %%i in (0 1 100) do (
   if "!str:~%%i,1!" neq "" (
      set "s=!s!!str:~%%i,1!  "
   )
)
set "ll=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z" 
set "ss=a b c d e f g h i j k l m n o p q r s t u v w x y z" 
for %%a in (%s%) do (
   for %%b in (%ll%) do (
      if /i %%a equ %%b (
        if %%a neq %%b (
           set res=!res!%%b
        )
      )
   )
   for %%b in (%ss%) do (
      if /i %%a equ %%b (
        if %%a neq %%b (
           set res=!res!%%b
        )
      )
   )
)
echo %res%
pause
复制代码

muink

@echo off

setlocal enabledelayedexpansion

(for /f "delims=" %%i in ('type 示例文件.txt') do (
   set "str=%%i"
   for %%s in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set "str=!str:%%s=%%s!"
   REM for %%s in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set "str=!str:%%s=%%s!"
   echo.!str!
))>示例文件_new.txt
复制代码