[已解决]批处理在字符间插入符号，请看一下问题出在哪里？

suseek · 发表于 2013-10-30 09:41:01

本帖最后由 suseek 于 2013-10-30 14:45 编辑

一个2008年的贴子
原贴是如何在文本中插入符号
比如 aaa.txt中
00112233445566778899
99887766554433221100

想用批处理在他们之间每隔2个数字插入+得到下面的效果

00+11+22+33+44+55+66+77+88+99
99+88+77+66+55+44+33+22+11+00
我的脚本是:

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ( aaa.txt ) do (
set var=
set str=%%a
call :lp
echo !var:~1!
)
pause
:lp
set str1=!str:~,2!
set var=!var!+!str1!
set str=!str:~2!
if not defined str goto :eof
goto :lp

复制代码

为什么结果会多出三项+
00+11+22+33+44+55+66+77+88+99+ + +
99+88+77+66+55+44+33+22+11+00+ + +
文档中并没有多余的空格,谢谢

apang · 发表于 2013-10-30 10:15:29

set str=%%a和set str=!str:~2!后面含有n多空格，str值为空格时就会出现后面的空加号
set赋值时用引号包围：set "str=%%a" 就可以了

foxJL · 发表于 2013-10-30 10:26:25

call的效率太低，试试全用for

@echo off&setlocal enabledelayedexpansion
for /f %%i in (aaa.txt) do (
set "str=%%i" & set "v="
for /l %%j in (0,2,18) do (set v=!v!+!str:~%%j,2!)
echo,!v:~1!
)
pause

复制代码

foxJL · 发表于 2013-10-30 10:32:05

300行比你的快了10秒钟,要效率尽量少用call goto这些命令

DAIC · 发表于 2013-10-30 10:47:04

回复 4# foxJL

凑个热闹：

sed "s/../&+/g; s/+$//" aaa.txt

复制代码

suseek · 发表于 2013-10-30 14:48:33

谢谢APANG的指导,FOXJL的新思路,DAIC的新方法

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理在字符间插入符号，请看一下问题出在哪里？

评分

评分

评分

评分