【已解决】批处理:帮忙改一下重命名文件的脚本啊

001011 · 发表于 2013-8-18 06:45:16

本帖最后由 001011 于 2013-8-18 09:03 编辑

下面的这个脚本，原先设计的改变jpg的文件名。现在的一批文件夹里面同时有两种格式 jpg和tif 请帮忙改一下叫吧感谢
原先求助的帖子链接：http://www.bathome.net/thread-25445-1-1.html

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
set /a n=0
for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul') do (
set /a n+=1&set "num=00!n!"
ren "%%~dpna\%%b" "%%~na-!num:~-3!.jpg"
)
)

复制代码

canyuexiaolang · 发表于 2013-8-18 07:24:03

好歹也是二级士官了，难道一点都没学么。

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
set /a n=0
for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul ^& dir /a-d /b "%%~dpna\*.wma" 2^>nul') do (
set /a n+=1&set "num=00!n!"
echo ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
)
)
pause

复制代码

gawk · 发表于 2013-8-18 08:40:46

@echo off
setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
set n=0
for /f "delims=" %%b in ('dir /a-d /b "%%~dpna" 2^>nul') do (
set /a n+=1
set "num=00!n!"
ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
)
)

复制代码

001011 · 发表于 2013-8-18 09:02:56

非常感谢不是没学只是按照我所学的测试了几次都没有成功
我再努力

CrLf · 发表于 2013-8-18 11:12:45

个人比较喜欢 set /a n+=1001 来代替 set /a n+=1&set "num=00!n!"
仅适用低于 %06d 的格式

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】批处理:帮忙改一下重命名文件的脚本啊

评分

评分

评分