【已解决】批处理如何获取指定盘大小的变量？

807979023 · 发表于 2013-3-31 18:59:04

本帖最后由 807979023 于 2013-4-1 10:55 编辑

比如：
如何获取R盘大小的变量，以m为单位。

家鹏 · 发表于 2013-3-31 20:49:33

wmic LogicalDisk where "Caption='R:'" get FreeSpace,Size /value

以字节为单位

apang · 发表于 2013-4-1 10:16:16

@echo off
%2 for /f "tokens=2delims==" %%a in ('wmic logicaldisk where "name='C:'" get size/value^|find "="') do set sz=%%a
%2 mshta vbscript:createobject("wscript.shell").run("%~s0 "^&round(%sz%/1024/1024,2)^&" Rem")(window.close)&goto :eof
echo C盘容量为 %1 MB
pause

复制代码

terse · 发表于 2013-4-1 14:00:24

笨办法也是老办法了

@echo off&setlocal enabledelayedexpansion
set Md=1048576&set "name=c:"
for /l %%i in (1 1 9) do set /aNum%%i=MD*%%i&set "Num%%i=0!Num%%i!"
for /f "skip=1" %%a in ('wmic logicaldisk where "name='%name%'" get Size') do (
set "Size=0%%a00"
set S=!Size!&set Line=0
for %%i in (16 8 4 2 1) do if "!s:~%%i!" neq "" set/a Line+=%%i&set "S=!S:~%%i!"
set "str=!Size:~1,7!"
if !str! lss !MD! (set i=8)else set i=7&set "str=!Size:~,7!"
for /l %%i in (1 1 9) do set s=!s:%%i=0!
for /l %%i in (!i! 1 !Line!) do (
set "str=!s!!str!!Size:~%%i,1!"
set "str=!str:~-8!"
if !str! geq !Num1! (
set N=1
for /l %%j in (2 1 9) do if "!str!" geq "!Num%%j!" set "N=%%j"
set "G_Size=!G_Size!!N!"
for %%j in (!N!) do set /a "str=3!str!-1!Num%%j!"
set str=!str:~1!
) else set "G_Size=!G_Size!0"
)
echo %name% !G_Size:~,-2!.!G_Size:~-2! [M]
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] 【已解决】批处理如何获取指定盘大小的变量？