求教,批处理文本B里面的内容到文本A的对应的文字后面

5935726 · 发表于 2013-3-25 21:52:44

本帖最后由 5935726 于 2013-3-25 21:59 编辑

文本A的内容
name=
add=
pass=

name=
add=
pass=

name=
add=
pass=

文本B的内容
1234
2345
3456

我想把B的内容,对应的复制到A的 name= 的后面求bat代码

tmplinshi · 发表于 2013-3-25 22:33:16

@echo off
SetLocal EnableDelayedExpansion
::
:: 设置文本
::
set Text_A="a.txt"
set Text_B="b.txt"
::
:: 把文本B每一行保存为变量
::
set n=0
for /f "usebackq delims=" %%a in (%Text_B%) do (
set /a n += 1
set .!n!.=%%a
)
::
:: 修改文本A
::
set n=0
set TempFile=.tmp%random%
(
for /f %%a in (' findstr /n .* %Text_A% ') do (
set LineText=
set /p LineText=
if /i "!LineText:~0,5!" == "name=" (
set /a n += 1
for %%a in (.!n!.) do set LineText=name=!%%a!
)
echo,!LineText!
)
) <%Text_A% >%TempFile%
move %TempFile% %Text_A%
start "" %Text_A%

复制代码

5935726 · 发表于 2013-3-26 04:19:01

回复 2# tmplinshi

版主好凶残啊

我朋友看了是这样评价你的

感谢
由于我是初学者,有些不懂的地方可以请教你吗

tmplinshi · 发表于 2013-3-26 05:34:10

回复 3# 5935726

有不懂的直接回帖就行了，其他人看见了也许也会回复你的。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 求教,批处理文本B里面的内容到文本A的对应的文字后面