设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT原创&转载 › 批处理版注册表法隐藏磁盘（普通隐藏） ...
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发新帖
查看: 27307|回复: 6

[系统增强] 批处理版注册表法隐藏磁盘（普通隐藏）

[复制链接]
wxcute
发表于 2008-9-16 20:17:05 | 显示全部楼层 |阅读模式
代码未简化。只是需要的时候用用
有需要的可以配合我的这个帖子简化一下
输入字母后按顺序大写输出
这种隐藏可以在资源管理器中输入被隐藏的盘符以打开
有简短说明的，新手可以拆开学习学习

其中[小写转大写][十进制转十六进制]两个是完全抄来的，呵呵
  1. @echo off

  3. :inp
  4. set Drv=
  5. cls
  6. echo 输入数字“0”取消隐藏，输入不重复的字母隐藏相应的磁盘。
  7. set/p Drv=输入磁盘(如：EaF)-

  9. if "%Drv%"=="" goto :inp
  10. set "A_Z=A B C D E F G H I J K L N M O P Q R S T U V W X Y Z"

  12. for /f %%i in ("%Drv%") do call :setv "%%i"
  13. if %Drv%==0 set TT=00&goto :hidrv

  15. ::小写换大写
  16. for %%j in (%A_Z%) do call,set "Drv=%%Drv:%%j=%%j%%"

  18. ::判断重复
  19. set ddrv=%Drv%
  20. set num=
  21. :rpd
  22. if #%dDrv%==# goto :rout
  23. set/a num+=1
  24. ::判断字符
  25. call :wrd %ddrv:~0,1%
  26. if %flag%==0 goto :err
  27. set dDrvTmp%num%=%ddrv:~0,1%
  28. set dDrv=%ddrv:~1%
  29. goto :rpd
  30. :rout
  31. setlocal enableDelayedExpansion
  32. for /l %%c in (1 1 %num%) do (
  33. 　set/a nn=%%c+1
  34. 　for /l %%d in (!nn! 1 %num%) do (
  35. 　　if /i !dDrvTmp%%c!==!dDrvTmp%%d! goto :err
  36. 　)
  37. )

  39. ::按顺序排列
  40. for /l %%e in (1 1 %num%) do (
  41. 　for /l %%f in (1 1 %num%) do (
  42. 　　if !dDrvTmp%%e! lss !dDrvTmp%%f! (
  43. 　　　set x=!dDrvTmp%%e!
  44. 　　　set dDrvTmp%%e=!dDrvTmp%%f!
  45. 　　　set dDrvTmp%%f=!x!
  46. 　　)
  47. 　)
  48. )
  49. for /l %%k in (1 1 %num%) do (
  50. 　set DD=!DD!!dDrvTmp%%k!
  51. )

  53. ::显示
  54. set dd=!dd:~-%num%!
  55. echo 要隐藏的磁盘有%DD%，共[%num%]个盘。

  57. set n10=
  58. :MuD
  59. if #%DD%==# goto :reg16
  60. set DDTmp=%dD:~0,1%
  61. set DD=%dD:~1%

  63. set n=1
  64. for %%m in (%A_Z%) do (
  65. 　call :setn n
  66. 　if /i %DDTmp%==%%m call :setn2 n2&goto :outFor
  67. )
  68. :outFor
  69. set/a n10+=%n2%
  70. goto :MuD

  72. ::换成十六进制
  73. :reg16
  74. call :A %n10%
  75. ::echo !T3!

  77. ::注册表二进制数值表达方式
  78. ::T3换BIN
  79. set TT=
  80. :bi
  81. set/a x+=1
  82. set Tn=0%T3:~-2%
  83. set Tn=!Tn:~-2!
  84. set T3=%T3:~,-2%
  85. set TT=!TT!!Tn!
  86. if not #%T3%==# goto :bi

  88. ::隐藏磁盘
  89. ::-=核心代码=-
  90. :hidrv
  91. set TT=%TT%000000
  92. echo %TT:~,8%
  93. reg add HKCU\SoftWare\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDrives /t REG_BINARY /d %TT:~,8% /f

  95. echo 结束explorer进程生效。按任意键结束并打开我的电脑查看
  96. pause>nul
  97. taskkill /f /im explorer.exe>nul
  98. endlocal
  99. start/min "" explorer "%~dp0"
  100. start explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}

  102. ping n 3 127.1>nul
  103. goto :eof

  105. ::调用标签
  106. :err
  107. 　cls&echo 输入格式不正确，或有不允许的字符。
  108. 　echo 请重新输入...
  109. 　ping n 2 127.1>nul
  110. 　goto :inp
  111. 　goto :eof
  112. :wrd
  113. 　for %%p in (%A_Z%) do if %1==%%p set flag=1&goto :eof
  114. 　set flag=0
  115. 　goto :eof
  116. :setv
  117. 　set Drv=%~1
  118. 　goto :eof
  119. :setn
  120. 　set/a %1*=2
  121. 　goto :eof
  122. :setn2
  123. 　set/a %1=%n%/2
  124. 　goto :eof
  125. :A
  126. 　set str=0123456789ABCDEF
  127. 　set T1=%1
  128. 　SET T3=
  129. :B
  130. 　set/A T2=T1%%16
  131. 　SET T2=!str:~%t2%,1!
  132. 　SET/A T1=%T1%/16
  133. 　SET T3=%T2%%T3%
  134. 　IF %T1%==0 GOTO :EOF
  135. 　GOTO B

  137. goto :eof
  138. exit
  139. ::========================
  140. ABCD　E　F　G 　H 　I 　J　　K　　L　　M　　N 　　O
  141. 1248 16 32 64 128 256 512 1024 2048 4096 8192 16384
  142. 　P 　　Q　　　R　　　S　　　T　　　U 　　　V
  143. 32768 65536 131072 262144 524288 1048576 2097152
  144. 　W 　　　X　　　　Y　　　　Z
  145. 4194304 8388608 16777216 33554432
  146. ::------------------------
  147. 输入字母，判断是哪个，计算出十进制数，再换算成十六进制
  148. 相加，得结果
  149. 结束explorer进程，再打开我的电脑查看
  150. ::------------------------
  151. 系统目录CLSID：
  152. 网上邻居.{208D2C60-3AEA-1069-A2D7-08002B30309D}
  153. 我的电脑.{20D04FE0-3AEA-1069-A2D8-08002B30309D}
  154. 回收站(满).{5ef4af3a-f726-11d0-b8a2-00c04fc309a4}一般无效
  155. 回收站.{645FF040-5081-101B-9F08-00AA002F954E}
  156. ::------------------------
  157. 输入字母，判断是哪个，+[判断重复][转成大写][调整字母顺序]，
  158. 计算出十进制数，再换算成十六进制，+[换成注册表相应的格式]，
  159. 结束explorer进程，再打开我的电脑查看
  160. ::------------------------
  161. [如何清空变量]
  162. [去除一行中重复的字符]
  163. ::------------------------
  164. setlocal enableDelayedExpansion
  165. 开启了变量延迟，如果目录或文件名中含有“!”感叹号，
  166. 可能会解释成变量识别符号。
  167. ::------------------------
  168. REG_BINARY（默认）类型换成REG_DWORD也可以用。
  169. ::========================
复制代码

评分

参与人数 2PB +13 收起 理由
SmallK + 5 辛苦了
pusofalse + 8 感谢分享

查看全部评分

回复

举报

wxcute
 楼主| 发表于 2008-9-30 16:32:01 | 显示全部楼层

借今天修改下代码吧

身体还有些不适，不过已经好多了。
太费脑子的事情做不来，就改改代码，还有帮忙回下简单的帖子吧。
  1. @echo off

  3. :inp
  4. cls
  5. set Drv=
  6. echo 输入数字“0”取消隐藏，输入若干字母隐藏相应的磁盘。
  7. set/p Drv=输入磁盘(如：EaF)-

  9. if "%Drv%"=="" goto :inp
  10. if %Drv%==0 set TT=00&goto :hidrv

  12. ::小写换大写顺序输出并剔除重复
  13. set mat=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
  14. for %%d in (%mat%) do (
  15. 　call set _%%d=
  16. )
  17. :lp
  18. if not defined _%Drv:~,1% set "_%Drv:~,1%=1"
  19. set "Drv=%Drv:~1%"
  20. if defined Drv goto lp
  21. set n=1
  22. set n10=
  23. set Dnum=
  24. for %%m in (%mat%) do (
  25. 　call :setn n
  26. 　if defined _%%m (
  27. 　　call :sshow %%m Drv Dnum n2 n10
  28. 　)
  29. )

  31. ::显示
  32. echo.
  33. echo 要隐藏的磁盘有%Drv%，共[%Dnum%]个盘。

  35. ::换成十六进制
  36. :reg16
  37. setlocal enableDelayedExpansion
  38. call :A %n10%

  40. ::注册表二进制数值表达方式
  41. ::T3换BIN
  42. set TT=
  43. :bi
  44. set/a x+=1
  45. set Tn=0%T3:~-2%
  46. set Tn=!Tn:~-2!
  47. set T3=%T3:~,-2%
  48. set TT=!TT!!Tn!
  49. if not #%T3%==# goto :bi

  51. ::隐藏磁盘
  52. ::-=核心代码=-
  53. :hidrv
  54. set TT=%TT%000000
  55. reg add HKCU\SoftWare\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDrives /t REG_BINARY /d %TT:~,8% /f

  57. echo 结束explorer进程生效。按任意键结束并打开我的电脑查看
  58. pause>nul
  59. taskkill /f /im explorer.exe>nul
  60. endlocal
  61. start/min "" explorer "%~dp0"
  62. start explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}

  64. ping -n 3 127.1>nul
  65. goto :eof

  67. ::调用标签
  68. :sshow
  69. 　set %2=%Drv%%1
  70. 　set/a %3+=1
  71. 　set/a %4=n/2
  72. 　set/a %5+=n2
  73. 　goto :eof
  74. :setn
  75. 　set/a %1*=2
  76. 　goto :eof
  77. :A
  78. 　set str=0123456789ABCDEF
  79. 　set T1=%1
  80. 　SET T3=
  81. :B
  82. 　set/A T2=T1%%16
  83. 　SET T2=!str:~%t2%,1!
  84. 　SET/A T1=%T1%/16
  85. 　SET T3=%T2%%T3%
  86. 　IF %T1%==0 GOTO :EOF
  87. 　GOTO B
复制代码
回复

举报

ynkm0871
发表于 2010-4-29 11:33:10 | 显示全部楼层
这个批处理很好用的哟，感谢并支持！
回复

举报

heanv
发表于 2010-8-15 01:40:16 | 显示全部楼层
不错不错，真的管用。
回复

举报

RobinKee
发表于 2010-11-17 19:42:19 | 显示全部楼层
好东西!!!! 哈哈
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-17 00:09 , Processed in 0.020474 second(s), 9 queries , File On.

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表