批处理能否做一个点餐系统？

lovealei

1. 
   
2.    米线类(编号1开头)
   
3. ----------------------------------------------------------------------------------
   
4.    [111] 杂酱米线(小) 3.5元  [121] 杂酱米线(中) 4.0元  [131] 杂酱米线(大) 4.5元
   
5.    [112] 焖肉米线(小) 4.0元  [122] 焖肉米线(中) 4.5元  [132] 焖肉米线(大) 4.5元
   
6.    [113] 牛肉米线(小) 4.0元  [123] 牛肉米线(中) 4.5元  [133] 牛肉米线(大) 4.5元
   
7.    [114] 猪脚米线(小) 4.0元  [124] 猪脚米线(中) 4.5元  [134] 猪脚米线(大) 4.5元
   
8.    [115] 三鲜米线(小) 3.5元  [125] 三鲜米线(中) 4.0元  [135] 三鲜米线(大) 4.5元
   
9. ----------------------------------------------------------------------------------
   
10. 
    
11.    卷粉类(编号2开头)
    
12. ----------------------------------------------------------------------------------
    
13.    [211] 杂酱卷粉(小) 3.5元  [221] 杂酱卷粉(中) 4.0元  [231] 杂酱卷粉(大) 4.5元
    
14.    [212] 焖肉卷粉(小) 4.0元  [222] 焖肉卷粉(中) 4.5元  [232] 焖肉卷粉(大) 5.0元
    
15.    [213] 牛肉卷粉(小) 4.0元  [223] 牛肉卷粉(中) 4.5元  [233] 牛肉卷粉(大) 5.0元
    
16.    [214] 猪脚卷粉(小) 4.0元  [224] 猪脚卷粉(中) 4.5元  [234] 猪脚卷粉(大) 5.0元
    
17.    [215] 三鲜卷粉(小) 3.5元  [225] 三鲜卷粉(中) 4.0元  [235] 三鲜卷粉(大) 4.5元
    
18. ----------------------------------------------------------------------------------
    
19. 
    
20.    面条类(编号3开头)
    
21. ----------------------------------------------------------------------------------
    
22.    [311] 杂酱面条(小) 4.0元  [321] 杂酱面条(中) 4.5元  [331] 杂酱面条(大) 5.0元
    
23.    [312] 焖肉面条(小) 4.5元  [322] 焖肉面条(中) 5.0元  [332] 焖肉面条(大) 5.5元
    
24.    [313] 牛肉面条(小) 4.5元  [323] 牛肉面条(中) 5.0元  [333] 牛肉面条(大) 5.5元
    
25.    [314] 猪脚面条(小) 4.5元  [324] 猪脚面条(中) 5.0元  [334] 猪脚面条(大) 5.5元
    
26.    [315] 三鲜面条(小) 4.0元  [325] 三鲜面条(中) 5.0元  [335] 三鲜面条(大) 5.0元
    
27. ----------------------------------------------------------------------------------
    
28. 
    
29.    饵丝类(编号4开头)
    
30. ----------------------------------------------------------------------------------
    
31.    [411] 杂酱饵丝(小) 4.0元  [421] 杂酱饵丝(中) 4.5元  [431] 杂酱饵丝(大) 5.0元
    
32.    [412] 焖肉饵丝(小) 4.5元  [422] 焖肉饵丝(中) 5.0元  [432] 焖肉饵丝(大) 5.5元
    
33.    [413] 牛肉饵丝(小) 4.5元  [423] 牛肉饵丝(中) 5.0元  [433] 牛肉饵丝(大) 5.5元
    
34.    [414] 猪脚饵丝(小) 4.5元  [424] 猪脚饵丝(中) 5.0元  [434] 猪脚饵丝(大) 5.5元
    
35.    [415] 三鲜饵丝(小) 4.0元  [425] 三鲜饵丝(中) 4.5元  [435] 三鲜饵丝(大) 5.0元
    
36. ----------------------------------------------------------------------------------
    
37. 
    
38.    饺子类(编号5开头)
    
39. ----------------------------------------------------------------------------------
    
40.    [511] 清汤饺子(小) 4.5元  [521] 清汤饺子(中) 5.0元  [531] 清汤饺子(大) 5.5元
    
41.    [512] 酸辣饺子(小) 4.5元  [522] 酸辣饺子(中) 5.0元  [532] 酸辣饺子(大) 5.5元
    
42.    [513] 麻辣饺子(小) 4.5元  [523] 麻辣饺子(中) 5.0元  [533] 麻辣饺子(大) 5.5元
    
43. ----------------------------------------------------------------------------------
    
44. 
    
45.   请输入编号:

复制代码

上面代码中,111 112 113 等是商品编号, 对应相应的变量 S111,S112,S113 , 每个商品有对应的价格变量 SJ111,SJ112,SJ113

这些变量已经定义好, 接下来的问题是:

如果只选择一个商品是很好解决的,但是如果是选择多个商品呢? 还有多个商品,多个数量的问题,

比如说选择了这三种商品,要如何计算总价 111] 杂酱米线(小) 3.5元  [121] 杂酱米线(中) 4.0元  [131] 杂酱米线(大) 4.5元

又比如说
[111] 杂酱米线(小) 3.5元   二份
[121] 杂酱米线(中) 4.0元   三份
[131] 杂酱米线(大) 4.5元   一份

又要如何计算?

CUer

把你定义变量的那部分代码贴出来看看

lovealei

1. Set S111=杂酱米线(小)
   
2. Set S112=焖肉米线(小)
   
3. Set S113=牛肉米线(小)
   
4. Set S114=猪脚米线(小)
   
5. Set S115=三鲜米线(小)
   
6. 
   
7. Set S211=杂酱卷粉(小)
   
8. Set S212=焖肉卷粉(小)
   
9. Set S213=牛肉卷粉(小)
   
10. Set S214=猪脚卷粉(小)
    
11. Set S215=三鲜卷粉(小)
    
12. 
    
13. Set S311=杂酱面条(小)
    
14. Set S312=焖肉面条(小)
    
15. Set S313=牛肉面条(小)
    
16. Set S314=猪脚面条(小)
    
17. Set S315=三鲜面条(小)
    
18. 
    
19. Set S411=杂酱饵丝(小)
    
20. Set S412=焖肉饵丝(小)
    
21. Set S413=牛肉饵丝(小)
    
22. Set S414=猪脚饵丝(小)
    
23. Set S415=三鲜饵丝(小)
    
24. 
    
25. Set S511=清汤饺子(小)
    
26. Set S512=酸辣饺子(小)
    
27. Set S513=麻辣饺子(小)
    
28. 
    
29. ::-----------------------------------------------------------
    
30. Set S121=杂酱米线(中)
    
31. Set S122=焖肉米线(中)
    
32. Set S123=牛肉米线(中)
    
33. Set S124=猪脚米线(中)
    
34. Set S125=三鲜米线(中)
    
35. 
    
36. Set S221=杂酱卷粉(中)
    
37. Set S222=焖肉卷粉(中)
    
38. Set S223=牛肉卷粉(中)
    
39. Set S224=猪脚卷粉(中)
    
40. Set S225=三鲜卷粉(中)
    
41. 
    
42. Set S321=杂酱面条(中)
    
43. Set S322=焖肉面条(中)
    
44. Set S323=牛肉面条(中)
    
45. Set S324=猪脚面条(中)
    
46. Set S325=三鲜面条(中)
    
47. 
    
48. Set S421=杂酱饵丝(中)
    
49. Set S422=焖肉饵丝(中)
    
50. Set S423=牛肉饵丝(中)
    
51. Set S424=猪脚饵丝(中)
    
52. Set S425=三鲜饵丝(中)
    
53. 
    
54. Set S521=清汤饺子(中)
    
55. Set S522=酸辣饺子(中)
    
56. Set S523=麻辣饺子(中)
    
57. ::-----------------------------------------------------------
    
58. Set S131=杂酱米线(大)
    
59. Set S132=焖肉米线(大)
    
60. Set S133=牛肉米线(大)
    
61. Set S134=猪脚米线(大)
    
62. Set S135=三鲜米线(大)
    
63. 
    
64. Set S231=杂酱卷粉(大)
    
65. Set S232=焖肉卷粉(大)
    
66. Set S233=牛肉卷粉(大)
    
67. Set S234=猪脚卷粉(大)
    
68. Set S235=三鲜卷粉(大)
    
69. 
    
70. Set S331=杂酱面条(大)
    
71. Set S332=焖肉面条(大)
    
72. Set S333=牛肉面条(大)
    
73. Set S334=猪脚面条(大)
    
74. Set S335=三鲜面条(大)
    
75. 
    
76. Set S431=杂酱饵丝(大)
    
77. Set S432=焖肉饵丝(大)
    
78. Set S433=牛肉饵丝(大)
    
79. Set S434=猪脚饵丝(大)
    
80. Set S435=三鲜饵丝(大)
    
81. 
    
82. Set S531=清汤饺子(大)
    
83. Set S532=酸辣饺子(大)
    
84. Set S533=麻辣饺子(大)
    
85. ::-----------------------------------------------------------
    
86. ::价格设置(小碗)
    
87. ::-----------------------------------------------------------
    
88. Set Sj111=3.5
    
89. Set SJ112=4.0
    
90. Set SJ113=4.0
    
91. Set SJ114=4.0
    
92. Set SJ115=3.5
    
93. 
    
94. Set SJ211=3.5
    
95. Set SJ212=4.0
    
96. Set SJ213=4.0
    
97. Set SJ214=4.0
    
98. Set SJ215=3.5
    
99. 
    
100. Set SJ311=4.0
     
101. Set SJ312=4.5
     
102. Set SJ313=4.5
     
103. Set SJ314=4.5
     
104. Set SJ315=4.0
     
105. 
     
106. Set SJ411=4.0
     
107. Set SJ412=4.5
     
108. Set SJ413=4.5
     
109. Set SJ414=4.5
     
110. Set SJ415=4.0
     
111. 
     
112. Set SJ511=4.5
     
113. Set SJ512=4.5
     
114. Set SJ513=4.5
     
115. ::价格设置(中碗)

复制代码

bingxing8000

很有创意啊

garyng

回复 3# lovealei


   楼主要开“批处理餐厅”吗？

CrLf

很有意思，我试试：

1. @echo off&setlocal enabledelayedexpansion
   
2. for %%a in (米线 卷粉 面条 饵丝 饺子) do (
   
3.         set /a a+=1
   
4.         set a!a!=%%a
   
5. )
   
6. ::主食
   
7. set b=@小中大
   
8. ::份量
   
9. for %%a in (杂酱 焖肉 牛肉 猪脚 三鲜) do (
   
10.         set /a c+=1
    
11.         set c!c!=%%a
    
12. )
    
13. ::配料
    
14. 
    
15. set -=------------------------------------------------------------------------------
    
16. for /l %%a in () do (
    
17.         setlocal&echo;&echo  !-:~-35! 菜  单 !-:~-35!
    
18.         for /l %%a in (1 1 23) do set k= !k!
    
19.         for /f %%a in ('findstr /b "[0-9][0-9][0-9]=" %0') do (
    
20.                 set J%%a
    
21.                 for /f "delims==" %%b in ("%%a") do (
    
22.                         set @=%%b
    
23.                         for /f "tokens=1-3" %%c in ("!@:~,1! !@:~1,1! !@:~2,1!") do (
    
24.                                 if %%c neq !last! (
    
25.                                         if defined echo echo !echo!
    
26.                                         echo  !-!
    
27.                                         for %%f in (tn echo) do set %%f=
    
28.                                         set last=%%c
    
29.                                 )
    
30.                                 set /a tn+=1,t=tn%%2
    
31.                                 set na=%%b:!c%%e!!a%%c!（!b:~%%d,1!）!k!
    
32.                                 set mo=!k:~-8!!J%%b:~,-1!.!J%%b:~-1! 元
    
33.                                 set echo=!echo!  !na:~,15!!mo:~-7!      
    
34.                                 if !t!==0 echo !echo!&set echo=
    
35.                         )
    
36.                 )
    
37.         )
    
38.         echo  !-!
    
39.         rem 输出菜单
    
40. 
    
41.         echo;
    
42.         set /p in=请输入菜单：（可以同时多选）^
    
43. 
    
44.   
    
45.         echo;
    
46.         for %%b in (!in!) do (
    
47.                 if defined J%%b (
    
48.                         set @=%%b
    
49.                         for /f "tokens=1-3" %%c in ("!@:~,1! !@:~1,1! !@:~2,1!") do (
    
50.                                 set na=%%b:!c%%e!!a%%c!（!b:~%%d,1!）!k!
    
51.                                 set mo=!k:~-8!!J%%b:~,-1!.!J%%b:~-1! 元
    
52.                                 echo   !na:~,20!!mo:~-7!
    
53.                                 set /a $+=!J%%b!
    
54.                         )
    
55.                 ) else echo   %%b:  [无此条目]
    
56.         )
    
57.         if defined @ (
    
58.                 echo;
    
59.                 set $=!k!!$:~,-1!.!$:~-1! 元
    
60.                 echo !k![总价：!$:~-6!]!k:~-14!!date! !time!
    
61.         )
    
62.         pause>nul
    
63.         for /l %%a in (1 1 4) do echo;
    
64.         endlocal
    
65. )
    
66. ::菜单输入、计算和输出
    
67. 
    
68. ::以下为菜目编号与价格（以角为单位，方便计算）
    
69. 111=35
    
70. 112=40
    
71. 113=40
    
72. 114=40
    
73. 115=35
    
74. 
    
75. 211=35
    
76. 212=40
    
77. 213=40
    
78. 214=40
    
79. 215=35
    
80. 
    
81. 311=40
    
82. 312=45
    
83. 313=45
    
84. 314=45
    
85. 315=40
    
86. 
    
87. 411=40
    
88. 412=45
    
89. 413=45
    
90. 414=45
    
91. 415=40
    
92. 
    
93. 511=45
    
94. 512=45
    
95. 513=45

复制代码

效果如下：

1. 
   
2. -------------------------------- 菜  单 --------------------------------------
   
3. ------------------------------------------------------------------------------
   
4.   111:杂酱米线（小）      3.5 元        112:焖肉米线（小）      4.0 元
   
5.   113:牛肉米线（小）      4.0 元        114:猪脚米线（小）      4.0 元
   
6.   115:三鲜米线（小）      3.5 元
   
7. ------------------------------------------------------------------------------
   
8.   211:杂酱卷粉（小）      3.5 元        212:焖肉卷粉（小）      4.0 元
   
9.   213:牛肉卷粉（小）      4.0 元        214:猪脚卷粉（小）      4.0 元
   
10.   215:三鲜卷粉（小）      3.5 元
    
11. ------------------------------------------------------------------------------
    
12.   311:杂酱面条（小）      4.0 元        312:焖肉面条（小）      4.5 元
    
13.   313:牛肉面条（小）      4.5 元        314:猪脚面条（小）      4.5 元
    
14.   315:三鲜面条（小）      4.0 元
    
15. ------------------------------------------------------------------------------
    
16.   411:杂酱饵丝（小）      4.0 元        412:焖肉饵丝（小）      4.5 元
    
17.   413:牛肉饵丝（小）      4.5 元        414:猪脚饵丝（小）      4.5 元
    
18.   415:三鲜饵丝（小）      4.0 元
    
19. ------------------------------------------------------------------------------
    
20.   511:杂酱饺子（小）      4.5 元        512:焖肉饺子（小）      4.5 元
    
21. ------------------------------------------------------------------------------
    
22. 
    
23. 请输入菜单：（可以同时多选）
    
24.   112 122 313 214 512 415
    
25. 
    
26.   112:焖肉米线（小）           4.0 元
    
27.   122:  [无此条目]
    
28.   313:牛肉面条（小）           4.5 元
    
29.   214:猪脚卷粉（小）           4.0 元
    
30.   512:焖肉饺子（小）           4.5 元
    
31.   415:三鲜饵丝（小）           4.0 元
    
32. 
    
33.                        [总价：21.0 元]              2011/09/01 周四 23:11:31.32

复制代码

bluewing009

很好做吧，既然名字、单价已知，可以set一个choose变量，作为选择编号（即点菜输入），定义格式：“编号 数量”然后以空格分离（没有数量的可设置为1），那么价格=单价*数量，然后累加即可。最后得出一个总价。

cjiabing

虽然复杂了点，但更实用了点。
如果想要界面漂亮点请参考：
批处理自定义界面（大小和颜色） http://www.bathome.net/thread-13918-1-1.html

1. @echo off&setlocal enabledelayedexpansion
   
2. MODE con: COLS=100
   
3. title 点餐结算系统
   
4. echo;  
   
5. echo;                                  点餐结算系统
   
6. echo;
   
7. echo;
   
8. echo;编号——名     称——价格     编号——名     称——价格     编号——名     称——价格
   
9. echo -------------------------------------------------------------------------------------
   
10. :菜单
    
11. set str1=
    
12. set str2=
    
13. set str3=
    
14. for /f "usebackq skip=80 tokens=1,2,3,4,5,6,7,8* delims=-][ " %%a in ("%~0") do (
    
15. if %%a lss 999999 if "%%c" geq "0.0元" set "str1=%%a - %%b - %%c；"
    
16. if %%d lss 999999 if "%%f" geq "0.0元" set "str2=%%d - %%e - %%f；"
    
17. if %%g lss 999999 if "%%i" geq "0.0元" set "str3=%%g - %%h - %%i；"
    
18. if defined str1 if defined str2 if defined str3 echo;!str1!  !str2!  !str3!
    
19. )
    
20. echo -------------------------------------------------------------------------------------
    
21. set 总价=0
    
22. set var=
    
23. cd.>DCJStemp
    
24. ::由于批处理不能进行浮点运算，无法获得小数点后一位数，请自行更换算法。
    
25. echo;
    
26. echo     开始点菜，输入方法【编号  数量】示例如下：
    
27. echo     购买编号为111的“杂酱米线”“两份”，则输入：111 2
    
28. echo     点餐过程中的总价没有去掉小数点，最后结账时才计算小数点。
    
29. echo     返回菜单【M】结束点菜【Q】
    
30. :点菜
    
31. echo;
    
32. set /p input=    请输入：
    
33. echo;
    
34. if "%input%"=="" goto 点菜
    
35. if /i "%input%"=="Q" goto 结账
    
36. if /i "%input%"=="M" goto 菜单
    
37. for /f "tokens=1,2" %%x in ("%input%") do (
    
38.     for /f "usebackq skip=7 tokens=1,2,3,4,5,6,7,8* delims=-][ " %%a in ("%~0") do (
    
39.         if %%x==%%a (
    
40.             for /f "tokens=1,2 delims=.元" %%o in ("%%c") do set /a 总价=%%o%%p*%%y+!总价!
    
41.             set "var=%%a；名称：%%b；单价：%%c；总价：!总价!；"
    
42.             echo     !var!&echo     !var!>>DCJStemp
    
43.         )
    
44.         if %%x==%%d (
    
45.             for /f "tokens=1,2  delims=.元" %%o in ("%%f") do set /a 总价=%%o%%p*%%y+!总价!
    
46.             set "var=编号：%%d；名称：%%e；单价：%%f；总价：!总价!；"
    
47.             echo     !var!&echo     !var!>>DCJStemp
    
48.         )
    
49.         if %%x==%%g (
    
50.             for /f "tokens=1,2  delims=.元" %%o in ("%%i") do set /a 总价=%%o%%p*%%y+!总价!
    
51.             set "var=编号：%%g；名称：%%h；单价：%%i；总价：!总价!；"
    
52.             echo     !var!&echo     !var!>>DCJStemp
    
53.         )
    
54.     )
    
55. )
    
56. goto 点菜
    
57. :结账
    
58. set _总价=0
    
59. set /a _总价=!总价!/10
    
60. cls
    
61. echo;
    
62. echo;   
    
63. echo;                                  结    账
    
64. echo -------------------------------------------------------------------------------------
    
65. echo;
    
66. echo;
    
67. echo     你已经点的菜：
    
68. echo;
    
69. type     DCJStemp
    
70. echo;
    
71. echo     实际总价格：%_总价%.!总价:~-1,1! 元
    
72. echo;
    
73. echo;
    
74. echo -------------------------------------------------------------------------------------
    
75. pause
    
76. del /f /q DCJStemp>nul 2>nul
    
77. cls
    
78. goto 菜单
    
79.   ------------------------------以下放菜谱--------------------------------------
    
80. 
    
81. 
    
82.    米线类(编号1开头)
    
83. ----------------------------------------------------------------------------------
    
84.    [111] 杂酱米线(小) 3.5元  [121] 杂酱米线(中) 4.0元  [131] 杂酱米线(大) 4.5元
    
85.    [112] 焖肉米线(小) 4.0元  [122] 焖肉米线(中) 4.5元  [132] 焖肉米线(大) 4.5元
    
86.    [113] 牛肉米线(小) 4.0元  [123] 牛肉米线(中) 4.5元  [133] 牛肉米线(大) 4.5元
    
87.    [114] 猪脚米线(小) 4.0元  [124] 猪脚米线(中) 4.5元  [134] 猪脚米线(大) 4.5元
    
88.    [115] 三鲜米线(小) 3.5元  [125] 三鲜米线(中) 4.0元  [135] 三鲜米线(大) 4.5元
    
89. ----------------------------------------------------------------------------------
    
90. 
    
91.    卷粉类(编号2开头)
    
92. ----------------------------------------------------------------------------------
    
93.    [211] 杂酱卷粉(小) 3.5元  [221] 杂酱卷粉(中) 4.0元  [231] 杂酱卷粉(大) 4.5元
    
94.    [212] 焖肉卷粉(小) 4.0元  [222] 焖肉卷粉(中) 4.5元  [232] 焖肉卷粉(大) 5.0元
    
95.    [213] 牛肉卷粉(小) 4.0元  [223] 牛肉卷粉(中) 4.5元  [233] 牛肉卷粉(大) 5.0元
    
96.    [214] 猪脚卷粉(小) 4.0元  [224] 猪脚卷粉(中) 4.5元  [234] 猪脚卷粉(大) 5.0元
    
97.    [215] 三鲜卷粉(小) 3.5元  [225] 三鲜卷粉(中) 4.0元  [235] 三鲜卷粉(大) 4.5元
    
98. ----------------------------------------------------------------------------------
    
99. 
    
100.    面条类(编号3开头)
     
101. ----------------------------------------------------------------------------------
     
102.    [311] 杂酱面条(小) 4.0元  [321] 杂酱面条(中) 4.5元  [331] 杂酱面条(大) 5.0元
     
103.    [312] 焖肉面条(小) 4.5元  [322] 焖肉面条(中) 5.0元  [332] 焖肉面条(大) 5.5元
     
104.    [313] 牛肉面条(小) 4.5元  [323] 牛肉面条(中) 5.0元  [333] 牛肉面条(大) 5.5元
     
105.    [314] 猪脚面条(小) 4.5元  [324] 猪脚面条(中) 5.0元  [334] 猪脚面条(大) 5.5元
     
106.    [315] 三鲜面条(小) 4.0元  [325] 三鲜面条(中) 5.0元  [335] 三鲜面条(大) 5.0元
     
107. ----------------------------------------------------------------------------------
     
108. 
     
109.    饵丝类(编号4开头)
     
110. ----------------------------------------------------------------------------------
     
111.    [411] 杂酱饵丝(小) 4.0元  [421] 杂酱饵丝(中) 4.5元  [431] 杂酱饵丝(大) 5.0元
     
112.    [412] 焖肉饵丝(小) 4.5元  [422] 焖肉饵丝(中) 5.0元  [432] 焖肉饵丝(大) 5.5元
     
113.    [413] 牛肉饵丝(小) 4.5元  [423] 牛肉饵丝(中) 5.0元  [433] 牛肉饵丝(大) 5.5元
     
114.    [414] 猪脚饵丝(小) 4.5元  [424] 猪脚饵丝(中) 5.0元  [434] 猪脚饵丝(大) 5.5元
     
115.    [415] 三鲜饵丝(小) 4.0元  [425] 三鲜饵丝(中) 4.5元  [435] 三鲜饵丝(大) 5.0元
     
116. ----------------------------------------------------------------------------------
     
117. 
     
118.    饺子类(编号5开头)
     
119. ----------------------------------------------------------------------------------
     
120.    [511] 清汤饺子(小) 4.5元  [521] 清汤饺子(中) 5.0元  [531] 清汤饺子(大) 5.5元
     
121.    [512] 酸辣饺子(小) 4.5元  [522] 酸辣饺子(中) 5.0元  [532] 酸辣饺子(大) 5.5元
     
122.    [513] 麻辣饺子(小) 4.5元  [523] 麻辣饺子(中) 5.0元  [533] 麻辣饺子(大) 5.5元
     
123. ----------------------------------------------------------------------------------
     

复制代码

raymai97

用批处理做，感觉有点怪啊~

mstsc

很有创意的想法啊        慢慢学习中

BAT1

在实际使用中会有这样一种情况:
比如，8号台先点了2个菜9瓶酒，
5号台点了2个菜
8号后来又加了3个菜要合到前面2个菜里一起算
1号点了5个菜
8号买单的时候又退回3瓶酒
8号是要在临走的时候再付钱那么这个脚本要怎么做呢？

还有就是价钱开的比我们这边便宜多了，我也想去吃，我们这里猪肉面条卖13块一碗。

wolfan

强大啊。
然后在加上一个打印接口（400MM小单打印）在加个导入EXLCE方便财务管理~

说话~ CMD的打印是不是可以按照窗口的大小来输出打印呢？

cjiabing

回复 11# BAT1


    搞那么复杂，不过稍微懂得for、if、set的都不算难！~自己搞下

BAT1

回复 13# cjiabing

其实我也试着写过，但是完成后的脚本很长很长。
    记得batman 说过，代码超过100行的批处理里面就有很多垃圾代码
    而且，我们论坛的综止是“不求最大，但求最好，做最实用的批处理论坛”

所以希望cjiabing版主亲自出马，用 矢豆  小  米青  练 的代码（100行以内）写一个最好的点餐系统。切记不是第二好，也不是第三好，是最好！！！（在功能上最好添加上11楼的要求）

冷玉公子

哈哈 这个我觉得应该是把选择的东西输出到一个临时的文本中，然后选择完毕后，再读取计算就OK了吗、
很有兴趣帮你写这个 哈哈