【练习-007】批处理去除指定字符前所有的0

batman

如文本1.txt:

0000acb0h
0b0c00a000s
0000h00ga00
a0000000
复制代码

通过批处理将文本所有字符串字符a前的0去除输出如下：

acb0h
bca000s
hga00
a0000000
复制代码

要求：代码简洁、高效、通用，不生成临时文件
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
本题已有较完美的解答方案：
　　见9楼pusefalse版主和本人10楼的方案。

[ 本帖最后由 batman 于 2008-8-4 17:55 编辑 ]

pusofalse

********************
屏蔽，看错题意了。

[ 本帖最后由 pusofalse 于 2008-8-2 04:20 编辑 ]

null

我失败了，但我有个问题
我的测试代码如下：

@echo off
for /f "tokens=1,2 delims=a" %%i in (1.txt) do (
set a=%%i
set a=%a:0=%
echo %a%a%%j
)
复制代码

结果为：

 
acb0h
a000s
a00
a
复制代码

在CMD中运行
set a=0b0c00a000s
set a=%a:0=%
echo %a%
的结果正常，显示为:bcas
为什么在上面的测试代码中结果却全部变没了呢？

pusofalse

原帖由 null 于 2008-8-2 01:15 发表
我失败了，但我有个问题
我的测试代码如下：
@echo off
for /f "tokens=1,2 delims=a" %%i in (1.txt) do (
set a=%%i
set a=%a:0=%
echo %a%a%%j
)

结果为：

acb0h
a000s
a00
a


在CMD中运行
...

你的这两个代码输出的结果是理所当然的。第一个因为没有开启变量延迟，即使开启了，输出的结果也不会正确。
第二个。你测试如下代码。

 
set a=0b0c00a000s&echo %a%
pause
复制代码

保存为bat。运行，你会发现a的值并不是你所想的那样,而是显示echo处于关闭状态。
这是因为CMD命令解释器在读到set a=0b0c00a000s&echo %a%这一条完整的语句时，发现a用%%闭合，是个变量，会把它替换成之前所赋给它的字符串常量，并把它打印出来。而在这条完整的语句之前并没有给a赋值，即是空值。所以才会显示echo处于关闭状态。请理解“一条完整的语句”的意思。
set a=0b0c00a00s&echo %a% 这才是一条完整的语句。
同样的，for语句中给a赋值，然后又在for中引用%a%，在这之前，CMD早就把它替换为空值了，所以你的代码会出错。
如何避免这种出错呢，要用到变量延迟了。
setlocal enabledelayedexpansion 这条语句的意思即是开启变量延迟。它的作用就是要告诉CMD，在读到一条完整的语句时，不要急匆匆地扩展变量。而是在执行复合语句(for语句或if语句中其后用一对圆括号闭合的所有语句称为复合语句，用&或&&连接的也是复合语句。)中的某单条语句之后，再执行变量的扩展，也就是说，这个变量扩展的行为被延后了。在开启延迟之后，在for中给变量a赋值，又在for中引用a，此时，就不应用%%将其闭合了，而是用!!。
你的代码应该是这样。

 
@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=a" %%i in (1.txt) do (
set a=%%i
set a=!a:0=!
echo !a!a%%j
)
pause
复制代码

但输出的结果仍不符合楼主的要求，这就要看你的了。

还要记得，如果在复合语句之外再次引用变量，此时它的值是在复合语句之内最后得到的值。
如下代码：

 
@echo off&setlocal enabledelayedexpansion
for /l %%a in (100 1 199) do set var=%%a&echo !var:~1!
echo %var%
pause
复制代码

关于变量延迟，搜索一下，多做测试很快就能明白了，我说的很粗糙。

[ 本帖最后由 pusofalse 于 2008-8-2 04:06 编辑 ]

null

我明白了，十分感谢！

batman

提示一下：
　　开启变量延迟是我们常用的方法，但大家想一想本题是不是可以不开变量延迟？

batman

我们出题目的目的在于让大家都活跃下思路，在设法解题的过程中能得到提高。

本题确实不难，希望大家充分利用好每次出题的机会来提高自己，同时也可获
得一定的积分奖励（当然这并不是目的所在）。

ieutk

@echo off&setlocal enabledelayedexpansion
for /f "usebackq skip=12 delims=" %%a in ("%~dpnx0") do (
        set "var=%%a"
        set "var=!var:a=a#!"
        for /f "tokens=1* delims=#" %%i in ("!var!") do (
                 set "eo1=%%i"&set "eo2=%%j"
                 set "eo1=!eo1:0=!"
                 set "eo2=!eo2:#=!"
                 echo.!eo1!!eo2!
            )
    )
pause&goto :eof
0000acb0ha0
0b0c00a000s
0000h00ga00
a0000000a
a00d0sa000d0a0
复制代码

[ 本帖最后由 ieutk 于 2008-8-3 15:09 编辑 ]

pusofalse

@echo off
for /f "delims=" %%. in (1.txt) do (
   set "str=%%."
   call,set "str=%%str:*a=%%"
   for /f "delims=a" %%{ in ("%%.") do (
         set "var=%%{"
        call,echo.%%var:0=%%a%%str%%
  ))
pause>nul
复制代码

来个怪异的。^_^

batman

我的解：

@echo off
for /f "tokens=1,2 delims=a" %%i in (1.txt) do (
     if "%%j" neq "" (
        set "str=%%i"
        call,set "str=%%str:0=%%"
        call,echo %%str%%a%%j
        ) else (
        echo a%%i
     )
)
pause>nul
复制代码

more

如果测试文本如下,要求去除第一个a前的0,那么只有9楼的代码成功:

0000acb0a0h
0ab0c00a000s
0000h00ga00
00a000a0000
复制代码

[ 本帖最后由 more 于 2008-8-5 11:59 编辑 ]

batman

批处理之所以如此得到大家的青睐，是因为它可以现写现用很方便，
同时从一另一层面上就要求我们具体问题具体对待，相信谁也不会
回为要解决一个普通的问题而写出一个适合出所有此类问题的代码
吧，如真要这样做，在时间上的损耗将是一笔无可估量的损失，我
们也会因此而得不偿失。

ieutk

如果测试文本如下,要求去除第一个a前的0,那么只有9楼的代码成功

用11楼提供的字符经测试，8，9楼代码都通过，10楼没有通过

批处理之所以如此得到大家的青睐，是因为它可以现写现用很方便，
同时从一另一层面上就要求我们具体问题具体对待，相信谁也不会
回为要解决一个普通的问题而写出一个适合出所有此类问题的代码
吧，如真要这样做，在时间上的损耗将是一笔无可估量的损失，我
们也会因此而得不偿失。

呵呵，说的也是，有时在写代码的时候会出现考滤问题不全而导致代码不通用。

Clark2505

可怜的我为什么都学不会for的用法？？
各位大大怎么学的？？

shqf

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=a" %%i in (1.txt) do (
set aftera=%%j
if "!aftera!"=="" set aftera=%%i
set a=%%i
set a=!a:0=!
echo !a!a!aftera!
)
pause
复制代码

[ 本帖最后由 shqf 于 2008-8-5 21:57 编辑 ]