[已解决]批处理删除文本中空行的脚本修改

yun1831

1. @echo off
   
2. ::By Shilyx mailto oversleep@163.com
   
3. if {%1}=={} goto :EOF
   
4. 
   
5. :begin
   
6. if {%1}=={} goto end
   
7. call elBlank %1
   
8. shift
   
9. goto begin
   
10. 
    
11. elBlank
    
12. if not exist %1 goto :EOF
    
13. echo Deleting Balnk Lines in %1
    
14. echo.
    
15. type %1 | findstr /V "^$" >C:\_tmp.Shilyx
    
16. type C:\_tmp.Shilyx>%1
    
17. goto :EOF
    
18. 
    
19. :end
    
20. if exist C:\_tmp.Shilyx del C:\_tmp.Shilyx
    
21. echo Process Succeed, press any key to exit ...
    
22. pause>nul

复制代码

这段脚本可以，但是稍大一点文件就会产生乱码，高手请修改一下，不胜感谢！

batman

我晕，这么复杂，没必要改了，直接给你一个：

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in ('type a.txt') do (
   
3.      if not defined flag (echo.%%i>a.txt&set "flag=a") else (echo.%%i>>a.txt)
   
4. )
   
5. start a.txt

复制代码

[ 本帖最后由 batman 于 2008-7-29 20:55 编辑 ]

namejm

　　要想兼容所有特殊情况（行首是分号、冒号、行内带感叹号、&、>、|……最后两个字符为空格+0～9），还是需要用这个代码：

1. @echo off
   
2. cd.>reslut.txt
   
3. for /f "delims=" %%i in ('findstr /n .* test.txt') do (
   
4.     set "str=%%i"
   
5.     setlocal enabledelayedexpansion
   
6.     set "str=!str:*:=!"
   
7.     if defined str (echo.!str!)>>reslut.txt
   
8.     endlocal
   
9. )
   
10. start reslut.txt

复制代码

batman

原帖由 namejm 于 2008-7-29 20:53 发表
　　要想兼容所有特殊情况（行首是分号、冒号、行内带感叹号、&、>、|……最后两个字符为空格+0～9），还是需要用这个代码：@echo off
cd.>reslut.txt
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
...

考虑的好全啊！namejm就是namejm，学习了。

bakdfkuk

对于第一行有空行的文本,处理起来不行啊,能不能改进呢?

Batcher

删除一个文件中的空行：

1. findstr "." "1.txt" > "2.txt"

复制代码

删除多个文件中的空行：

1. @echo off
   
2. chcp 65001
   
3. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
4.     findstr "." "%%i" > "%%i.tmp"
   
5.     move /y "%%i.tmp" "%%i"
   
6. )

复制代码

yyz219

回复 6# Batcher


    很好的代码

aloha20200628

用批处直接读写文本文件，读取会自动过滤空行，但用 echo 写出不会删除末尾换行符，且有每行字符量8KB的限制，还有行首字符过滤设置（默认是 ; 字符），以下一行流纯批取消了行首字符过滤设置...

1. 
   
2. (for /f "delims="eol^= %%a in (1.txt) do echo,%%a)>2.txt
   

复制代码

在没有预装 powershell 的系统中，如果要删除全部空行包括末尾换行符，可用以下代码

1. 
   
2. @echo off &setlocal &findstr "." 1.txt>#.$
   
3. for /f %%n in ('find /c /v ""^<#.$') do set "n=%%n"
   
4. (for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" #.$') do if %%a neq %n% (echo,%%b) else set/p="%%b"<nul)>2.txt
   
5. del /q #.$ &pause&exit/b
   

复制代码

但以上代码要求最后一行首字符不能是空格或跳格，否则会被扣除，以下 bat+jscript 脚本（存为 test.bat 运行）会弥补此缺憾，突破每行8KB字符量限制，而且能够兼容 ansi(即gb2312) 和 utf-8 编码文件，删除全部空行及其末尾换行符...

1. 
   
2. 2>1/* ::
   
3. @echo off &cscript /nologo /e:jscript "%~f0" 1.txt 2.txt &pause&exit/b */
   
4. v=WSH.arguments, as=WSH.createobject('adodb.stream'), as.mode=3, as.type=2, as.charset='437', as.open, as.loadfromfile(v(0)), s=as.readtext(), as.close;
   
5. s=s.replace(/[\r\n]+/g,'\r\n').replace(/\s*$/, '');
   
6. as.open, as.writetext(s), as.savetofile(v(1),2), as.close, WSH.quit();
   

复制代码