[已解决]请教文件压缩批处理

qq370135415

1. @echo off
   
2. ::如果E盘没有Output\1文件夹，创建Output\1。
   
3. if not exist "E:\Output\1" mkdir "E:\Output\1"
   
4. ::将C:\OutFolder\1里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\1。
   
5. for /f "usebackq tokens=1* delims=" %%a in (`dir /b "C:\OutFolder\1"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\1\%%a.rar" "C:\OutFolder\1\%%a")
   
6. 
   
7. ::如果E盘没有Output\test文件夹，创建Output\test。
   
8. if not exist "E:\Output\test" mkdir "E:\Output\test"
   
9. ::将C:\OutFolder\test里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\test。
   
10. for /f "usebackq tokens=1* delims=" %%a in (`dir /b "C:\OutFolder\test"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\test\%%a.rar" "C:\OutFolder\test\%%a")
    
11. 
    
12. ::如果E盘没有Output\asd文件夹，创建Output\asd。
    
13. if not exist "E:\Output\asd" mkdir "E:\Output\asd"
    
14. ::将C:\OutFolder\asd里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\asd。
    
15. for /f "usebackq tokens=1* delims=" %%a in (`dir /b "C:\OutFolder\asd"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\asd\%%a.rar" "C:\OutFolder\asd\%%a")
    
16. 
    
17. pause

复制代码

首先这是一个用来批量压缩文件的批处理

目的是将C:\OutFolder目录下的所有文件夹里的文件压缩备份到E:\Output目录下 并把每个文件压缩成单独的文件



最后完成的效果是 C:\OutFolder\1\456.txt  变成 E:\Output\1\456.rar

                              C:\OutFolder\test\1.txt           E:\Output\test\1.rar

                              C:\OutFolder\asd\abc.txt        E:\Output\asd\abc.rar

也就是只把盘符和后缀名变了一下

或者说把C:\OutFolder下的所有文件单独压缩一下然后将C:\OutFolder复制到E盘下





请教 如果C:\OutFolder目录下有很多文件夹怎样来实现

hanyeguxing

1. @echo off
   
2. for /r "C:\OutFolder" %%a in (*) do (
   
3.         md "e:%%~pa" 2>nul
   
4.         rar.exe a -inul -m5 "e:%%~pna.rar" "%%a"
   
5. )

复制代码

hanyeguxing

如果要改变路径:

1. @echo off&setlocal enabledelayedexpansion
   
2. set "r=C:\OutFolder"
   
3. set "s=E:\Output"
   
4. for /r "%r%" %%a in (*) do (
   
5.         set "d=%%~dpa"
   
6.         md "!d:%r%=%s%!" 2>nul
   
7.         rar.exe a -inul -m5 "!d:%r%=%s%!%%~na.rar" "%%a"
   
8. )

复制代码

qq370135415

非常感谢版主！谢谢！

lanni654321

看来懂得东西  还是很少呢……